load sound

[lolosi]

hallo alle zusammen,

ich habe folgendes script, indem zwei buttons
sound abspielen sollen. diese werden erst aktiv,
wenn der sound geladen ist
auf dem rechner funktionert das, nur auf
dem server nicht. wieso?

if (mySound1.getBytesLoaded() == mySound1.getBytesTotal() ) {
    text1 = "play";
    _root.but.enabled = true;
} else {
    text1 = "loading";
    _root.but.enabled = false;
}
if (mySound2.getBytesLoaded() == mySound2.getBytesTotal() ) {
    text2 = "play";
    _root.but2.enabled = true;
} else {
    text2 = "loading";
    _root.but2.enabled = false;
}

besten dank!

[harego]

Lokal ist der Sound schneller geladen als im Netz !
Es wird IF abgefragt und der Sound ist nicht da => ergo else !

Ich würde einen Preloader dafür verwenden !
Also ein onEnterFrame vor der IF.
Und wenn geladen, dann delete onEnterFrame

[lolosi]

danke, für die antwort.

es gibt noch ein problem, wenn ich
mit den veränderungen arbeite.

die else funktion funktioniert nicht.
hast du noche eine idee?

this.onEnterFrame = function() {
    if (mySound1.getBytesLoaded() == mySound1.getBytesTotal() ) {
        text1 = "play";
        _root.but.enabled = true;
    } else {
        text1 = "loading";
        _root.but.enabled = false;
    }
    if (mySound2.getBytesLoaded() == mySound2.getBytesTotal() ) {
        text2 = "play";
        _root.but2.enabled = true;
    } else {
        text2 = "loading";
        _root.but2.enabled = false;
    }
};
delete onEnterFrame;
stop();

[pape]

hi!
du deletest das onEnterFrame sofort wieder.. dass muss natürlich mit in den then teil...und du solltest auch das this. bei onEnter Frame mit angeben beim deleten (delete this.onEnterFrame) und du musst auch die sounds beide dabei beachten bevor dus deletest also entweder so:
(nichts von den folgenden scripten ist getetstet)

this.onEnterFrame = function() {
    if (mySound1.getBytesLoaded() >= mySound1.getBytesTotal()   && mySound2.getBytesLoaded() >= mySound2.getBytesTotal() ) {
        text1 = "play";
        text2 = "play";
        _root.but.enabled = true;
        _root.but2.enabled = true;
        delete this.onEnterFrame;//<hier hin.. erst deleten wenn geladen...
    } else {
        text1 = "loading";
        text2 = "loading";
        _root.but.enabled = false;
       _root.but2.enabled = false;
    }
};
stop(); 

oder mit zwei onEnterFrames arbeiten um die sounds getrennt zu laden.. z.b. so:

this.createEmptyMovieClip("loader1", 1000);
this.createEmptyMovieClip("loader2", 1001);
 
loader1.onEnterFrame = function() {
    if (mySound1.getBytesLoaded() >= mySound1.getBytesTotal()) {
        text1 = "play";
        _root.but.enabled = true;
        delete this.onEnterFrame;//<hier hin.. erst deleten wenn geladen...
        this.removeMovieClip(); // und noch den loader1 mc wieder löschen
    } else {
        text1 = "loading";
        _root.but.enabled = false;
    }
};
 
this.loader2.onEnterFrame = function() {
    if (mySound2.getBytesLoaded() >= mySound2.getBytesTotal() ) {
        text2 = "play";
        _root.but2.enabled = true;
        delete this.onEnterFrame;//<hier hin.. erst deleten wenn geladen...
        this.removeMovieClip(); // und noch den loader2 mc wieder löschen
    } else {
        text2 = "loading";
       _root.but2.enabled = false;
    }
};
stop(); 

auch schön: mit einer var gehts auch um beides in einem onenterframe zu machen und trotzdem getrennt abzufragen:

