html-formatierten text speichern? (mit konkretem Beispiel)

[Mr.Twister]

hallo,
im moment kann ich einen (einfachen) Text per php speichern und wieder abrufen. Nun möchte ich gerne mit htmlText arbeiten.
Das Einlesen klappt, die Verwendung von Stylesheets auch.
Nachdem ich aber nun den htmlText in Flash in einem input-Textfeld bearbeitet habe, möchte ich ihn wieder per php in die html-Datei speichern.

Zwar klappt auch das, allerdings ist flash anschließend nicht mehr dazu in der Lage, diesen html-Text darzustellen.

Scheinbar geht beim Speichern durch das php-Script irgend eine Formatierung verloren. Wenn ich mir den Code in Flash tracen lasse, sehe ich, daß er ansich korrekt aussieht.

Hat jemand von euch Erfahrung damit, htmlText zu speichern?

Danke für Hilfe!

(anbei natürlich das Beispiel)

[shorty]

schade, unerwartetes dateiformat (me@MX2004pro)

[Mr.Twister]

shit, hätte ich dran denken müssen.
hier ist ne version für mx 2004

es gilt zu bedenken:
richtig testen kann man das eiegntlich nur online.
ich habe es testhalber mal auf www.vivavision.de/test liegen.

und nachdem man änderungen vorgenommen hat, zeigt er noch so lange den alten text, bis man die seite aktualisiert.

[shorty]

Jup Twister, guck dir mal den String, welcher nach dem Bearbeiten in die news.html geschrieben werden soll ganz genau an. du wirst sehen, das das php script n ganzen satz zeichen ersetzt, z.B. schreibt es vor hochkomata ein slash, was dann bei bearbeitung der datei, in der vorher folgendes stand:

<a href="shorty.html">hello world!</a>

danach so aussieht:

<a href=\"shorty.html\">hello world! </a>

flash kann nun natürlich den html text als solchen nichtmehr erkennen, und zeigt ihn somit nichtmehr an, weil nicht gültig.

[Mr.Twister]

ahjooo,
gut, also das ist dann schonmal die fehlerursache.
gute diagnose! :-)
vielen dank schonmal!

nun habe ich also beim einlesen des contents versucht, per split'n'join den backslash durch "" (also nichts) zu ersetzen, was offensichtlich nicht funzt.

besser wäre ja ohnehin, die html gleich sauber zu schreiben, anstatt die grütze nachher durch flash neu interpretieren zu lssen.

hmm ...
also ich vermute mal, daß du mich schon nah an's ziel gebracht hast.
ich fummel mal weiter.

[shorty]

Nein, nicht so umständlich, guck hier, so gehts auch mit umlauten, sonderzeichen, und und und, und vor allem ohne System.useCodepage & den üblichen split and join martathon müll...

ich habe, damit du siehst wie es läuft n template text mit allen möglichen sonderzeichen & link reingeschrieben. pass deine pfade an, drück auf senden, und danach schau'st was im textfeld bzw. der news.html steht.
TimeLine

PHP-Code:

this.stop();
//  -------------------------------------------------
var _r:MovieClip = _level0;
var _t:MovieClip = this;
//  -------------------------------------------------
function submit():Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(ok) {
        if (ok) {
            _t.txtInput.htmlText = this.content;
        }
    };
    //  achte hier auf die escape-sequenz vorm senden !
    lv.content = escape(txtInput.text);
    lv.sendAndLoad('http://localhost/_root/tester/write.php', lv, 'POST');
}
btSendAndLoad.onRelease = function() {
    submit();
};
txtInput.text = '<a href="http://www.shorty-bmc.com">!"§$%&/()=?ß,.-!?</a> shorty <b>müller</b>'; 


PHP

PHP-Code:

<?php

    $file = "news.html";
    $content = $_POST['content'];
    $content = urldecode($content);
    $content = utf8_decode($content);
    
    $src = fopen($file, "w");
    fwrite($src , $content);
    fclose($src);    

    $src = fopen($file,"r");
    $newContent = fgets($src);
    $newContent = utf8_encode($newContent);
    fclose($src);
    
    echo "&content=".$newContent;
    
