Grrrrooooßßßes Problem Mit Dem Prloader

[djripper]

Hallo alle zusammen.
Ich habe früher mit Flash MX 2004 einen preloader gehabt.
Doch jetzt habe ich Flash 8 und WEnn ich ihn öffne dann zeigt er mir alles richtig an aber dann beim test will er nicht mehr.
liegt das an der version oder kann man da was verändern??

PHP-Code:

stop();
// einen prototype erstellen für movieclips;
MovieClip.prototype.preload = function() {
    //der variabel totalBytes die dateigröße des ganzen filmes zuordnen;
    var totalBytes = _root.getBytesTotal();
    //die variabel prozent erhält zu beginn den wert null;
    var prozent = 0;
    //x-scalierung des preloaderbalkens wird dem prozent gleichgesetzt;
    this.balken._xscale = prozent;
    //das textfeld mit preloader-info/fortschritt bekommt ausrichtung links und an dynamischen text angepasste größe;
    this.T_prozent.autoSize = "LEFT";
    //onEnterFrame: immer wieder checken, so oft der film "die "szene" betritt" (bei 30 frames per scond eben 30 mal in der sekunde;
    this.onEnterFrame = function() {
        // die variabel loadedBytes = was gerade geladen ist;
        loadedBytes = _root.getBytesLoaded();
        //formel für ausrechnung des wertes prozent;
        prozent = Math.round(loadedBytes*100/totalBytes);
        //solange prozent weniger als hundert ist.....
        if (prozent<100) {
            //der Texx ist:
            this.T_prozent.text = "loading woodlight..."+prozent+"% loaded";
            //balkenbreite = prozent....
            this.balken._xscale = prozent;
            // alles andre(ergo, wenn 100 % geladen)
        } else {
            //das textfeld erhält fixen text;
            this.T_prozent.text = "woodlight complete loaded...100 %";
            //balken ist originalbreit(100%);
            this.balken._xscale = 100;
            //verzögerte weiterleitung zum nächsten/einen anderen frame
            var iv = setInterval(function () {
                _root.nextFrame();
                //wichtig: nur einmal das intervall aufrufen, deswegen sofort clearen!!!!
                clearInterval(iv);
                //verzögerung in millisekunden(hier eine sekunde);
            }, 1000);
            // und gaaaanz wichtig: nach verwendung onEnterFrame-events immer löschen....performance!!!!!
            delete this.onEnterFrame;
        }
    };
};
// der movieclip MC_preloader ruft die funktion auf;
MC_preloader.preload();
// nach diesem frame kommt /kommen dann der/die frame/frames mit dem inhalt; 


[andretti]

freut mich dass dir mein preloader gute dienste erweist;

vielleicht gibst du dem movieclip mal den instanznamen "MC_preloader".....

[djripper]

EJ dANKE jetzt klappts .
ein mächtiges handgeklapper an addretti.
danke noch mal.

djripper