Klassenmethode in Eventhandler aufrufen

[p-flash]

Hi,

ich habe eine Klasse Gegner1. Davon erstelle ich ein Objekt einGegner1.
Dieses Objekt übergebe ich als Initialisierung der Methode attachMovie.

Ich will dass das Mc das attached wurde direkt
onEnterFrame = function() { this.bewegen(); }; besitzt, wobei bewegen() als prototype in der Klasse Gegner1 erstellt wurde.

Ich habe es so versucht, aber das geht nicht

PHP-Code:

_global.Grenze = 200;
_global.GegnerTiefe = 300;
// Klasse Gegner1 erstellen
function Gegner1(pX, pY, pEnergie, pGeschwindigkeit, pWaffe, pAnzahlSchuss)
{
    this._x = pX;
    this._y = pY;
    this.Energie = pEnergie;
    this.Geschwindigkeit = pGeschwindigkeit;
    this.Waffe = pWaffe;
    this.AnzahlSchuss = pAnzahlSchuss;
    // Aktuellen Tiefe-Stand erhoehen
    ++_global.GegnerTiefe;
}
Gegner1.prototype.schiessen = function()
{
    trace(34);
    _root.attachMovie(this.Waffe, this.Waffe + _global.GegnerSchussTiefe, _global.GegnerSchussTiefe);
}
Gegner1.prototype.bewegen = function()
{
    trace("hallo");
    this._x -= this.Geschwindigkeit;
    /*if(this._x < _global.Grenze)
    {
        this.onEnterFrame = this.schiessen;
    }*/
};

var einGegner1 = new Gegner1(Stage.width, 30, 100, 5, null, 10);

einGegner1.onEnterFrame = function { this.bewegen(); };
this.attachMovie("gegner1_mc", "gegner1_mc"+_global.GegnerTiefe, _global.GegnerTiefe, einGegner1); 


Das klappt aber nicht. Wenn ich aber
einGegner1.onEnterFrame = function() { this._x -= 5; };
klappt es. Wieso wird die Funktion bewegen im onEnterFrame nicht aufgerufen? einGegner1.bewegen() klappt.

Bin dankbar für jeden Tip.

p-flash

[Scrawer]

du gehst das etwas falsch an...

du musst deine class gegner auch erst von der movieclip class erben lassen...leider reicht das bei flash selber so noch nicht aus... da eben durch new MovieClip kein movieclip container erstellt wird... für das gibt es dann noch registerClass.....

ein kleines beispiel..... erstell in der Library einen MovieClip für deinen Gegner und vergibt die ID: "ENEMY_MOVIECLIP"

function EnemyClass()
{
    // constructor
}
 
// extends MovieClip Class
EnemyClass.__proto__ = MovieClip.prototype;
 
// methode
EnemyClass.prototype.moveRight = function()
{   
    this.onEnterFrame = function()
    {
        this._x += 10;
        
        if (this._x > 200)
        {
            delete this.onEnterFrame;
        }
    }
}
 
// class registrieren
Object.registerClass("ENEMY_MOVIECLIP", EnemyClass);
 
// instanz erstellen 
_root.attachMovie("ENEMY_MOVIECLIP", "enemyA", 1);
 
_root.enemyA.moveRight(); 

das sollte dich weiterbringen

[p-flash]

Hammer. Danke.

Wie kann ich aber Argumente übergeben, um die attachten Mcs verschiedene initalisierungswerte zu geben?

Nochmals Danke.

p-flash

[Scrawer]

du kannst dem attachMovie ein initObject übergeben.... für die setter, da werden dann MovieClip setter und wenn vorhanden setter der EnemyClass ausgeführt...

wenn du jedoch beim erstellen einer class instanz parameter setzen möchtest.... welche nicht per "new" sondern mit "registerClass" und "attachMovie" erstellt wird, geht das nur über eine zusätzliche "init" methode.....

[p-flash]

hmm...kannst du ein Beispiel machen. verstehe es nicht ganz.

danke.

p-flash

[Scrawer]

// constructor
function EnemyClass() 
{
    this.__isInitialize = false;
} 
 
// extends MovieClip Class 
EnemyClass.__proto__ = MovieClip.prototype; 
 
// init methode 
EnemyClass.prototype.init = function(x, y, energy) 
{    
    if (!this.__isInitialize)
    {
        // __isInitialize stellt sicher das die init methode nur einmal ausgeführt wird
        this.__isInitialize = true;
 
        this._x = x;
        this._y = y;
        this.__energy = energy;
 
        return this;
    }
}
 
// methode 
EnemyClass.prototype.moveRight = function() 
{    
}
 
//----
 
// class registrieren 
Object.registerClass("ENEMY_MOVIECLIP", EnemyClass); 
 
// instanz erstellen 
var enemy = _root.attachMovie("ENEMY_MOVIECLIP", "enemyA", 1).init(0, 0, 100);
enemy.moveRight(); 

[p-flash]

GENIAL!! Vielen Dank!

p-flash