Ladekontrolle für mehrere dynamisch geladene jpegs?

[tonymeman]

Hallo,

ich lade 3 Jpegs per loadMovie in 3 MCs. Diese MCs werden dann per AS ein- und ausgeblendet.

Wie genau kriege ich dieses "dann" hin? Ich will, dass der Film erst weiterläuft, wenn alle 3 Bilder vollständig geladen sind.

Jemand ne Idee? (Am besten mit AS-Code, da ich noch ziemlich mies im AS programmieren bin ...)

Danke schonmal.

[RustyCake]

Schon mit suchen und finden loader oder bilder loader oder ähnlichem versucht!!

Loader gibts hier zum Säue Füttern

[johanness]

Naja, speziell für mehrere Bilder nicht. Ich hab mal einen Thread gestartet, ahb aber keine Lösungen bekommen. Habz zwar bisher noch net gebraucht, aber deswegen auch noch nicht geschrieben

[RustyCake]

Mehrere Bilder,. Sounds oder Movieclips, wo zum Henker ist der unterschied!!
Und da hab ich schon selber einige reingestellt!!

[RustyCake]

Hier der ist aus einem Thread von mir, allerdings hat der "Majo" diese Variante geschrieben!!

stop();
anzahl = 3;
for (i=1; i<=anzahl; i++) {
        _root.createEmptyMovieClip("con"+i, i+20);
        _root["con"+i].loadMovie("http://mario-rudolph.de/bilder/bild"+i+".swf");
        _root.createTextField("txt"+i, i, 420, 24*i, 130, 20);
        _root.balken.duplicateMovieClip("bal"+i, i+100);
        _root["bal"+i]._x = 420;
        _root["bal"+i]._y = 24*i;
        _root["bal"+i]._xscale = 0;
};
this.loader_funk = function() {
        for (i=1; i<=anzahl; i++) {
                t = _root["con"+i].getBytesTotal();
                l = _root["con"+i].getBytesLoaded();
                if (l>=4) {
                        pt = Math.ceil((l/t)*100);
                        _root["bal"+i]._xscale = pt;
                        _root["txt"+i].text = pt+" % von Mc"+i+" geladen";
                        if (pt >= 100) {
                                _root["bal"+i].removeMovieClip();
                                _root["txt"+i].removeTextField();
                                clearInterval(loadID);
                        }
                }
        }
};
loadID = setInterval(loader_funk, 10); 

[tonymeman]

Wenn du schon selber welche reingestellt hast, könntest du mir bestimmt auch mal einen Link auf den Thread geben?

Ich hab nämlich schon lange gesucht und immer nur die für ein Bild gefunden. Die haben aber in meinem Fall nicht funktioniert.

Und so viel Code kann das doch eigentlich nicht sein. Wie gesagt müsste ja nur überprüft werden, ob alle 3 Bilder geladen sind und wenn ja den Film weiterlaufen lassen.

EDIT: Tja, da haben wir wohl fast gleichzeitig gepostet. Danke schonmal, ich probiers dann mal aus!

[tonymeman]

Tach RustyCake,

hab das Script gerade ausprobiert, es funktioniert nicht.

Ich denke es liegt daran, dass clearInterval(loadID); innerhalb der for-Schleife steht. Damit wird nach dem ersten geladenen Bild die Ladekontrolle beendet. Aber genau das soll ja erst passieren, wenn alle Bilder geladen sind.

Ein weiteres Problem ist, dass für jedes Bild eine extra Ladeanzeige erstellt wird. Auch wird jedes Bild sofort dargestellt, nachdem es geladen ist.

Könnte man das nicht irgendwie umbauen, um eine Ladekontrolle für alle Bilder gemeinsam zu erhalten und dass die Bilder erst angezeigt werden, wenn alle geladen sind?

[momo-loom]

Hi ,

ich hatte das Problem auch schon mal.
Ich poste Dir jetzt mal ein bisschen Code, habe allerdings
grad keine Zeit es zu erklären, hoffe Du kannst es umbauen,
oder Dir selber eine Lösung damit erarbeiten.
In dem Script geht es darum, dass eine dyn. Anzahl von Bilder
und ein Content-swf geladen wird.

Das ist leider aus einem relativ Komplexen Zusammenhang gerissen, aber vielleicht hilft's
Dir ja.

Es geht sicherlich smarter:

Das ist ein onEnterFrame:

