LoadVars - Fehler?

[skamarkus]

liebe Leute, hier schon gepostet auf Flash Compile-Fehler ??? weil ich dachte es ist ein Fehler beim Kompilieren, nun aber sehr seltsame Lösung:

meine 1. Version zeigt eben nur im SWF bei Selbstöffnen den geladenen Text an:

PHP-Code:

var lorem_lv:LoadVars = new LoadVars();
lorem_lv.onData = function (src:String):Void {
    if (src == undefined) {
        trace("Error loading content.");
        return;
    } 
    inhalt_txt.text = src;
};

lorem_lv.load("web_rk.txt"); 


nun die Flash-Hilfe durchforstet und eine 2.Version gefunden unter LoadVars bei onData mit 3 (!) Parameter... leider keine Erklärung dazu gefunden... habt ihr ne Ahnung?

PHP-Code:

my_lv.load("content.txt", my_lv, "GET"); 


jetzt kommt das lustigste, wenn ich bei mir das einfüg geht es auch, obwohl mein LoadVars-Objekt "lorem_lv" heißt und ich kein my_lv habe !!! wie geht das? ich hab dann weiterprobiert und kann auch michi oder test als 2. Paramenter reinschreiben, buxtihudi aber nicht siehe hier:

PHP-Code:

var lorem_lv:LoadVars = new LoadVars();
lorem_lv.onData = function (src:String):Void {
    if (src == undefined) {
        trace("Error loading content.");
        return;
    } 
    inhalt_txt.text = src;
};

lorem_lv.load("web_rk.txt", my_lv, "GET"); 


ich würd gern das Ganze verstehen und bedank mich schon im Voraus...

//edit: nun geht es auch nicht mehr mit den 3. Parametern, also wenn das kein Flashbug is weiß ich auch nicht

lg,
m

[readme.txt]

so 100% versteh ich das Problem nicht, aber ich würde dir raten anstatt "onData" lieber "onLoad" zu verwenden. Das ist tendentiell sicherer und du hast direkt noch eine Boolsche Variable die dir sagt ob die Abfrege erfolgreich war oder nicht.

leider keine Erklärung dazu gefunden.

Bei der LoadVars.load-Methode wird nur die URL als Parameter genutzt. Wenn du auch noch Variablen mit an den Request hängen willst, solltest du die sendAndLoad-Methode nutzen, bei der der zweite Parameter die LoadVars-Instanz ist, an die du die Variablen gehängt hast. Der dritte Parameter ist dann optional und bezeichnet die HTTP-Übertragungsmethode GET oder POST.

Und wenn du einen möglichen Response auswerten willst, solltest du immer wie von readme.txt vorgeschlagen, den onLoad-Callback statt des onData-Callbacks verwenden.

[skamarkus]

so ich hab versucht das nachzuvollziehen, nur check ich nicht wie ich nun die vars ausm lader_lv herausbekomm nach dem Übergeben?

lg,
m

PHP-Code:

var hinlader_lv:LoadVars = new LoadVars();
var lader_lv:LoadVars = new LoadVars();

lader_lv.onData = function(src:String):Void  {
    if (src == undefined) {
        trace("Error loading content.");
        return;
    } else {
        trace("WHO_ "+_lader_lv.who);
        trace("HOW_ "+ lader_lv.wie);
        trace("SRC_ "+src);
        _root.Cweb_mc[_global.who].text = src;
        _root.Cweb_mc[_global.who].setTextFormat(my_fmt12);
    }
};
//
getStuff = function (iam:String, who:String, how:String) {
    trace("getStuff iam:  "+iam);
    trace("getStuff who:  "+who);
    trace("getStuff how:  "+how);
    trace("--------------------");
    hinlader_lv.wer = who;
    hinlader_lv.wie = how;
    hinlader_lv.sendAndLoad(iam, lader_lv);
};



getStuff("web_rk.txt", "inhalt_txt", "my_fmt12");
getStuff("test.txt", "titel_txt", "my_fmt22"); 


Ausgabe:
********** BILD 10 ****************
getStuff iam: web_rk.txt
getStuff who: inhalt_txt
getStuff how: my_fmt12
--------------------
getStuff iam: test.txt
getStuff who: titel_txt
getStuff how: my_fmt22
--------------------
WHO_ undefined
HOW_ undefined
SRC_ RK DIENSTLISTE


