lineTo-Kreuzung Teil 2

[FireShark]

Tja, "lineTo-Kreuzung" wurde ja geschlossen. Dazu äußere ich mich jetzt mal nicht.
Also nochmal (nicht ganz) von vorne: Ich möchte den Schnittpunkt zwischen zwei Linien berechnen.
Was mache ich hier falsch?

PHP-Code:

createEmptyMovieClip("q", 1);
createEmptyMovieClip("w", 2);
qx1 = 100;
qy1 = 100;
qx2 = 100;
qy2 = 100;
wx1 = 100;
wy1 = -100;
wx2 = 100;
wy2 = 200;
q.lineStyle(1, 0);
q.lineTo(qx1, qy1);
q._x = qx2;
q._y = qy2;
w.lineStyle(1, 0);
w.lineTo(wx1, wy1);
w._x = wx2;
w._y = wy2;
var s = ((qx2 - qx1) * (wy1 - qy1) - (qy2 - qy1) * (wx1 - qx1))/((wx2 - wx1) * (qy2 - qy1) - (qx2 - qx1) * (wy2 - wy1));
var x = wx1 + s * (wx2 - wx1);
var y = wy1 + s * (wy2 - wy1);
//trace(x + "   " + y + "   " + s); // NaN   NaN   NaN -> Division durch Null... und jetzt? 


Danke im Voraus.
MfG
FireShark

[michael]

Strecken schneiden

[hgseib]

du hasst da eine merkwürdige mischung deiner koordinaten.

function fSchnittLineLine(p1, p2, p3, p4) {
	var ary = [];
	var x21 = p2._x-p1._x, y21 = p2._y-p1._y;
	var x13 = p1._x-p3._x, y13 = p1._y-p3._y;
	var x43 = p4._x-p3._x, y43 = p4._y-p3._y;
	var d = y43*x21-x43*y21;
	if (d) {
		var u2 = (x21*y13-y21*x13)/d;
		if (0<=u2 && u2<=1) {
			var u1 = (x43*y13-y43*x13)/d;
			(0<=u1 && u1<=1) ? ary.push({_x:p1._x+x21*u1, _y:p1._y+y21*u1}) : '';
		}
	}
	return ary;
}
//
createEmptyMovieClip("q", 1);
createEmptyMovieClip("w", 2);
qx1 = 100;
qy1 = 100;
qx2 = 100;
qy2 = 100;
wx1 = 100;
wy1 = -100;
wx2 = 100;
wy2 = 200;
q.lineStyle(1, 0);
q.lineTo(qx1, qy1);
q._x = qx2;
q._y = qy2;
w.lineStyle(1, 0);
w.lineTo(wx1, wy1);
w._x = wx2;
w._y = wy2;
//
schnittpunkt = fSchnittLineLine({_x:qx2, _y:qy2}, {_x:qx2+qx1, _y:qy2+qy1}, {_x:wx2, _y:wy2}, {_x:wx2+wx1, _y:wy2+wy1});
if (schnittpunkt.length>0) {
	trace("schnittpunkt bei: "+schnittpunkt[0]._x+"//"+schnittpunkt[0]._y);
} else {
	trace("kein schnittpunkt");
}

http://www.seibsprogrammladen.de/fra.../Schnittpunkte

[FireShark]

Oha, ja, das sollte erstmal genügen. Vielen Dank Euch beiden!
Ich werde mir das ganze dann mal zu Gemüte führen.

MfG
FireShark