getUrl?? im rotation menue

[dcmschell]

Hallo,

brauche dringend eure Hilfe :-D
Ich habe das Flashstar Menue runtergeladen, geht auch wunderbar, nur weiß ich nicht wie ich die einzelnen Bilder verlinken kann, sodass jedes Bild seine eigene Url anwählt beim draufklicken? Könnt ihr mir vielleicht weiterhelfen? Möchte das Script als nromale Naivation verwenden.

LG Claudi

Hab hier mal das Script gepostet!

PHP-Code:


//Bild-Dateien
bListe = ["bilder/01.jpg", "bilder/02.jpg", "bilder/03.jpg", "bilder/04.jpg", "bilder/05.jpg", "bilder/06.jpg", "bilder/07.jpg"];
//bListe2 = ["bilder/01.jpg", "bilder/02.jpg", "bilder/03.jpg"];
//bListe3 = ["bilder/01.jpg", "bilder/02.jpg", "bilder/03.jpg", "bilder/04.jpg", "bilder/05.jpg"];
MovieClip.prototype.ZoomDiv = function (pDim, pTempo)
{    
    if (this._xscale < pDim - 1 / pTempo)
    {
        this._xscale = this._xscale + (pDim - this._xscale) / pTempo;
        this._yscale = this._yscale + (pDim - this._yscale) / pTempo;
    }
    else if (this._xscale > pDim + 1 / pTempo)
    {
        this._xscale = this._xscale + (pDim - this._xscale) / pTempo;
        this._yscale = this._yscale + (pDim - this._yscale) / pTempo;
    }
    else
    {
        this._xscale = this._yscale = pDim;            
    }
};
ASSetPropFlags (MovieClip.prototype, "ZoomDiv", 1);

MovieClip.prototype.rotation_menue = function (bildListe, posX, posY, alpha, fokus, posZ, radius, rsichtbar, drehfaktor)
{
    var mwinkel = 0;
    var bilder = [];
    var pi = 2 * Math.PI;
    var signal = true;
    var zsignal = false;
    var bild, dimension, piwinkel;
    
    this._x = posX;
    this._y = posY;
    this._alpha = alpha;
    
    for (var i = 0; i < bildListe.length; i++)
    {
        bild = this.attachMovie ("bildrahmen", "bild" + i, i);
        bild.wphase = pi / bildListe.length * i;
        bild.container.loadMovie (bildListe[i]);
        bild.onRollOver = function() 
        { 
            signal = false; 
        }
        bild.onRollOut = function() 
        { 
            signal = true; 
        }
        bild.onPress = function ()
        {
            obj = this;
            signal = false;
            zsignal = !zsignal;            
        };
        if (rsichtbar == false)    bild.rahmen._visible = 0;        
        bilder.push (bild);    
    }
    this.onEnterFrame = function ()
    {
        if (zsignal)
        {            
            obj.container.ZoomDiv(150,6);
            obj.rahmen._width = obj.container._width;
            obj.rahmen._height = obj.container._height;
        }
        else
        {
            obj.container.ZoomDiv(100,6);
            obj.rahmen._width = obj.container._width;
            obj.rahmen._height = obj.container._height;
        }
        if (signal)
        {
            mwinkel += zentrum._xmouse / drehfaktor;
            if (mwinkel >= pi)    mwinkel -= pi;
            if (mwinkel < 0) mwinkel += pi;
            for (var i = 0; i < bilder.length; i++)
            {
                bild = bilder[i];
                bild.x = radius * Math.cos (bild.wphase + mwinkel);
                bild.z = radius * Math.sin (bild.wphase + mwinkel) + posZ;
                dimension = fokus / bild.z;
                piwinkel = Math.atan2 (bild.x, bild.z);
                bild._x = bild.x * dimension;
                bild._xscale = -100 * dimension * Math.sin (bild.wphase + mwinkel + piwinkel);
                bild._yscale = 100 * dimension;
                bild.swapDepths (-(int (bild.z)));            
            }    
        }
    };
}

zentrum.rotation_menue (bListe, Stage.width/2, Stage.height/2, 100, 600, 600, 200, true, 5000);
//zentrum2.rotation_menue (bListe2, Stage.width/2, 80, 100, 600, 600, 200, true, 5000);
//zentrum3.rotation_menue (bListe3, Stage.width/2, 320, 100, 600, 600, 200, true, 5000); 


Das wird mit diesem Script sehr aufwändig, weil:

PHP-Code:

bild.container.loadMovie (bildListe[i]); 


Du müsstest mit einem Preloader den Punkt abfangen, wo das Bild geladen ist. Erst dann kannst du einen Klickevent setzen, der einen getURL auslöst. In einer for-Schleife ist das aber ziemlich schwierig, weil die Bilder selten in der Reihenfolge geladen werden, in der der loadMovie initialisiert wird.

Ich würde eher einen Ansatz mit der MovieClipLoader-Klasse wählen, bspw.:

PHP-Code:


//Zähler
var index:Number = 0;

//Liste der Bilder
var files:Array = new Array("bilder/01.jpg", "bilder/02.jpg", "bilder/03.jpg", "bilder/04.jpg", "bilder/05.jpg", "bilder/06.jpg", "bilder/07.jpg");

var urls:Array = new Array("http://www.url1.com");//etc
//Liste der MCs
var mcs:Array = new Array();
var len:Number = files.length;

//leere MCs erzeugen
for(var i=1;i<=len;i++){
   this.mcs.push(this.createEmptyMovieClip("con"+i,i));
   this["con"+i]._x = (i*100);//evtl. positionieren
}

//erstes Bild laden
var mclListener:Object = new Object();
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mclListener);
mcLoader.loadClip(files[index], mcs[index]);



//fertiggeladen
mclListener.onLoadInit = function(mc:MovieClip) {
   trace("fertig, mc="+mc);

   //Auslöser für getURL
   mc.onRelease = function(){
      getURL(urls[index],"_blank");
   }

   index++;
   if (index < len) {//sind noch weitere zu laden?
       mcLoader.loadClip(files[index], mcs[index]);
   }
}

this.stop(); 


BTW: setz bitte zwecks besserer Lesbarkeit deine Scriptschnippsel hier in PHP-Tags. Hab das für dein Script oben mal angepasst...