Komische Fehlermeldung

[thkolz]

Hallo,

ich habe eine Klasse, die Daten aus einer XML mittels der Delegate-Klasse laden soll.
Das Beispiel ist aus dem Flash-Online-Tutorial.

Ich bekomme immer folgende Fehlermeldung:

**Fehler** D:\Flash\SomeClassThatUsesLoadedXML.as: Zeile 15: Keine Methode mit dem Namen 'Delegate' vorhanden.
     		xmlData.onLoad=Delegate.create(this,processXML);

Anzahl der ActionScript-Fehler: 1 	 Gemeldete Fehler: 1

Das ist die Klasse:

PHP-Code:

import mx.utils.Delegate;

class SomeClassThatUsesLoadedXML{ // with Delegate class

    private var inited:Boolean=false;
    private var xmlData:XML;
    
    function SomeClassThatUsesLoadedXML(){
        if(!inited) {
            init();
        }
    }
    private function init() {
        xmlData=new XML();
        xmlData.onLoad=Delegate.create(this,processXML);
        inited=true;
    }
    private function processXML():Void {
        trace("Load event fired on: "+this + "\nXML data: "+ xmlData);
    }
    public function loadXML(urlPath:String):Void {
        xmlData.load(urlPath);
    }
    public function toString() {
        return "[SomeClassThatUsesLoadedXML]";
    }
} 


Das steht im FLA-File:

PHP-Code:

import SomeClassThatUsesLoadedXML;
var experimental:SomeClassThatUsesLoadedXML=new SomeClassThatUsesLoadedXML();
experimental.loadXML("daten.xml"); 


Und ja, die beiden Dateien liegen im gleichen Verzeichnis

Ich hab's mal hochgeladen. Wäre super, wenn sich jemand das mal anschauen könnte!

[artjom]

mach mal die import anweisung weg und schreib:

PHP-Code:

xmlData.onLoad=mx.utils.Delegate.create(this,processXML); 


gruß

[shorty]

kolz, mal was anderes, wofür bitte dieser aufwand?

[thkolz]

Dann kommt folgende Meldung:

**Fehler** D:\Flash\SomeClassThatUsesLoadedXML.as: Zeile 13: Keine Methode mit dem Namen 'mx' vorhanden.
     		xmlData.onLoad=mx.utils.Delegate.create(this,processXML);  

Anzahl der ActionScript-Fehler: 1 	 Gemeldete Fehler: 1

[thkolz]

Zitat von shorty

kolz, mal was anderes, wofür bitte dieser aufwand?

Ich muss eine XML-Datei in einer Funktion überprüfen, und ohne Delegate ist das wohl nicht möglich, da ich sonst "undefined" zurückgeliefert bekomme.

Das liegt wohl daran, dass die XML-Datei erst vollständig geladen werden muss...

[shorty]

doch doch, das geht, du must nur vorher ne referenz auf die klasse setzen

PHP-Code:

class foo {
    public function bla() {
        trace('hello world!');
    }
    public function init():Void {
        var _c:foo = this;
        var x:XML = new XML();
        x.ignoreWhite = true;
        x.onLoad = function(ok) {
            if (ok) {
                // mit ref läuft ...
                _c.bla();
                // ohne ref läuft nicht ...
                bla();
            }
        };
        x.load('file.xml');
    }
} 


[thkolz]

Wo soll ich was referenzieren?

In der Klasse?

So, wie deine Funktion aufgebaut ist, mache ich das bei mir in der FLA auch, aber das bringt mich leider nicht weiter.

Ich würde es ja auch lieber einfach machen, aber das geht leider nicht.

[shorty]

wat möchtest du denn haben, soll die xml schon bei der instanzierung geladen werden, oder solls flexibel sein?

[thkolz]

Ja, die XML soll direkt am Anfang geladen werden, so dass ich in der FLA immer darauf zugreifen kann...

[shorty]

ok, und wenn ich es richtig verstanden habe, soll das nur genau einmal geschehen. sprich, die einmal geladene xml bzw. das xmlData object darf nicht wieder überschrieben, soll aber überprüft werden?!?

[thkolz]

Genau.

Am anfang werden die Werte in zwei ComboBoxen geladen (Produkt und Modell).

Innerhalb einer Button.onClick-Funktion werden dann die Elemente der in den Comboboxen ausgwählten Werte, die in eine Liste eingefügt wurden, in einer ScrollPane dargestellt.

Dabei muss überprüft werden, ob ein Produkt einer bestimmten Marke vorliegt. Wenn ja, dann wird die Ausgabe etwas geändert.

Mit der Funktion, die das überprüft, habe ich so meine Probleme.

Deswegen wäre es super, wenn ich am Anfang die XML-Datei einlesen könnte, und dann immer darauf zugreifen kann.

