Langsam Zeichnen ?

[wulfcam]

Hallo!
In einer Animation sollen Strichen eingeblendet werden. Mit Maske hab ich es schon gemacht, aber ich suche jetzt nach einer schnittigen Lösung.

onClipEvent (load){
	lineStyle(2, 0x000000, 100);
	}
onClipEvent (enterFrame){
	moveTo(0, 0);
	lineTo(100, 0);
             lineTo(100,100);
	}

Das funktioniert so ja gut, aber wenn der Strich langsam gezeichnet werden soll, weiß ich nicht mehr weiter.
Hat jemand einen Tip?
Vielen Dank schon mal im voraus.
Ciao
Arbeite mit Flash 8!

[rendner[i]]

Würde es so machen, sieht zwar etwas viel aus aber ist schnell überschaubar was was macht.

Da du ja Flash8 hast würde ich nicht das EnterFrame auf den mc selber legen sondern in die Hauptzeitleiste der Bühne.
Also deinen mc einfach ins erste Frame packen, dann ihm den Instanznahmen myMc geben und den Script ebenfalls ins erste Frame der Hauptzeitleiste packen.

PHP-Code:

myMc.lineStyle( 2 , 0x000000 , 100 );
// zuerst die Punkte setzen
nextPoints( myMc, [ [100 , 0] , [100 , 100] ]);
// dann erst den mc initialisieren, weil er dort schon
// auf die Punkte zurueck greift
init( myMc, 1, 0, 0 );

myMc.onEnterFrame = function()
{
    // die eigentliche "Zeichenfunktion" aufrufen
    render( this );
}

function init( mc: MovieClip, speed: Number, startX: Number, startY: Number ): Void
{
    mc.x = startX;
    mc.y = startY;
    mc.moveTo( startX, startY );
    mc.speed = speed;            // mit welcher Geschw. gezeichnet wird
    setNextPoint( mc )            // ersten Zielpunkt setzen
}

// berechnet den neuen xWert fuer
// die Linie
function updateX( mc: MovieClip ): Void
{
    if( mc.gX > (mc.x + mc.speed) ) mc.x += mc.speed;
    else if (mc.gX < (mc.x - mc.speed) ) mc.x -= mc.speed;
    else mc.x = mc.gX;
}

// ebenso fuer y
function updateY( mc: MovieClip ): Void
{
    if( mc.gY > (mc.y + mc.speed) ) mc.y += mc.speed;
    else if (mc.gY < (mc.y - mc.speed) ) mc.y -= mc.speed;
    else mc.y = mc.gY;
}

// zeichnet die Linie anhand der berechneten 
// Koordinaten
function render( mc: MovieClip ): Void
{
    // pruefen ob der Zielpunkt schon erreicht
    if( mc.x != mc.gX || mc.y != mc.gY )
    {
        updateX( mc );            // neuen xWert ermitteln
        updateY( mc );            // neuen yWert ermitteln
        mc.lineTo( mc.x, mc.y);    // ermittelten Wert zeichnen
    }
    // wenn ja, dann nach neuem Zielpunkt gucken
    else setNextPoint( mc );
}

// setzt ein Array, was die naechsten Punkte (Ziele)
// enthaelt
function nextPoints( mc: MovieClip, arr: Array ): Void
{
    // Array kopieren
    mc.arr = [].concat( arr );
}

// prueft ob noch ein Ziel (Punkt) vorhanden ist
// und setzt diese Koordinaten als neue Zielpunkte
function setNextPoint( mc: MovieClip ): Void
{
    // gucken ob noch ein Punkt da ist
    if( mc.arr.length )
    {
        mc.gX = mc.arr[0][0];        // neuer xZielwert
        mc.gY = mc.arr[0][1];        // neuer y Zielwert
        mc.arr.splice( 0, 1 );        // Punkt aus dem Array entfernen
    }
    // das onEnterFrame beenden
    else delete mc.onEnterFrame;
} 


EDIT:
Kleinen Fehler in der Funktion init beseitigt...

[wulfcam]

vielen dank für das script,
doch was du einfach nennst ist für mich schon sehr komplex...
ich guck es mir mal an, vielleicht komm ich damit klar.
Danke.
PS.: vielleicht gibt es ja doch noch eine einfache möglichkeit, den Strich langsam zu zeichnen!

[rendner[i]]

PS.: vielleicht gibt es ja doch noch eine einfache möglichkeit, den Strich langsam zu zeichnen!

Das ist schon sehr einfach, es sieht nur eben viel aus.
Habs jetzt auch etwas auskommentiert...