kann man das noch optimieren ???

[:: RK ::]

hi,

inspiriert durch dieses Game:
http://www.flashforum.de/forum/showt...hreadid=127086

hab ich mich mal drann gesetzt, um die steuerung nachzubauen.
nun wollt ich euch fragen ob das auch einfacher geht bzw. ob man
das noch optimieren kann ???

is noch ganz frisch aus der AS schmiede

kL = new Object();
kL.onKeyDown = function() {
    if (Key.getCode() == 38) {
        flyObj.yDir = "up";
        flyObj.gotoAndStop(4);
    }
    if (Key.getCode() == 37) {
        flyObj.xDir = "left";
        flyObj.gotoAndStop(2);
    }
    if (Key.getCode() == 39) {
        flyObj.xDir = "right";
        flyObj.gotoAndStop(3);
    }
};
//
kL.onKeyUp = function() {
    if (Key.getCode() == 38) {
        flyObj.yDir = "down";
    }
    if ((Key.getCode() == 37) || (Key.getCode() == 39)) {
        flyObj.xDir = "center";
    }
    flyObj.gotoAndStop(1);
};
//------------------------------------------------------------
MovieClip.prototype.moveDown = function() {
    this.ySpeed += this.yAcceleration;
};
//
MovieClip.prototype.center = function() {
    if (this.xSpeed>0) {
        this.xSpeed -= this.xAcceleration/2;
    }
    if (this.xSpeed<0) {
        this.xSpeed += this.xAcceleration/2;
    }
};
//
MovieClip.prototype.moveUp = function() {
    this.ySpeed -= this.yAcceleration;
};
//
MovieClip.prototype.moveLeft = function() {
    this.xSpeed -= this.xAcceleration;
};
//
MovieClip.prototype.moveRight = function() {
    this.xSpeed += this.xAcceleration;
};
//
MovieClip.prototype.fly = function() {
    this.onEnterFrame = function() {
        if (this.yDir == "up") {
            this.moveUp();
        }
        if (this.yDir == "down") {
            this.moveDown();
        }
        if (this.xDir == "left") {
            this.moveLeft();
        }
        if (this.xDir == "right") {
            this.moveRight();
        }
        if (this.xDir == "center") {
            this.center();
        }
        if (this._y>Stage.height) {
            this._y = 0-this._height;
        } else if (this._y<(0-this._height)) {
            this._y = Stage.height;
        }
        if (this._x>Stage.width) {
            this._x = 0-this._width;
        } else if (this._x<(0-this._width)) {
            this._x = Stage.width;
        }
        this._y += this.ySpeed;
        this._x += this.xSpeed;
    };
};
//------------------------------------------------------------
Key.addListener(kL);
flyObj = mc1;
flyObj.yAcceleration = 0.1;
flyObj.xAcceleration = 0.1;
flyObj.ySpeed = 0;
flyObj.xSpeed = 0;
flyObj.yDir = "down";
flyObj.xDir = "center";
flyObj.fly(); 

wer's mal testen will, copy&paste ins erste Frame, nen kleinen
kreis zeichnen und "mc1" nennen, Registrierungspunkt: links oben.

[:: RK ::]

ok, hab gemerkt, dass die ganzen PROTOTYPEN nicht nötig sind

Stage.scaleMode = "noScale";
Stage.align = "TL";
Stage.showMenu = false;
//
kL = new Object();
kL.onKeyDown = function() {
    if (Key.getCode() == 38) {
        flyObj.yDir = "up";
    }
    if (Key.getCode() == 37) {
        flyObj.xDir = "left";
    }
    if (Key.getCode() == 39) {
        flyObj.xDir = "right";
    }
};
//
kL.onKeyUp = function() {
    if (Key.getCode() == 38) {
        flyObj.yDir = "down";
    }
    if ((Key.getCode() == 37) || (Key.getCode() == 39)) {
        flyObj.xDir = "center";
    }
    flyObj.gotoAndStop(1);
};
//------------------------------------------------------------
MovieClip.prototype.fly = function() {
    this.onEnterFrame = function() {
        //
        if (this.yDir == "up") {
            this.ySpeed -= this.yAcceleration;
            this.gotoAndStop(4);
        }
        if (this.yDir == "down") {
            this.ySpeed += this.yAcceleration;
        }
        if (this.xDir == "left") {
            this.xSpeed -= this.xAcceleration;
            this.gotoAndStop(2);
        }
        if (this.xDir == "right") {
            this.xSpeed += this.xAcceleration;
            this.gotoAndStop(3);
        }
        if (this.xDir == "center") {
            if (this.xSpeed>0) {
                this.xSpeed -= this.xAcceleration/5;
            }
            if (this.xSpeed<0) {
                this.xSpeed += this.xAcceleration/5;
            }
        }
        //
        if ((this.xDir == "left") && (this.yDir == "up")) {
            this.gotoAndStop(6);
        }
        if ((this.xDir == "right") && (this.yDir == "up")) {
            this.gotoAndStop(5);
        }
        //
        if (this._y>Stage.height) {
            this._y = 0-this._height;
        } else if (this._y<(0-this._height)) {
            this._y = Stage.height;
        }
        if (this._x>Stage.width) {
            this._x = 0-this._width;
        } else if (this._x<(0-this._width)) {
            this._x = Stage.width;
        }
        this._y += this.ySpeed;
        this._x += this.xSpeed;
    };
};
//------------------------------------------------------------
Key.addListener(kL);
flyObj = mc1;
flyObj.yAcceleration = 0.05;
flyObj.xAcceleration = 0.05;
flyObj.ySpeed = 0;
flyObj.xSpeed = 0;
flyObj.yDir = "down";
flyObj.xDir = "center";
flyObj.fly(); 

