helligkeit per AS zu langsam?

[Newsdesigner]

Ich habe versucht ein Script hier aus dem Forum für meine Karte zu verwenden. Ich habe die Karte unten angehängt. Leider funktioniert es nicht.
Es verhält sich wie, bei Google Maps, einige Gebiete verschwinden bei MouseOver. Grund, anders als über Zeitleiste, kann ich über Script die Funktion nicht abbrechen.

Es soll folgendes passieren. Wenn mein mit dem Mauszeiger über ein Gebiet geht, soll die Fläche heller werden, wenn man das Gebiet verlässt wieder dunkler. Allerdings wird es immer heller, aber nur selten dunkler.

MovieClip.prototype.addProperty("_brightness",function(){
        var t = new Color(this).getTransform();
        var p = 0;
        if(t.rb > 0 && t.gb > 0 && t.bb > 0){
                p = (((t.rb+t.gb+t.bb)/3*100/(0xff))+100-((t.ra+t.ga+t.ba)/3))/2;
        } else if(t.ra < 100 && t.ga < 100 && t.ba < 100){
                p = (t.ra+t.ga+t.ba-300)/3;
        }
        return Math.round(p);
},function(v){
        var a = (v>0)?(100-v):(100+v);
        var b = (v>0)?((0xff)*v/100):(0);
        new Color(this).setTransform({ra:a, rb:b, ga:a, gb:b, ba:a, bb:b});
});
 
 
function fHelligkeit(vMC, vSteps, vBrightness) {
        vMC.brightnessSteps = vSteps;
        vMC.brightnessAdd = (vBrightness/vSteps);
        vMC.onEnterFrame = function() {
                if (this.brightnessSteps--) {
                        this._brightness += vMC.brightnessAdd;
                } else {
                        delete this.onEnterFrame;
                }
        };
}
 
 
for(i=1;i<=6;i++){
    _root.karte["region"+i].id = i;
    
    _root.karte["region"+i].onRollOver = function() { 
        fHelligkeit(_root.karte["region"+this.id], 4, 50);
        //_root.karte["region"+this.id]._brightness=50;
    }
    
    _root.karte["region"+i].onRollOut = function() { 
        fHelligkeit(_root.karte["region"+this.id], 4, 0);
        //_root.karte["region"+this.id]._brightness=0;
    }
} 

[hannabi]

Habe gerade nur kurz Zeit. Aber mach das doch über ein alpha-tween. Irgendetwas in der Richtung.

this.td._alpha = 60;
this.td.onRollOver = function() {
    var mc = this._parent.td;
    this.onEnterFrame = function() {
        mc._alpha<100 ? mc._alpha += 5 : (mc._alpha=100, delete this.onEnterFrame);
    };
};
this.td.onRollOut = function() {
    var mc = this._parent.td;
    this.onEnterFrame = function() {
        mc._alpha>60 ? mc._alpha -= 5 : (mc._alpha=0, delete this.onEnterFrame);
    };
}; 

[Newsdesigner]

Würde ich machen, aber ich will sowohl in den positiven, als auch in den negativen Helligkeitsbereich rein und das geht nicht mit _alpha. Ich will weiße Schrift in Grau einfärben.

[hannabi]

Was ist denn ein negativer und was ein positiver Helligkeitsbereich?

Um weiße in graue Schrift zu tweenen, musst du doch einfach nur _alpha durch textColor ersetzen und das AS entsprechend anpassen, oder nicht?

[Newsdesigner]

Bei Alpha kannst Du den Wert nur von 0 bis 100 verändern, bei Helligkeit geht es von +100 über 0 bis -100. Auch das obere Script unterstützt negative Werte.

[rena]

Eine Möglichkeit wäre die Änderung folgender Funktion

function fHelligkeit(vMC, vSteps, vBrightness) {
    vMC.brightnessSteps = vSteps;
    vMC.brightness = vBrightness;
    vMC.onEnterFrame = function() {
        if (Math.abs(this.brightness-this._brightness)>2) { //2 = "Toleranzwert"
            this._brightness += (this.brightness-this._brightness)/this.brightnessSteps;
        }else{
            delete this.onEnterFrame
        }
    };
} 

Gruß
Rena

[Newsdesigner]

Ich weiß zwar noch nicht warum, aber es funktioniert. Viele Dank!
Ich werde gleich die Scripte vergleichen.

Danke!!!

[Newsdesigner]

Ich habe nach sehr langer Zeit mal wieder eine Frage. Ich möchte eine Elemente mit einer Farbe versehen und dann diese fHelligkeit Funktion anwenden. Irgendwie holt sich die Funktion die urspründliche Farbe wieder.
liegt es an der Variable 't' oder was kann ich gegen sie machen? Kann ich diese irgendwie fest vergeben?

for (i=1; i<=4; i++) {
	var farbe_color:Color = new Color(_root["quadrat"+i]);
	farbe_color.setRGB(0xFF0000);
}

var Timeline = this;

MovieClip.prototype.addProperty("_brightness",function(){
        var t = new Color(this).getTransform();
        var p = 0;
        if(t.rb > 0 && t.gb > 0 && t.bb > 0){
                p = (((t.rb+t.gb+t.bb)/3*100/(0xff))+100-((t.ra+t.ga+t.ba)/3))/2;
        } else if(t.ra < 100 && t.ga < 100 && t.ba < 100){
                p = (t.ra+t.ga+t.ba-300)/3;
        }
        return Math.round(p);
},function(v){
        var a = (v>0)?(100-v):(100+v);
        var b = (v>0)?((0xff)*v/100):(0);
        new Color(this).setTransform({ra:a, rb:b, ga:a, gb:b, ba:a, bb:b});
});

function fHelligkeit(vMC, vSteps, vBrightness) {
        vMC.brightnessSteps = vSteps;
        vMC.brightness = vBrightness;
        vMC.onEnterFrame = function() {
                if (Math.abs(this.brightness-this._brightness)>2) { //2 = "Toleranzwert"
                        this._brightness += (this.brightness-this._brightness)/this.brightnessSteps;
                }else{
                        delete this.onEnterFrame
                }
        };
}

for (i=1; i<=4; i++) {
	
	_root["quadrat"+i].id = i;
	
	//var farbe_color:Color = new Color(_root["bundesland"+i]);
	//farbe_color.setRGB(0xFF0000);

	_root["quadrat"+i].onRollOver = function() { 
		fHelligkeit(_root["quadrat"+this.id], 3, 60);
	}

	_root["quadrat"+i].onRollOut = function() { 
		fHelligkeit(_root["quadrat"+this.id], 3, 0);
	}
}