Kontakt Formular kommt immer leer an...

[Noti]

Hallo Leute,

:: RK :: hat ein tolles Kontaktformular gemacht, welches bei mir leider nur teilweise funktioniert. Das Formular wird geschickt, jedoch kommt es "leer" an. Ich habe alles mir mögliche getan, aber ich komme einfach nicht auf die Lösung.

Das Script in der SWF ist:

PHP-Code:

///////////////////////////////////////////////////////////////////////////////
//
var txtFeldArr:Array = ["txtName", "txtVorname", "txtStrasse", "txtOrt", "txtTel", "txtFax", "txtEmail", "txtWeb", "txtMessage"];
var txtLabelArr:Array = ["Name", "Vorname", "Straße", "PLZ/Ort", "Telefon", "Fax", "Email", "Website", "Nachricht"];
//
///////////////////////////////////////////////////////////////////////////////
//
TextField.prototype.setOldContent = function() {
    this.text = txtLabelArr[this.i];
};
//----------------------------------------------------------------------------
TextField.prototype.setOldTxtStyle = function() {
    this.textColor = "0x777777";
    this.borderColor = "0x999999";
    this.backgroundColor = "0x000000";
};
//----------------------------------------------------------------------------
// 
TextField.prototype.setNewTxtStyle = function() {
    this.textColor = "0x000000";
    this.borderColor = "0x003399";
    this.backgroundColor = "0xB0B0FF";
};
//----------------------------------------------------------------------------
TextField.prototype.checkForOldContent = function() {
    if (this.text == txtLabelArr[this.i]) {
        return true;
    }
};
// ---------------------------------------------------------------------------
TextField.prototype.checkIfEmpty = function() {
    if (this.text == "") {
        return true;
    }
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncInit = function () {
    mcFormular.txtStatus.textColor = "0xFF0000";
    mcFormular.txtStatus.text = "";
    // ----------------------------------------------------------
    for (i=0; i<txtFeldArr.length; i++) {
        mcFormular[txtFeldArr[i]].text = txtLabelArr[i];
        mcFormular[txtFeldArr[i]].tabIndex = i+1;
        mcFormular[txtFeldArr[i]].setOldTxtStyle();
        mcFormular[txtFeldArr[i]].i = i;
        mcFormular[txtFeldArr[i]].onSetFocus = function() {
            this.setNewTxtStyle();
            if (this.checkForOldContent()) {
                this.text = "";
            }
        };
        mcFormular[txtFeldArr[i]].onKillFocus = function() {
            this.setOldTxtStyle();
            if (this.checkIfEmpty()) {
                this.setOldContent();
            }
        };
    }
    // ----------------------------------------------------------
    mcFormular.btnClear.onRelease = function() {
        this.txtLabel._x = this.txtLabel._y -= 1;
        fncInit();
    };
    mcFormular.btnSend.onRelease = function() {
        this.txtLabel._x = this.txtLabel._y -= 1;
        fncSend(mcFormular);
    };
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncSend = function (mc) {
    var felderVoll:Boolean = false;
    var trueEmail:Boolean = false;
    for (var i = 0; i<txtFeldArr.length; i++) {
        if ((mc[txtFeldArr[i]].text == "") || (mc[txtFeldArr[i]].text == txtLabelArr[i])) {
            mc[txtFeldArr[i]].textColor = "0xFF0000";
            mc.txtStatus.text = "Bitte füllen Sie alle Felder korrekt aus!";
            felderVoll = false;
        } else {
            felderVoll = true;
        }
        // --------------------------------------------------------------------
        if ((mc.txtEmail.text.indexOf("@")<2) || (mc.txtEmail.text.indexOf(".")<5)) {
            mc.txtEmail.textColor = "0xFF0000";
            mc.txtStatus.text = "Bitte füllen Sie alle Felder korrekt aus!";
            trueEmail = false;
        } else {
            trueEmail = true;
        }
    }
    // ------------------------------------------------------------------------
    if ((felderVoll == true) && (trueEmail == true)) {
        var receiveData:LoadVars = new LoadVars();
        receiveData.onLoad = function(success) {
            getURL("javascript:alert('PHP GELADEN')");
            if (success) {
                if (receiveData.infoOk) {
                    getURL("javascript:alert('OK: EMAIL GESENDET')");
                    mc.txtStatus.textColor = "0x00CC00";
                    mc.txtStatus.text = "Daten wurden erfolgreich gesendet";
                    delete receiveData;
                    delete sendData;
                } else {
                    getURL("javascript:alert('FEHLER: EMAIL NICHT GESENDET')");
                    mc.txtStatus.textColor = "0xFF0000";
                    mc.txtStatus.text = "Daten konnten leider nicht gesendet werden!";
                }
            }
        };
        // 
        var sendData:LoadVars = new LoadVars();
        for (var i = 0; i<txtFeldArr.length; i++) {
            sendData[txtFeldArr[i]] = mc[txtFeldArr[i]].text;
        }
        // 
        sendData.sendAndLoad("flashMail.php", receiveData, "POST");
        mc.txtStatus.textColor = "0xFF0000";
        mc.txtStatus.text = "Daten werden gesendet ...";
    }
};
//
///////////////////////////////////////////////////////////////////////////////
//
mcFormular.btnClear.txtLabel.text = "löschen";
mcFormular.btnSend.txtLabel.text = "senden";
mcFormular.btnClear.txtLabel.textColor = "0xA8A8FF";
mcFormular.btnSend.txtLabel.textColor = "0xA8A8FF";
//----------------------------------------------------------------------------
mcFormular.btnClear.onRollOver = mcFormular.btnSend.onRollOver=function () {
    this.txtLabel.textColor = "0xFFFFFF";
};
mcFormular.btnClear.onRollOut = mcFormular.btnSend.onRollOut=function () {
    this.txtLabel.textColor = "0xA8A8FF";
};
//----------------------------------------------------------------------------
mcFormular.btnClear.onPress = mcFormular.btnSend.onPress=function () {
    this.txtLabel._x = this.txtLabel._y += 1;
};
mcFormular.btnClear.onReleaseOutside = mcFormular.btnSend.onReleaseOutside=function () {
    this.txtLabel.textColor = "0x000000";
    this.txtLabel._x = this.txtLabel._y -= 1;
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncInit(); 


An dieser Stelle hab ich auch schon "GET" anstatt "POST" geschrieben. Resultat das selbe.

sendData.sendAndLoad("flashMail.php", receiveData, "POST");

Das PHP File sieht so aus:

PHP-Code:

<?

$myMail = "gianninotari@hotmail.com";

$nowDay = date("d.m.Y");
$nowClock = date("H:i:s");

$message = "
Empfangen am $nowDay um $nowClock:
----------------------------------------------------------------------------

Vorname: $GLOBALS[txtVorname]
Name:    $GLOBALS[txtName]
Strasse: $GLOBALS[txtStrasse]
PLZ/Ort: $GLOBALS[txtOrt]
Tel:     $GLOBALS[txtTel]
Fax:     $GLOBALS[txtFax]
Email:   $GLOBALS[txtEmail]
Web:     $GLOBALS[txtWeb]


Nachricht:
-----------------------------
$GLOBALS[txtMessage]


----------------------------------------------------------------------------
";

$header = "From:$GLOBALS[txtEmail]";
$subject = "Email Anfrage";


$mail1 = mail($myMail, $subject, utf8_decode(urldecode($message)), $header);

echo "infoOk=$mail1";

?>

Alles Dateien findet ihr hier:

http://gi-dance.ch/test/

Wäre cool, wenn mir jemand helfen könnte. Ich bin nämlich beinahe am durchdrehen ^^.

Gruss,

Noti

[:: RK ::]

hi,

hast du das mit "GET" und "POST" auf in der PHP Datei angepasst???

[Noti]

Hi,

Der Meister höchst persönlich. Du bist echt ein toller typ. Eine Frage und schon bist du zur Stelle.

Zu deiner Frage:
Nein, was muss ich denn anpassen?

Nebenbei:
Die aktuelle PHP Version des Servers ist: PHP 4.3.10

Die andere Frage, was die Rechte angeht:

Welche dateien muss ich welche Rechte geben... Braucht es "777"?

[:: RK ::]

hi,

ja, ich lass mich ab und zu zu euch Fußvolk runter

ne spaß ... also in der PHP Datei musst du folgendes machen

GET in Flash -> $_GET[...] in PHP
POST in Flash -> $_POST[..] in PHP

PHP Version passt, an den Rechten musst du nix ändern.
Ganz normal per FTP hochladen.



Mit $GLOBALS[...] kannst du ALLE Variablen von PHP ansprechen
(bis auf SESSIONS, die haben nen eigenen Container), doch manchmal
wird das vom Webhoster deaktiviert.

[Noti]

Nachdem dass ich die PHP Datei mit POST angeglichen habe hats funktioniert.

Danke viel mals. Das Formular ist toll, und dass du so schnell reagiert hast find ich riesig. Mach weiter so.

Gruss,

Noti

[:: RK ::]

jo, kein thema