this.onEnterFrame = function() {
    if (mySound1.getBytesLoaded() >= mySound1.getBytesTotal()) {
        text1 = "play";
        _root.but.enabled = true;
        this.load1 = true;
    } else {
        text1 = "loading";
        _root.but.enabled = false;
    }
    if (mySound2.getBytesLoaded() >= mySound2.getBytesTotal() ) {
        text2 = "play";
        _root.but2.enabled = true;
        this.load2 = true;
    } else {
        text2 = "loading";
       _root.but2.enabled = false;
    }
    if ( load1 && load 2) {
        delete this.onEnterFrame;//<hier hin.. erst deleten wenn beide sounds geladen...
    }
};
stop(); 

achja noch was...
du kannst das but.enabled = false auch aus dem onEnterFrame nehmen.. spart nen paar resourcen...
einfach das falsen vor dads onEnterFrame und erst wieder frei geben, wenn geladen.. die mehrmalige zuewisung ist eigentlich sinnlos bzw verschwenderisch... genauso sieht es auch mit den texten aus.. einmalige zuweisung rteicht und nur ändern wenn der sond fertig geladen wurde...dann fällt auch der ganze else teil immer raus (wie du siehst sehr viel ökonomischer)...

jeweils so (hier mal nur für einen button und ein textfeld):

_root.but.enabled = false;
text1 = "loading";
this.onEnterFrame = function() {
    if (mySound1.getBytesLoaded() >= mySound1.getBytesTotal()) {
        text1 = "play";
        _root.but.enabled = true;
        delete this.onEnterFrame;
    }
} 

ach und noch was:
was ich die ganze zeit schon korrigiert habe, ich aber nicht erwähnt habe:
man sollte immer loaded>=total schreiben und nicht loaded== total.
das liegt daran, dass manchmal etwas mehr geladen wird als nötig (das ist wirklich minimal und tritt nur manchmal auf.. habe leider vergessen was das genau war.. ich glaube im faq oder tut board hat rena dazu was geschrieben..musste mal nen bisl suchen) und da sollte man auf nummer sicher gehen!

soooo...
wie gesagt .. ist alles nicht getestet.. deswegen besser kein copy&paste.. ist nur "kurz" runter geschrieben... sollen nur Denkansätze sein und veschiedene Möglichkeiten aufzeigen!

Hoffe die arbeit hat sich gelohnt und du bekommst das in den griff und lernst was dabei..falls nicht frag einfach noch mal nach!!!!!!

bis dann,

greetz,
Robert

Edit:
Sprachliche-richtigkeit optimiert...

[harego]

hier noch eine kpl lösung:

PHP-Code:

//Button auf enabled_______________________________________________________________
_root.but1.enabled = false;
_root.but2.enabled = false;

//Sound laden______________________________________________________________________
mSound1 = new Sound (this);
mSound1.loadSound ("loop2.mp3", true);
mSound1.stop ();
mSound2 = new Sound (this);
mSound2.loadSound ("loop3.mp3", true);
mSound2.stop ();

//Preloader _______________________________________________________________________
Sound.prototype.loader_sound = function (x, mc) {
    mc._sound = this;
    mc.onEnterFrame = function () {
        _root["text" + x].text = this._sound.getBytesLoaded ();
        if (this._sound.getBytesLoaded () == this._sound.getBytesTotal () && this._sound.getBytesLoaded () > 10) {
            trace (this._sound.getBytesLoaded ());
            delete this.onEnterFrame;
            _root["text" + x].text = "play " + x;
            _root["but" + x].enabled = true;
        }
    };
};

//functions aufruf__________________________________________________________________
mSound1.loader_sound (1, _root.but1);
mSound2.loader_sound (2, _root.but2);

//Sound starten______________________________________________________________________
_root.but1.onRelease = function () {
    mSound1.start ();
};
_root.but2.onRelease = function () {
    mSound2.start ();
}; 


[pape]

@ harego.. schön und gut... aber schreib bitte geladen>=zuladen statt "==" .. wie oben schon erwähnt is des besser/sicherer...
ansonsten is des natürlich ne schöne Lösung

[harego]

Ups ... Tippfehler...

Es geht aber so auch , nur sollte man besser ">=" verweden !