?>

gruß,
shorty

[Mr.Twister]

ja wie geil ist das denn??

also es geht!

saubere sache, vielen dank, shorty!
*ordenverleih* :-)

dann werde ich es mal versuchen, auf meinen fall umzumünzen.
*bastel und fummel*

[shorty]

°lach° freut mich wenn's dich glücklich macht

sport frei, peace & fette beute
shorty

[shorty]

ahhh, lol, da war n schönheitsfehler in folgender zeile des php scripts (habs oben schon geändert)

PHP-Code:

$newContent = utf8_encode($content); 


es sollte natürlich so lauten (nicht das du denkst ich will dich ***split and join*** )

PHP-Code:

$newContent = utf8_encode($newContent); 


[darwin26]

<<--- sich auch freut über den Schnipsel ...

Danke shorty...
grz.Chris

[shorty]

hehe, hi darwin - bidde, bidde
hab's gleich mal in meine sig gepackt, kommt ja öfter vor die frage mit den umlauten o.ä.

[Mr.Twister]

soderle, habe die schönheitskorrektur auch durchgeführt :-)

[DaKinel]

Aber bitte Vorsicht mit dem '&' bei der Verwendung von escape()/unescape() und utf8_encode()/utf8_decode(). Dieses Zeichen wird nicht mit kodiert und kann für fehler sorgen .

[shorty]

Nun gut, wie herr bokelberg so schön sagt: "es muss immer noch was zum optimieren übrig bleiben" thx für den tipp @ kinel. Dann halt doch etwas split & join.

{edit} einen post weiter unten (#15), dass ganze Klassenbasiert (flash & php)

timeline

PHP-Code:

this.stop();
//  -------------------------------------------------------------------------------------------
var _r:MovieClip = _level0;
var _t:MovieClip = this;
//  -------------------------------------------------------------------------------------------
var a:Array = new Array();
//  hier die zu splitenden zeichen (thx @ daKinel :) eingeben)
a[0] = ['%', '{MODULO}'];
a[1] = ['+', '{PLUS}'];
a[2] = ['&', '{AND}'];
function check(s:String, out:Boolean):String {
    for (var i in a) {
        out == true ? s = s.split(a[i][0]).join(a[i][1]) : s = s.split(a[i][1]).join(a[i][0]);
    }
    return out == true ? escape(s) : s;
}

//  -------------------------------------------------------------------------------------------
function submit():Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(ok) {
        if (ok) {
            //  beim empfang den parameter false übergeben
            _t.txtInput.htmlText = check(this.content, false);
        }
    };
    //  beim versenden den parameter true übergeben
    lv.content = check(txtInput.text, true);
    lv.sendAndLoad('http://localhost/_root/tester/write.php', lv, 'POST');
}

//  -------------------------------------------------------------------------------------------
btSendAndLoad.onRelease = function() {
    submit();
};
txtInput.text = ' % & + öäüÖÄÜ?=)\(/&%$§"!~\''; 


php

PHP-Code:

<?php

    function check($s, $out) {
        $a = array();
        //  hier die zeichen eingeben (genau wie in der .fla)
        $a[0] = array('%', "{MODULO}");
        $a[1] = array('+', "{PLUS}");
        $a[2] = array('&', "{AND}");
        
        for($i = 0; $i < count($a); $i++) {
            $out == true ? $s = eregi_replace('\\'.$a[$i][0], $a[$i][1], $s) : $s = eregi_replace($a[$i][1], $a[$i][0], $s);
        }
        return $s;
    };

    $content = $_POST['content'];
    $content = urldecode($content);
    $content = utf8_decode($content);
    $content = check($content, false);
    
    $file = "news.html";
    $src = fopen($file, "w");
    fwrite($src , $content);
    fclose($src);    

    $src = fopen($file,"r");
    $newContent = fgets($src);
    $newContent = utf8_encode($newContent);
    $newContent = check($newContent, true);
    fclose($src);
    
    echo "&content=".$newContent;
    
