HELP: testen in flash geht, swf im player ist aber leer

[stylefetish]

Hallo,

ich hatte gestern schon mal ein anderes Problem beschrieben. Wenn ich den Film nun exportiere funktioniert das alles in Flash wenn ich das aber als swf angucke ist nichts da…

PHP-Code:

function createNavi(topnavi_array:Array, startY:Number, aTopnaviCol:Array) : Void {

        var navigation_mc:MovieClip;
        var mBg:MovieClip;
        var navigation_txt:TextField;
        
        for (var i:Number = 0; i < topnavi_array.length; i++){      
            
            navigation_mc = this.createEmptyMovieClip("topnavi_mc"+i, this.getNextHighestDepth());
            mBg = navigation_mc.createEmptyMovieClip("mBackground", navigation_mc.getNextHighestDepth());
            
            
            navigation_mc._y = startY;
            navigation_mc._alpha = 0;
            
            
            mBg.beginFill(aTopnaviCol[i], 100);
            drawRectangle(mBg, Stage.width, 14);
            mBg.endFill();
            
            navigation_txt = navigation_mc.createTextField("topnavi_txt",  navigation_mc.getNextHighestDepth(), 5, -1, 0, 0);
            navigation_txt.wordWrap = false;
            navigation_txt.autoSize = true;
            navigation_txt.embedFonts = true;
            //navigation_txt.antiAliasType = "advanced";

             // Set Navigation Text Format 
            var fmtTopNavi:TextFormat = new TextFormat();
            fmtTopNavi.color = 0xFFFFFF;
            fmtTopNavi.font = "ceriph"
            fmtTopNavi.size = 8;
            
            navigation_txt.text =  String(topnavi_array[i]);
            trace(navigation_txt.text );
            navigation_txt.setTextFormat(fmtTopNavi);
            

            var endY:Number = Stage.height / 2 + (14*i) 
            
            navigation_mc.tween("_y", endY, 0.6*(i+0.5), "easeOutElastic");
            navigation_mc.alphaTo(100, 2, "easeOutQuad");
            
            navigation_mc.onRollOver = function (){
                
                var nId:Number = this._name.substr(this._name.length -1, this._name.length) 
            
                if (mMain.naviAktive != nId){
                    
                    this.mBackground.colorTo(0x990033, 3, "easeOutCubic");
            
                }
            }
            
            navigation_mc.onRelease = function () {
                
                if (mMain.naviAktive != nId || mMain.naviAktive == undefined){
                    
                    mMain["topnavi_mc"+mMain.naviAktive].mBackground.colorTo(aTopnaviCol[mMain.naviAktive], 4, "easOutQuad");
                    mMain.naviAktive = this._name.substr(this._name.length -1, this._name.length);
                    this.mBackground.colorTo(0xCC3300, 1, "easOutQuad");
                    generateSecondLevel(nId, this._y);
                
                }
                    
            }
            
            navigation_mc.onRollOut = function () {
                
                var nId:Number = this._name.substr(this._name.length -1, this._name.length) 
            
                if (mMain.naviAktive != nId){
                    
                    this.mBackground.colorTo(aTopnaviCol[nId], 1, "easOutQuad");
            
                }
            }
            
            navigation_mc.onReleaseOutside = navigation_mc.onRollOut;
        }
            
} 


ich bekomm wenn ich das als flash 7 exporitere eine Fehlermeldung die ich aber nicht so recht deuten kann…

PHP-Code:

Type mismatch in assignment statement: found Void where TextField is required.
             
navigation_txt = navigation_mc.createTextField("topnavi_txt",  navigation_mc.getNextHighestDepth(), 5, -1, 0, 0); 


Da ich navigation_txt ja am anfang der funktion als TextFeld ja am anfang explizit definiere.

Wer weiß da rat??
Danke
Guido

[bamboocha]

Player vor Version 8 geben bei createTextField "void" zurück! Da liegt der Hund begraben! Steht auch so in der Flashhilfe!

[stylefetish]

ah okay! Vielen Danke… Wenn man so lange mit createTextfield gearbeitet hat vermutet man immer es gäbe nichts mehr darüber in der Hilfe herauszufinden

[bamboocha]

Tja... so gehts!