Kreismenu von Fla6 auf Fla7

[hugeinc]

Hi zusammen,
ich hab hier ein Kreismenu zusammengebastelt.

Das Problem ist, dass es jetzt in Flash (MX 2004 prof) nicht mehr funktioniert. Ich such jetzt schon seit 2,5 Stunden und find einfach den Fehler nicht. Hat einer von Lust und Zeit, mal zu schauen und mir nen Tipp zu geben?
Mein Framescript:

MovieClip.prototype.drehscheibeInit = function(elast, ratio, snapsteps) {
    this.rotate = false;
    this.elast = elast;
    this.ratio = ratio;
    this.winkel = _rotation;
    this.ziel = this.winkel;
    if (arguments.length == 3) {
        snap = true;
        this.snapdist = snapdist;
    }
};
MovieClip.prototype.drehscheibe = function() {
    if (this.startrotate) {
        this.startrotate = false;
        this.rotate = true;
        this.offset = 180*Math.atan2(this._parent._ymouse-this._y, this._parent._xmouse-this._x)/Math.PI-this.ziel;
    }
    if (this.rotate) {
        this.ziel = 180*Math.atan2(this._parent._ymouse-this._y, this._parent._xmouse-this._x)/Math.PI-this.offset;
    }
    if (this.ziel>360) {
        this.ziel -= 360;
    }
    if (this.ziel<-360) {
        this.ziel += 360;
    }
    // einrasten
    if (this.snap) {
        this.ziel = Math.round(this.ziel/this.snapdist)*this.snapdist;
    }
    var diff = this.ziel-this.winkel;
    while (diff>180) {
        diff -= 360;
    }
    while (diff<-180) {
        diff += 360;
    }
    this.drehung = this.drehung*this.elast+diff*this.ratio;
    this.winkel += this.drehung;
    if (this.winkel>360) {
        this.winkel -= 360;
    }
    if (this.winkel<0) {
        this.winkel += 360;
    }
    this._rotation = this.winkel;
};
stop(); 

Das liegt auf den Kreisclips:

onClipEvent (load) {
    drehscheibeInit(0.05,0.2);
}
onClipEvent (enterFrame) {
    drehscheibe();
} 

Und das auf den Buttons in den Clips:

on (press) {
    startrotate=true;
}
on (release, releaseOutside) {
    rotate=false;
} 

Wäre klasse, wenn einer von euch nen Tipp hätte.
Greets, Micha

[FlashKasper]

Hi hugeinc

this.drehung = 0;

muss in drehscheibeInit initialisiert werden bzw. musst du die Variable vorher auf 0 setzen, sonst kann Flash7 mit der Variablen nicht rechnen.

Unter Flash 6 wurden alle nicht vorher initialisierten Variabeln immer mit 0 gesetzt, bei Flash 7 ist das nicht mehr der Fall.

Gruss
FlashKasper

[hugeinc]

Hi Kaspar,

sorry, wenn ich jetzt antworte. 2muchWork :-((

Hab deine Tipp direkt getestet und ... ´s läuft einwandfrei.
1000 Dank, Micha

> vorher initialisierten Variabeln
Jetzt weiss ich auch, warum so einige andere Dinge bei mir nicht liefen.

Greets, Micha