mauszeiger von zeigefinger in faust ändern

[nox1mus]

hi,
ich hab jetzt schon fleissig gestöbert, aber nichts gefunden. un zwar:

ich habe einen mc den man drag'en kann und damit man das auch ohne hinweis erkennen kann hätte ich gerne anstatt dieses man-kann-mich-klicken-zeigefingers die man-kann-mich-bewegen-faust.

ich weiss dass es in lingo einen befehl gibt mit dem man das aussehen der maus steuern kann, da liegt doch die vermutung nahe, dass man das in as auch kann. kennt zufällig jemand den paramater. irgendwas wie mouse.fist oder so

[:: RK ::]

hi,

du kannst das ja so machen, dass wenn man auf die zu
draggende Fläche klickt, die Mouse gehidet wird, und anstelle
der Mouse diese Hand, die du vorher in Flash importiert hast,
an die Mouse hängst.

also kurz gesagt: so 'n Mousezeigerwechsel

alles klar ???

Nein, das geht in Flash nicht. Du kannst mit useHandCursor=false auf Buttons statt der Hand den Zeiger beibehalten. Und du kannst mit Mouse.hide(); die Maus verstecken und stattdessen eine andere Grafik per Drag+Drop bewegen. Das sieht dann quasi genauso aus, als ob du einen anderen Mauszeiger verwendest. Im folgenden Beispiel habe ich eine echte Drag+Drop-Aktion mit einem Ersatzmauszeiger verwendet:

//der Scope lässt es zu, dass alle MC-Events hier liegen!!
 
meineGrafik.onRollOver = function(){
    Mouse.hide();               //Wenn der Mauszeiger über das Logo rollt, dann verstecke den Originalzeiger
    mcZeiger._visible = true;//und zeige stattdessen einen neuen Cursor
}
 
meineGrafik.onRollOut = function(){
    Mouse.show();         //Wenn der Cursor vom Logo rollt, dann alles wieder auf Anfang
    mcZeiger._visible = false;
}
 
mcZeiger.onMouseMove = function() {//Wenn der neue Cursor bewegt wird
        _root.mcZeiger._x = _root._xmouse;//dann bewege ihn auf gleichen Koordinaten wie den (versteckten) Originalzeiger
        _root.mcZeiger._y = _root._ymouse;
        if(_root.dd == true){//Wenn eine Dragfunktion gestartet ist
            if (_root.meineGrafik.hitTest(_root.mcZiel)) {//überprüfe ob das Zielfeld schon berührt wird
                _root.meineGrafik.mcPv._visible =false;//wenn ja, verstecke die Parkverbot-Anim und zeige die Parkplatz-Anim
                _root.meineGrafik.mcPp._visible =true;
                _root.meineGrafik.mcPp.play();
            } else {
                _root.meineGrafik.mcPv._visible =true;
                _root.meineGrafik.mcPp._visible =false;
            }
        }
        updateAfterEvent();
    };
    
 
// Filmsequenz Haufen
meineGrafik.onPress = function() {
    _root.meineGrafik.mcPv.play();        //wenn auf dem Logo geklickt wird
    _root.meineGrafik.mcPv._visible = true;//zeige Ersatzgrafik
    _root.dd = true;
    startDrag(this);                                //und starte den Dragevent
};
 
meineGrafik.onRelease = function() {
    stopDrag();          //wenn das Logo losgelassen wird
    _root.dd = false;
    _root.meineGrafik.mcPv._visible =false;//stoppe und verstecke die Animationen
    _root.meineGrafik.mcPp._visible =false;
    _root.meineGrafik.mcPv.stop();
    _root.meineGrafik.mcPp.stop();
    
    if (_root.meineGrafik.hitTest(_root.mcZiel)){   //wenn das Zielfeld berührt wird
        this._x = _root.mcZiel._x;          //lege das Logo auf das Zielfeld
        this._y = _root.mcZiel._y;
    }
    else{
        this._x = _root.dummyx;      //sonst lege das Logo auf Anfang
        this._y = _root.dummyy;
    }
};
 
//zuerst einige MCs verstecken
_root.mcZeiger._visible = false;
_root.meineGrafik.mcPv._visible = false;
_root.meineGrafik.mcPp._visible = false;
_root.dummyx = meineGrafik._x;//und die Startkoordinaten festhalten
_root.dummyy = meineGrafik._y; 

[nox1mus]

tausend dank für deine / eure mühen. schade ich dachte es gäbe von flash einige vorgefertigte mauszeiger, das wäre ja erheblich einfacher. aber so krieg ich es auch hin. wie gesagt danke und bis zum nächsten mal.