//btw: wie ich die Vars bei onLoad rausbekommen soll dann is mir auch ein Rätsel (kenn ich nur bei XML wenn man die Childs anspricht)

Eine LoadVars-Instanz sollte reichen und den zweiten Request würde ich erst starten, wenn der Response vom ersten da ist, sonst überschreibst du dir dein LoadVars-Objekt gleich wieder. Mal als Ansatz:

PHP-Code:

function geladen(erfolgreich) {
        if(erfolgreich) {
             trace("this.who="+this.who);//wenn im Textfile ein Eintrag mit &who=irgendeinEintrag& steht
             trace("this.wie="+this.wie);

             //dann den nächsten Aufruf starten
             //_level0.getStuff(...
        }
        else {
                trace("Fehler beim Laden");
        }
}
lv = new LoadVars();//Instanz erstellen
lv.onLoad = geladen;//Callback setzen

getStuff = function (iam:String, who:String, how:String) {
    trace("getStuff iam:  "+iam);
    trace("getStuff who:  "+who);
    trace("getStuff how:  "+how);
    trace("--------------------");
    lv.wer = who;
    lv.wie = how;
    lv.sendAndLoad(iam, lv);
};



getStuff("web_rk.txt", "inhalt_txt", "my_fmt12"); 


[skamarkus]

lieber Holger,

in der Textdatei ist nur Text (ohne Vars, ohne HTML) !!! die Vars "who" and "how" kommen vom Aufruf der getStuff-Funktion... (siehe Code)

vielleicht sollt ich mal erklären was ich will ?

habe 2 Textfelder (titel_txt und inhalt_txt) die mit Content befüllt werden sollen
aus 2 Textdateien (wüsste leider nicht wie man das aus einer rausfischt), und unterschiedlich ausschauen sollen, daher die 3 Parameter bei der "getStuff" - Textdateipfad, Textfeldname, Textformatierungsname... und die sollen nun quasi nacheinander befüllt werden - soweit meine Intention davon...

um eben diese 3 Parameter zu übergeben hab ich es nun mit der sendandload-methode probiert, aber scheinbar funzt das anders wenn du Vars meinst die in der Textdatei sind.

hmmm das Brett vorm Kopf wird nicht kleiner

Textfiles oder XML-Files nutzt man dann, wenn man dynamisch Inhalte im Flashfilm austauschen will, ohne jedes Mal den Film neu veröffentlichen zu müssen. Die Texte in den Textfiles sollten dann aber auch für die URL-Codierung mit Namen-/Wertepaaren aufbereitet sein, also bspw.:

&nick=agedoubleju&
&forum=flashforum.de&

Du kannst diese Variablen dann wie schon erwähnt auslesen:

PHP-Code:

function geladen(erfolgreich) {
        if(erfolgreich) {
             trace("this.nick="+this.nick);
             trace("this.forum="+this.forum);
        }
        else {
                trace("Fehler beim Laden");
        }
}
lv = new LoadVars();//Instanz erstellen
lv.onLoad = geladen;//Callback setzen
lv.load("meinText.txt"); 


Du kannst auch mehrere Werte in eine Variable setzen und dann mit einem String.split in ein Array schieben. Im Textfile kann das dann so aussehen:

&meineWerte=10,20,100&

Und im Flashfilm:

PHP-Code:

function geladen(erfolgreich) {
        if(erfolgreich) {
             trace("this.meineWerte="+this.meineWerte);
             werteliste = this.meineWerte.split(",");//die Liste an den Komma-Zeichen in ein Array splitten
             var len = werteliste.length;
             trace("Länge des Arrays: "+len);
             for(var i=0;i<len;i++){
                trace("werteliste["+i+"]="+werteliste[i]);//alle Werte einzeln ausgeben lassen
             }
        }
        else {
                trace("Fehler beim Laden");
        }
}
lv = new LoadVars();//Instanz erstellen
lv.onLoad = geladen;//Callback setzen
lv.load("meinText.txt"); 


[skamarkus]

alright alles klar,
bin gestern noch bis 2 gesessen und hab das nun (wie in vorherigen Projekten) mit XML gelöst, werd dann eine 2 . funktion mit deinem Material hier bauen und schaun, ob das realtime XML-Auslesen wirklich sichtbar Performance-lastiger ist... bzw alles vielleicht beim Start in Arrays zu laden.

danke für die Mühen

lg,
m