aber sonst ???

[Novanic]

Hi!

Ich würde anstatt der ganzen IF-Abfragen (mindestens bei den Key ...), Case (Switch/Case) verwenden. Das wäre auf jedenfall eine Optimierung.

:-)

Gruß Nova

[juggernart]

Die Frage ist, nach was du optimieren willst?
Willst du nen Schönheitswettbewerb mit deinem code gewinnen oder bessere Performance?

switch/case ist bestenfalls ne optische Verbesserung. Bei Performance-Tests mit if/else if und switch/case ergibt sich bei mir praktisch immer dasselbe.

auch interessant: http://www.oddhammer.com/actionscriptperformance/

[Novanic]

Hi,

ich glaub schon das Switch/Case schneller läuft als IF THEN ELSE! Ich glaube kaum das bei Switch/Case intern das gleiche abläuft wie bei IF.

Gruß Nova

[juggernart]

Glauben und Wissen ist ein Unterschied

t = getTimer();
for (i=0; i<10000; i++) {
    k++;
    if (k == 1) {
    } else if (k == 2) {
    } else if (k == 3) {
    } else if (k == 4) {
    } else if (k == 5) {
        k = 0;
    }
}
t = getTimer()-t;
output_txt.text = t;
//
t = getTimer();
for (i=0; i<10000; i++) {
    k++;
    switch (k) {
    case 1 :
        break;
    case 2 :
        break;
    case 3 :
        break;
    case 4 :
        break;
    case 5 :
        k = 0;
    }
}
t = getTimer()-t;
output_txt.text += "\r"+t; 

[Novanic]

Aber das wird der Compiler/Interpreter intern ja wohl kaum genau so machen wie IF THEN ELSE! Der Compiler/Interpreter springt dann ja direkt zu dem entsprechenden Wert und prüft nicht jede Anweisung einzelnt durch! Das hat 100pro andere Gründe als optik, die Optik wird ja nicht mal besser und bei z.B. C++ haben die Switch/Case mit Sicherheit nicht für die Optik erfunden!

Es wird ja nicht jeder Wert geprüft, sondern direkt zu dem entsprechenden Wert gesprungen! Und wenn es wirklich genau das Gleiche wäre, warum sieht das Strukturgramm von Switch/Case dann auch völlig anders aus als bei IF THEN ELSE?

Gruß Nova

[Janoscharlipp]

naja, wie das intern aussieht, kannste dir ja einfach mal mit Flashm ansehen, jedenfalls ist die switch/case-Struktur im Schnitt etwas langsamer.

[juggernart]

Ehrlich gesagt ist es mir wurscht, wie Flash die Anweisungen intern abarbeitet.
Mich interessiert nur, was schneller ist, und das kann man mit solchen Tests nachprüfen.

Nicht, dass ich hier klugschei..ern möchte, aber was letztlich zählt sind doch die Fakten.

[mati]

hi RK,

also, zumindest bei der Version mit IF-Abfragen kannst du noch einige Zeit rausholen wenn du ans ende jedes IF-Blocks ein return; einfügst, denn sobald die Taste gefunden wurde müssen die anderen Abfragen ja nicht mehr durchgeführt werden


grüße, mati

[:: RK ::]

hi,

danke mati, endlich ne vernünftige antwort
und kannst du auch erklären, warum das so ist ???

wenn nicht, ist das auch net schlimm, würd ich halt
interessieren

[mati]

hi RK,

klar, kein prob.

return:

Beschreibung
Aktion; gibt den von einer Funktion zurückgegebenen Wert an. Die Aktion return wertet ausdruck aus und gibt das Ergebnis als Wert der Funktion zurück, in der sie ausgeführt wird. Die Aktion return beendet die Funktion und ersetzt sie durch den Rückgabewert. Wenn die Anweisung return alleine verwendet wird, wird null zurückgegeben.

das heißt in unserm fall, dass die funktion also beendet wird und "null" zurückgegeben wird. das ist uns egal, weil wir von der fkt ja keinen rückgabewert erwarten bzw. auswerten... folgendes beispiel zeigt vielleicht die funktionsweise am einfachsten (just copy&paste):

var testi = 2;
function test(wert) {
    trace("abfrage1");
    if (wert==1) {
        trace("1");
        return;
    }
    trace("abfrage2");
    if (wert==2) {
        trace("2");
        return;
    }
    trace("abfrage3");
    if (wert==3) {
        trace("3");
        return;
    }
    trace("alle durch");
}
test(testi); 

gruß, mati

immer noch unklar? nochmal fragen!

[:: RK ::]

Geschrieben von mati
...
immer noch unklar? nochmal fragen!

nope, alles klar, tausend dank