CL.Preload1stTime = function() {
    var cP = ContenPath;
    
    var pctHolder_str = cP.contentButton.button.bild.pctHolder;
    
    var pctTotal = 0;
    var pctLoaded = 0;
        
        for(i in this.picts) {
        trace("bild "+ i+" :: "+this.picts[i].Path + " | Bytes ::" + cP.contentButton.button.bild.pctHolder["seg"+this.uid]["pct"+i].getBytesTotal());
        var PictsTotal = pctHolder_str.getTotalBytes_Pict(this.uid , i);
        
        if (PictsTotal != undefined && PictsTotal != -1) {
            this.picts[i].loading = true;
            trace("Picts" + i + " loading :: " + this.picts[j].loading + " SIZE: " + PictsTotal);
        }
        
        pctTotal  += pctHolder_str.getTotalBytes_Pict(this.uid , i);
        pctLoaded += pctHolder_str.getLoadedBytes_Pict(this.uid , i);
    }
    
    trace("__________________________________________________________");
    
    var Btotal  = cP.content.content.getBytesTotal() + pctTotal;
    var Bloaded = cP.content.content.getBytesLoaded() + pctLoaded;
    
    trace("CONTENT Total: "+cP.content.content.getBytesTotal());
 
    if(!isNaN(Bloaded/Btotal)) {
        this.label_txt.text = parseInt(Bloaded/1024) + "KB / " + parseInt(Btotal/1024) + "KB";
        
        this.bar_mc._width = 186 * (Bloaded / Btotal);
        
    } else {
        this.label_txt.text = "";
        this.bar_mc._width = 0;
    }
        
    if ( Bloaded == Btotal && Bloaded > 0) {
        if (!this.avoid) {
 
                
            }
        }
        
        for(l in this.picts) {
            if (this.picts[l].loading == "undefined" ||
                pctHolder_str.getTotalBytes_Pict(this.uid , l) !=  pctHolder_str.getLoadedBytes_Pict(this.uid , l) ||
                pctHolder_str.getTotalBytes_Pict(this.uid , l) == undefined ||
                isNaN( pctHolder_str.getTotalBytes_Pict (this.uid , l) / pctHolder_str.getLoadedBytes_Pict (this.uid , l) ) ||
                pctHolder_str.getTotalBytes_Pict(this.uid , l) == -1) {
                
                    var FilesLoaded = true;
            }
        }
        
        if (cP.content.content.getBytesTotal() ==  undefined || cP.content.content.getBytesTotal() ==  -1 ||
            cP.content.content.getBytesTotal() <= 0 ||                                       
            cP.content.content.getBytesTotal() != cP.content.content.getBytesLoaded() ) {
 
                var FilesLoaded = true;
        }
        
        if (!FilesLoaded) {
        
            this.bar_mc._width = 186;
            trace("PICTS LOADED BYTES :: " + pctTotal);
            trace("TOTAL LOADED BYTES :: " + Btotal);
            removeMovieClip(this);
            cP.fadeIn();
        } else {
            delete FilesLoaded; 
        }
    }
}; 

Das sind die Funktionen, die da oben auch aufgerufen werden:

PH.getTotalBytes_Pict = function (segmentID, pctID) {
    var total = this["seg"+segmentID]["pct"+pctID].pct.getBytesTotal();
    trace("SegmentID :: "+segmentID + " | pctID:"+ pctID+" | total: "+total);
    return total;
};
 
PH.getLoadedBytes_Pict = function (segmentID, pctID) {
    var total = this["seg"+segmentID]["pct"+pctID].pct.getBytesLoaded();
    trace("SegmentID :: "+segmentID + " | pctID:"+ pctID+" | loaded: "+total);
    return total;
}; 

[johanness]

Es wäre vielleicht besser sich da eine Funktion zu schreiben, die jeweils einen Container mit Preloader und allem, was dazugehört, erstellt.

@Rusty:
Dein Script ist mir jetzt wieder zu un-dymnamisch

[Majo]

hi tonymeman....das script funzt schon, sonst würde es nicht hier stehen...und der loader hört nicht nach dem ersten bild auf....schätzungsweise fliegen hier im forum noch 1000000000000000 externe loader rum


hi rusty"theLoaderFreak"cake

[RustyCake]

Geschrieben von johanness
@Rusty:
Es wäre vielleicht besser sich da eine Funktion zu schreiben, die jeweils einen Container mit Preloader und allem, was dazugehört, erstellt!
Dein Script ist mir jetzt wieder zu un-dymnamisch

Ob Dein vorschlag so dynamisch ist Naja!!
Des was ich gepostet hb ist ja von Majo

@ tonymeman

Hab des script selbst getestet, des funzt!! Sonst würde ich des net Posten !

[harego]

hi,

wenn du die Bilder hintereinander laden möchtest,
dann test doch mal das :