?>

damit's nicht zu kompliziert wird, habe ich die funktionen in flash & php ma gleich benannt ...

so besser?


shorty

[shorty]

Und weils so schön & nützlich zu sein scheint, hier das ganze OOP - Klassenbasiert (eine für flash & eine für php).

Um es richtig nutzen zu können, müssen die Klassenpfade für php & flash richtig gesetzt werden, wenn das erledigt ist, ist das handling super easy. Ich habe mal n kleines Beispiel mit rein getan.

Flash-Klasse (PhpString):

PHP-Code:

/***
 * PhpString
 *
 * Method : replace (s:String, out:Boolean)
 * set parameter "out" on true to submit a string, 
 * or false, for incomming php replaced strings.
 *
 * Note : php-class "FlashString.inc.php" needed!
 *
 * use -> start
 
 import com.shortybmc.extensions.string.*;
 var strSubmit:String = '+ shorty % shorty & ';
 strSubmit = PhpString.replace(strSubmit, true);
 trace(strSubmit);

 var strReceive:String = '{PLUS} shorty {MODULO} shorty {AND}';
 strReceive = PhpString.replace(strReceive, false);
 trace(strReceive);

 * use -> end
 *
 *
 * @shorty
 * @http://www.shorty-bmc.com
 *
 */
import com.shortybmc.extensions.string.*;
class PhpString extends String {
    public static function replace (s:String, out:Boolean) : String {
        var a:Array = new Array();
        a[0] = ['%', '{MODULO}'];
        a[1] = ['+', '{PLUS}'];
        a[2] = ['&', '{AND}'];
        for (var i in a) {
            out == true ? s = s.split(a[i][0]).join(a[i][1]) : s = s.split(a[i][1]).join(a[i][0]);
        }
        return out == true ? escape(s) : s;
    }
} 


PHP-Klasse (FlashString)

PHP-Code:

<?php

    class FlashString {
        function replace ($s, $out) {
            $a = array();
            $a[0] = array('%', "{MODULO}");
            $a[1] = array('+', "{PLUS}");
            $a[2] = array('&', "{AND}");
            
            if ($out == true) {
                $s = utf8_encode($s);
            } else {
                $s = urldecode($s);
                $s = utf8_decode($s);            
            }
            for($i = 0; $i < count($a); $i++) {
                $out == true ? $s = eregi_replace('\\'.$a[$i][0], $a[$i][1], $s) : $s = eregi_replace($a[$i][1], $a[$i][0], $s);
            }
            return $s;
        }
    }

?>

Anwendungsbeispiel - Flash (LoadVars)

PHP-Code:

this.stop();
//  -----------------------------------------------------------------------
import com.shortybmc.extensions.string.*;
//  -----------------------------------------------------------------------
function submit(s:String):Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(ok) {
        if (ok) {
            txtInput.htmlText = PhpString.replace(this.content, false);
        }
    };
    lv.content = PhpString.replace(s, true);
    lv.sendAndLoad('http://localhost/_root/tester/example.php', lv, 'POST');
}
//  ------------------------------------------------------------------------
btSendAndLoad.onRelease = function() {
    submit(txtInput.text);
}; 


Passend dazu das php Script, welches den datenstrom aufnimmt, mittels der php-klasse zeichen formatiert, eine html datei schreibt, jene ausliest, und den inhalt an flash zurück sendet, welches wiederum ... bla bla bla... anschauen

PHP-Code:

<?php

    require_once("FlashString.inc.php");
    $flashString = new FlashString();
    
    $content = $_POST['content'];
    $content = $flashString->replace($content, false);    
    
    // example start
    $file = "foo.html";
    $src = fopen($file, "w");
    fwrite($src , $content);
    fclose($src);    

    $src = fopen($file,"r");
    $newContent = fgets($src);
    fclose($src);
    // example end
    
    $newContent = $flashString->replace($newContent, true);
    echo "&content=".$newContent;

?>

Das wars ...


shorty