Mausrichtungsanzeiger Verbesserungsvorschläge

[flash bier]

Gruss zuvor,

bastel gerade an einem Mausrichtungsanzeiger rum.
Geht schon, aber nicht so wirklich, es zittert mir etwas zu arg !
Vielleicht hast du ja nen Verbesserungsvorschlag.
Einfach mal folgendes Script in den ersten Frame und los:

_root.createEmptyMovieClip("geraet",1);
geraet.lineStyle(0,0x000000,100);
 
geraet.moveTo(-50,-25);
geraet.beginFill(0xff0000);
geraet.lineTo(50,-25);
geraet.lineTo(50,25);
geraet.lineTo(-50,25);
geraet.lineTo(-50,-25);
geraet.endFill();
 
onEnterFrame=function(){
    _actX=_xmouse;
    _actY=_ymouse;
    neuerWINKEL=Math.atan2(_actY-_oldY,_actX-_oldX)/Math.PI*180;
    
    if(neuerWINKEL!=alterWINKEL && neuerWINKEL!=0){
        geraet._rotation=neuerWINKEL;
    }
    
    geraet._x=_root._xmouse;
    geraet._y=_root._ymouse;
    _oldX=_xmouse;
    _oldY=_ymouse;
    alterWINKEL=neuerWINKEL;
} 

Wäre Dankbar !!
Es sollte so bei 30 fps laufen !

MfG flash bier

[Janoscharlipp]

vielleicht solltest du nicht immer die letzten Koordinaten nehmen, sondern die vorletzten. Dann wäre es auch bei langsamen Bewegungen etwas besser.

Zudem könntest du den Winkel immer an den richtigen Winkel annährern, indem so sowas wie:

rotation += winkelunterschied / n;

machst. Dabei ist n z.B. 2; es bestimmt, wie schnell angenährt wird.
Für den Winkelunterschied brauchst du noch eine Funktion wie die folgende:

PHP-Code:

_global.getAngleDifference = function(a,b)
{
    /*
    gibt den kleineren orientierten Winkel (a,b) zurück
    */
    var d = b - a;
    if(d > 180)
    {
        return ((d + 180) % 360 ) - 180;
    }
    else if(d < -180)
    {
        return ((d - 180) % 360 ) + 180;
    }
    else
    {
        return d % 360;
    }
}; 


die simple Differenz kannst du nicht nehmen, da das 360 = 0 Grad Problem auftritt.

[flash bier]

Ha ....
Hab die Methode der Näherung auch gleich auf die Positionsberechnung angewendet !
Viel, viel geschmeidiger !!!!

THX .... und nochwas ???
Wäre beispielsweise ein Intervall von Vorteil ?

MfG flash bier

[Janoscharlipp]

nö, Interval bringt denke ich keinen Vorteil. Damit entkoppelst du ja einfach den Aufruf der Funktion von den Frames.

Du könntest mit onMouseMove arbeiten, dort die Koordinaten und Winkel berechnen, die letztendliche Rotation und Verschiebung aber dann in einem onEnterFrame abarbeiten. (sonst hört die Nährung plötzlich auf, wenn die Maus anhält, obwohl noch garnicht die richtigen Werte erreicht sind)
Aber wenns gut aussieht...nichts mehr ändern

[flash bier]

_root.createEmptyMovieClip("geraet",1);
geraet.lineStyle(0,0x000000,100);
 
geraet.moveTo(-100,-25);
geraet.beginFill(0xff0000);
geraet.lineTo(50,-25);
geraet.lineTo(50,25);
geraet.lineTo(-100,25);
geraet.lineTo(-100,-25);
geraet.endFill();
var countUp=0;
var rot_geschw=20;
var diffX=0;
var diffY=0;
 
onEnterFrame=function(){
    countUp+=1;
    //trace(countUp);
    diffX=Math.abs(_xmouse - geraet._x);
    diffY=Math.abs(_ymouse - geraet._y);
    //hier noch den entgültigen Abstand aus obigem errechnen !!
    
    if(diffX>20 or diffY>20){
        rot_geschw=5;
    }else{
        rot_geschw=20;
    }
    _actX=_xmouse;
    _actY=_ymouse;
    
    geraet._x  = geraet._x +  ( _actX- geraet._x )/5;
    geraet._y  = geraet._y +  ( _actY- geraet._y )/5;
    neuerWINKEL=Math.atan2(_actY-_ganzoldY,_actX-_ganzoldX)/Math.PI*180;
    if(neuerWINKEL != 0){
        winkelunterschied=getAngleDifference(alterWINKEL,neuerWINKEL);
        geraet._rotation += winkelunterschied/rot_geschw;
    }
    if(countUp == 5){
        countUp=0;
      _ganzoldX=_actX;
        _ganzoldY=_actY;
    }
    alterWINKEL=geraet._rotation;
} 
 
 _global.getAngleDifference = function(a,b)
{
    /*
    gibt den kleineren orientierten Winkel (a,b) zurück
    */
     var d = b - a;
    if(d > 180)
    {
        return ((d + 180) % 360 ) - 180;
    }
    else if(d < -180)
    {
        return ((d - 180) % 360 ) + 180;
    }
    else
    {
        return d % 360;
    }
}; 

finde ich schon nicht schlecht !

MfG flash bier