var anzahl = 4;
var i = 1;
function weiter () {
    trace(i)
    if (i < anzahl) {
        //**************************************************
        createEmptyMovieClip ("bildcont" + i, i);
        this["bildcont" + i].loadMovie ("bild_" + i + ".jpg");
        //this["bildcont" + i]._x = i*200
        //**************************************************
        createEmptyMovieClip ("oef1000" + i, 100);
        this["oef1000" + i].onEnterFrame = function () {
            total = eval ("bildcont" + i).getBytesTotal ();
            geladen = eval ("bildcont" + i).getBytesLoaded ();
            prozent = Math.round ((geladen / total) * 100);
            if (geladen >= total && geladen > 10) {
                delete this["oef1000" + i].onEnterFrame;
                i++;
                weiter ();
            }
        };
    }
}
weiter(); 

[tonymeman]

Tach Rusty, Tach Majo, natürlich funktioniert euer Skript, es ist aber nicht das, was ich gesucht habe, da bei eurem Skript für jedes einzelne Bild ein Ladestatus angezeigt wird.

Ich hab das ganze jetzt mal etwas umgeschrieben, so dass es eine Gesamt-Ladestatusanzeige über alle Bilder gibt und der Film auch erst dann weiterspielt, wenn alle Bilder geladen sind.

Wäre cool wenn mir jemand noch einen kleinen, in Größe und Farbe veränderbaren Ladebalken einbauen könnte.

stop();
anzahl = 3;
for (i=1; i<=anzahl; i++) {
    _root.createEmptyMovieClip("img"+i, i+20);
    _root["img"+i].loadMovie("bild"+i+".jpg");
    _root["img"+i]._alpha = 0;
}
 
_root.createTextField("txt", 50, 10, 30, 130, 20);
 
this.loader_funk = function() {
    t = 0;
    l = 0;
    for (i=1; i<=anzahl; i++) {
        t += _root["img"+i].getBytesTotal();
        l += _root["img"+i].getBytesLoaded();
    }
    if (l>=4) {
        pt = Math.ceil((l/t)*100);
        _root.txt.text = pt+" % geladen";
        if (pt >= 100) {
            _root.txt.removeTextField();
            clearInterval(loadID);
            for (i=1; i<=anzahl; i++) {
                _root["img"+i]._alpha = 100;
            }
            _root.play();
        }
    }
};
loadID = setInterval(loader_funk, 10); 

[RustyCake]

Müßte dann eigentlich gehen!

pt = Math.ceil((l/t)*100);
_root.balken_mc._xscale = pt;
_root.txt.text = pt+" % geladen"; 

[Majo]

oder wenn du zu faul bist einen balken_mc zu erstellen, dann lass es AS machen...

var startx = 300;
// x-anfansgskoordinaten des balkens
var starty = 200;
// y-anfangskoordinaten des balkens
var breite = 200;
// hier die breite des balkens einstellen
var hoehe = 2;
// hier die hoehe des balkens einsellen
var farbe = 0xff00ff;
// hier die farbe des balkens einstellen
var alpha = 100;
// hier den alphawert (durchsichtigkeit) des balkens einstellen
 
// zeichnen des balkens
_root.createEmptyMovieClip("balken_mc", 1);
// erstellt ein mc
balken_mc._x = startx;
balken_mc._y = starty;
with (balken_mc) {
    beginFill(farbe, alpha);
    lineTo(0, hoehe);
    lineTo(breite, hoehe);
    lineTo(breite, 0);
    lineTo(0, 0);
    endFill();
};
anzahl = 3;
for (i=1; i<=anzahl; i++) {
        _root.createEmptyMovieClip("img"+i, i+20);
        _root["img"+i].loadMovie("bild"+i+".jpg");
        _root["img"+i]._alpha = 0;
}
 
_root.createTextField("txt", 50, 10, 30, 130, 20);
 
this.loader_funk = function() {
        t = 0;
        l = 0;
        for (i=1; i<=anzahl; i++) {
                t += _root["img"+i].getBytesTotal();
                l += _root["img"+i].getBytesLoaded();
        }
        if (l>=4) {
                pt = Math.ceil((l/t)*100);
                _root.txt.text = pt+" % geladen";
                _root.balken_mc._xscale = pt;
                if (pt >= 100) {
                        _root.txt.removeTextField();
                        _root.balken_mc.removeMovieClip();
                        clearInterval(loadID);
                        for (i=1; i<=anzahl; i++) {
                                _root["img"+i]._alpha = 100;
                        }
                        _root.play();
                }
        }
};
loadID = setInterval(loader_funk, 10); 

@rusty...das wir uns immer in den loader-threads treffen ?!?