Funktion mit _alpha fängt nach 10tem Mal an zu ruckeln

[Marcellus]

Hallo Retter,

hab ein Problem und finde den Fehler nicht:
In meinem Film kann ich mich mit Vorwärts und Rückwärtsbutton durch eine Anzahl von Bildern klicken. Die Button übergeben entweder 1 oder -1 an folgende Funktion:

PHP-Code:

function zaehlen(a){
    this.aktiv = false;
    var m = this["imageCount_"+rubrikID];
    var nr;
    var z = detailNrNow + a;
    trace("z = "+z);
    //
    if(z == 0){
        nr = m;
    }else{
        if(z > m){
            nr = 1;
        }else{
            nr = z;
        }
    }
    trace("nr = "+nr);
    this.detailWeiter(nr)
} 


Die Variable nr wird nun an nächste Funktion übergeben. Hier wird das nächste Bild geladen:

PHP-Code:

function detailWeiter(detailNr){
    loaderbetreiben(1);
    duplicateMovieClip("detailcontainer_mc","detail_mc"+detailNr, detailNr+200);
    this["detail_mc"+detailNr].loadMovie(_root.detailpfad+this["detail"+rubrikID+"_"+detailNr]);
    //
    this.onEnterFrame = function() {
        var geladen = int(this["detail_mc"+detailNr].getBytesLoaded()*100/this["detail_mc"+detailNr].getBytesTotal());
        if (geladen>0) {
            myPicLoading = geladen;
            this.loader_mc.skala_mc._xscale = myPicLoading;
            this.loader_mc.ladeText = "Detailbild laden...";
        }
        //
        if (geladen>=100 && this["detail_mc"+detailNr]._height>10) {
            delete this.onEnterFrame;
            //
            loaderbetreiben(0);
            detailWechsel(detailNr);
        }
    };
} 


Wenn das Bild geladen ist, wird positioniert und eingeblendet. Das vorherige Bild wird ausgeblendet:

PHP-Code:

function detailWechsel(detailNr) {
    //
    this["detail_mc"+detailNr]._alpha = 0;
    this["detail_mc"+detailNr]._x = 0;
    this["detail_mc"+detailNr]._y = 0;
    //
    this.onEnterFrame = function() {
        //
        if (this["detail_mc"+detailNr]._alpha <= 80) {
            this["detail_mc"+detailNr]._alpha += 12;
            this["detail_mc"+detailNrNow]._alpha -= 12;
        }else{
            delete this.onEnterFrame;
            this["detail_mc"+detailNr]._alpha = 100;
            this["detail_mc"+detailNrNow]._alpha = 0;
            this.detailNrNow = detailNr;
            this.aktiv = true;
        }
    };
} 


Wenn ich 10 oder weniger Bilder habe, klappt es wunderbar. Ich kann soviel wechseln wie ich will, es gibt immer einen weichen Übergang.
Aber wenn es mehr als 10 Bilder sind wird der Wechsel ab dem 10. Bild sehr ruckelig.
Ich weß nicht woran es liegt??????????????
Schon jetzt vielen Dank für Eure Antwort(en8-)

[Der Frager]

Hallo!

Könnte sein, dass da einfach zu viele Bilder übereinander liegen. Da steht Flash nicht so drauf. Guck mal, ob das hier was hilft (wenn's überhaupt klappt):

PHP-Code:

function detailWechsel(detailNr) {
    // 
    this["detail_mc"+detailNr]._alpha = 0;
    this["detail_mc"+detailNr]._x = 0;
    this["detail_mc"+detailNr]._y = 0;
    this["detail_mc"+detailNrNow]._x = 0; // Hier erst auf 0 holen
    // 
    this.onEnterFrame = function() {
        // 
        if (this["detail_mc"+detailNr]._alpha<=80) {
            this["detail_mc"+detailNr]._alpha += 12;
            this["detail_mc"+detailNrNow]._alpha -= 12;
        } else {
            delete this.onEnterFrame;
            this["detail_mc"+detailNr]._alpha = 100;
            this["detail_mc"+detailNrNow]._alpha = 0;
            this["detail_mc"+detailNrNow]._x = -1000; // und hier weg mit dem Bild
            this.detailNrNow = detailNr;
            this.aktiv = true;
        }
    };
} 


[Marcellus]

Zitat von Der Frager

this["detail_mc"+detailNrNow]._x = -1000; // und hier weg mit dem Bild

Das wars. Das kann doch wohl nicht war sein!
Wie kommt man darauf??? Hast Du das mal irgendwo gelesen?

...ich sach ja Retter!!! Vielen,vielen Dank!!!

[gaspode]

Bilder die _alpha = 0 haben und gerade nicht gebraucht werden,
solltest Du _visible = false setzen.
Bei über 10 Bildern übereinander, die _alpha = 0 haben, macht
Flash «interessante Dinge».

>Wie kommt man darauf???
Ist mein liebster Flash«bug».

gruß, gaspode

[Der Frager]

...ach ja, _visible = false tut's natürlich auch. Wobei's eigentlich egal ist (behaupte ich mal so).

[Marcellus]

...funktionieren tuts Beides...

nochmal vielen Dank