...ganz schön sticky ;)

[bob_mosquito]

Soo Leuts,

dieser mjau-mjau-stickyButtons-CursorKlebundwiederZurückschnappeffekt is ja schon öfters thematisiert worden. Leider gabs den aber bisher bloß als Flash-5-Version. Und da ich mich gerade bissel in OOP reinzufitzen versuche, möchte ich euch folgende Resultate nich vorenthalten...

Voilá. Die stickyButton-Klasse.

class stickyButton extends MovieClip {
    
    var accel:Number;
    var convert:Number;
    var xstart:Number;
    var ystart:Number;
    var targetx:Number;
    var targety:Number;
    var radius:Number;
    var r:Number;
    var rollOver:Boolean;
    var normalDepth:Number;
    
    function stickyButton() {
        accel=.01;
        convert=.2;
        xstart=_x;
        ystart=_y;
        targetx=xstart;
        targety=ystart;
        radius=2;
        rollOver = false;
        normalDepth = this.getDepth();
        initialize();
 
    }
    
    function initialize(Void):Void {
        var mc = this;
        r = radius;
        onRollOver = function() {
            mc.rollOver = true;
            mc.swapDepths(_parent.getNextHighestDepth());
            mc.onEnterFrame = function() {
                mc.sticky_update();
            }
        }
        onRollOut = function() {
            mc.rollOver = false;
        }
        onPress = function() {
            mc.r = 5;
        }
        onRelease = function() {
            mc.r = radius;
        }
        onReleaseOutside = function() {
            mc.r = radius;
            mc.rollOver = false;
        }
    }
    
    function sticky_update(Void):Void {
        var mc:MovieClip = this;
        var xpos:Number = 0;
        var ypos:Number = 0;
 
        if(rollOver){
 
            var deltax:Number=_root._xmouse-xstart;
            var deltay:Number=_root._ymouse-ystart;
            targetx=_root._xmouse-deltax/r;
            targety=_root._ymouse-deltay/r;
 
        } else {
            targetx=xstart;
            targety=ystart;
        }
 
         xpos = xpos *accel + (targetx - _x) * convert; 
        _x += xpos;
        ypos = ypos * accel + (targety - _y) * convert; 
        _y += ypos;
        
        if(!rollOver && Math.round(_x) == targetx && Math.round(_y) == targety) {
            delete mc.onEnterFrame;
            _x = targetx;
            _y = targety;
            mc.swapDepths(normalDepth);
        }
        trace("_x:"+_x+", targetx:"+targetx+",  _y:"+_y+",  targety:"+targety);
    }
} 

Vielleicht kanns ja jemand verwenden...

[ricobeck]

sehr nett, das hier reinzustellen [*thumbs.up*],
aber kannst du bitte noch eine version zum angucken
machen? das ist vielleicht wirkungsvoller.



l.g.
rick

[bob_mosquito]

Sischa, sischa