[shorty]

ahhh, ok.

demnach "brauchst" du eine funktion / methode, welche zu aller erst die betreffende xml lädt, und eine, welche auf zuruf per parameter die xml durch-forstet, und guckt, ob zum parameter (marke) ein eintrag (produkt) vorhanden ist?!?


wenn ja, dann stopf doch pls. mal deine xml struktur in den anhang (bitte nur n auszug, so das man sieht, wie sie aufgebaut ist)

[Janoscharlipp]

Könnte es sein, dass du an den Klassenpfaden von Flash rumgespielt hast?
(Bearbeiten -> Voreinstellungen -> ActionScript -> AS 2.0 Einstellungen)
Da sollte auf jeden Fall ein Eintrag „$(LocalData)/Classes“ drinn sein.

[thkolz]

Zitat von Janoscharlipp

Könnte es sein, dass du an den Klassenpfaden von Flash rumgespielt hast?
(Bearbeiten -> Voreinstellungen -> ActionScript -> AS 2.0 Einstellungen)
Da sollte auf jeden Fall ein Eintrag „$(LocalData)/Classes“ drinn sein.

Da hab ich nichts dran gemacht. Das stimmt alles...

@shorty:
So sieht meine XML-Datei aus:

PHP-Code:

<?xml version="1.0" encoding="UTF-8"?>
<Import>
    <Row>
        <Producer>H6</Producer>
        <Model>T17</Model>
        <Field3> </Field3>
        <Field4>2 Aout 2005</Field4>
        <Field5>12150</Field5>
        <Field6>69 / 94</Field6>
        <Field7>(540)</Field7>
        <Field8>3510</Field8>
        <Field9>2780</Field9>
        ....
    </Row>
    </Import>

Es sind eigentlich 51 Elemente...

[shorty]

Ik habe in der zeit mal n kleines bsp gebastelt, schau dir dit mal an.
XML - Productkatalog

<?xml version='1.0' encoding='utf-8'?>
<products>
    <label id="levis">
	<item name="501" size="30/30"></item>
	<item name="501" size="32/30"></item>
	<item name="501" size="34/30"></item>
	<item name="401" size="32/32"></item>
	<item name="401" size="32/34"></item>
	<item name="401" size="34/30"></item>
    </label>
    <label id="diesel">
	<item name="seatle" size="29/30"></item>
	<item name="garbage" size="36/34"></item>
	<item name="shorty" size="128"></item>
    </label>
</products>

Klasse - Catalog

PHP-Code:

class Catalog {
    
    private var products:XML;
    private var loaded:Boolean;
    
    function Catalog() {
        loaded = false;
        load('products.xml');
    }
    
    private function load(source:String):Void {
        var _c:Catalog = this;
        products = new XML();
        products.ignoreWhite = true;
        products.onLoad = function(ok) {
            if (ok) {
                _c.loaded = true;
            }
        };
        products.load(source);
    }
    
    public function search(label:String, item:String):Void {
        if (loaded == true) {
            var check:Boolean = false;
            var n:Array = products[label].childNodes;
            if (n) {
                for (var i = 0; i < n.length; i++) {
                    if (n[i].attributes.name == item) {
                        check = true;
                        break;
                    }
                }
                if (check == true) {
                    trace('Label: "' + label + '" & item: "' + item + '" found!');
                    // deine aktionen ...
                } else {
                    // deine aktionen ...
                    trace('Label: "' + label + '" found! But not hit for item: "' + item + '"');
                }
            } else {
                // deine aktionen ...
                trace('Sorry, label not in catalog!');
            }
        } else {
            // deine aktionen ...
            wait(label, item);
        }
    }
    
    private function wait(label:String, item:String):Void {
        var _c:Catalog = this;
        trace('Please wait a second. Loading catalog ...');
        var ivWait = setInterval(function () {
            if (_c.loaded == true) {
                clearInterval(ivWait);
                _c.search(label, item);
            } else {
                trace('Please wait a second. Loading catalog ...');
            }
        }, 1000);
    }
    
} 


Timeline

PHP-Code:

var Products:Catalog = new Catalog();
//              label   |  item
Products.search('diesel', 'shorty'); 


An den Stellen, wo ich ein Trace geschrieben habe, könnte man eine simplen return true oder false, oder was dir sonst so einfällt setzen, um die suchanfrage auszuwerten.

Die methoden und der constructor sind aufgrund fehlender infos nur hin geklatscht. möglich wäre z.B. auch eine suche, in speziellen katalogen (unterschiedlichen *.xml files), welche als parameter übergeben, und bei erfolgreichem ladevorgang durchsucht werden ...


shorty

{edit} der schlüssel zum erfolg ist in jedem fall eine gut strukturierte xml datei ...