function() mehrfach verwenden

[Newsdesigner]

Hallo Actionscript-Gemeinde!

Ich wollte die folgende function mehrfach verwenden, allerdings bekomme ich es nicht hin sie mehrfach anzusteuern. Hat jemand eine Ahnung, wie ich nicht jedesmal textKreis1.drawCircle... , textKreis2.drawCircle... , textKreis3.drawCircle... schreiben muß. Mit einer Schleife geht es sicherlich, aber muß ich die ganze Function in die Schleife eintragen? Ich finde es einwenig viel. Ich hoffe jemand kann hier helfen

// function zum zeichen eines Kreises
textKreis.drawCircleText = function(text,meinKreis){
 
    // apply colour
    var col=new Color(this);
    col.setRGB(meinKreis.col);
 
    // convert angle
    var theta = (meinKreis.angle+180)*Math.PI/180;
 
    // set position of this clip
    this._x = meinKreis.x;
    this._y = meinKreis.y;
 
    // make var names more manageable
    var r=meinKreis.radius;
    var spac=meinKreis.spacing, fID=meinKreis.fontID, size=meinKreis.size;
 
    var L = text.length;
 
    // store the number of characters globally for easy removal
    _root.noChars = L;
 
    // width of previous(0) and current(1) character
    var cWidth0=0, cWidth1=0;
 
    // c takes value of each character
    var c;
    
    // for each letter in the text
    for(var i=0; i<L; i++){
        c = text.substr(i,1);
        if(c==" "){
            // width of a <space> 
            cWidth0 = size/2+spac;
        }else{
            // attach "font"
            this.attachMovie(fID,i,i);
            // send to correct character frame
            this[i].gotoAndStop(ord(c));
            // set size
            this[i]._xscale=size;
            this[i]._yscale=size;
            // find width of this character
            cWidth1 = this[i]._width/2;
            // increment angle
            theta += Math.atan((cWidth1+cWidth0+(i?spac:0))/r);
            // keep width for use with next character
            cWidth0 = cWidth1;
            // find new position and rotation
            this[i]._x = Math.cos(theta)*r;
            this[i]._y = Math.sin(theta)*r;
            this[i]._rotation = theta*180/Math.PI+90;
            var theta0 = meinKreis.drehung-(this[0]._rotation+450)%360;
            var theta1 = meinKreis.drehung-(this[_root.noChars-1]._rotation+450)%360;
            thetaMax = Math.max(theta1,theta0);
            thetaMin = Math.min(theta1,theta0);
            this._rotation =(thetaMin-(meinKreis.drehung+thetaMin-thetaMax)/2);
        }
    }
}
 
meinKreis = {x:200, y:200, radius:30, angle:0, drehung:0, size:16, spacing:1, fontID:"font1", col:0x996633}
meinKreis2 = {x:200, y:200, radius:30, angle:0, drehung:90, size:16, spacing:1, fontID:"font1", col:0x996633}
inputText = "Link AB";
inputText2 = "Link CD";
 
//_root.textCircle.duplicateMovieClip("textCircle2", 2);
textKreis.drawCircleText(inputText,meinKreis);
textKreis.drawCircleText(inputText2,meinKreis2); 

[RustyCake]

Mit sowas vielleicht!

PHP-Code:

var wievieleKreise=10;
for(var i=0; i<wievieleKreise; i++){
    drawCircle("text"+i, "meinKreis"+i);
} 


btw. reservierte wörter wie "text" würde ich nicht verwenden

[ANTICHRIST]

Wie wäre es das Teil per prototype in eine Methode umzuwandeln ???

[Newsdesigner]

Danke für die Vorschläge, aber so einfach scheint es nicht zu sein.

function drawCircle(text,meinKreis){
 
(...)
 
}
 
meinKreis0 = {x:200, y:200, radius:30, angle:0, drehung:0, size:16, spacing:1, fontID:"font1", col:0x996633}
meinKreis1 = {x:200, y:200, radius:30, angle:0, drehung:90, size:16, spacing:1, fontID:"font1", col:0x663399}
meinKreis2 = {x:200, y:200, radius:30, angle:0, drehung:180, size:16, spacing:1, fontID:"font1", col:0x669933}
meinKreis = array(meinKreis0,meinKreis1,meinKreis2);
inputText = array("Link AB", "Link CD", "Link EF");
 
var wievieleKreise=3;
for(var i=0; i<wievieleKreise; i++){
    drawCircle(inputText[i], meinKreis[i]);
} 

Vielleicht eine andere Idee?

[hgseib]

für zwei aufrufe brauchts auch zwei objekte, bzw. die funktion entsprechend ändern.

und das fla ist für flash5 eingestellt. dann muss man auch die möglichkieten von flash5 nehmen.

[Newsdesigner]

Viele Dank, aber geht das auch mit 3 Texten? Bei mir geht es nicht!

function drawCircleText(vThis,meinText, meinKreis) {
 
(...)
 
}
meinKreis = {x:200, y:200, radius:30, angle:0, drehung:0, size:12, spacing:1, fontID:"font1", col:0x996633};
meinKreis2 = {x:200, y:200, radius:30, angle:0, drehung:-180, size:12, spacing:1, fontID:"font1", col:0x339966};
meinKreis3 = {x:200, y:200, radius:30, angle:0, drehung:180, size:12, spacing:1, fontID:"font1", col:0x336699};
meinText = "Link AB";
meinText2 = "Link CD";
meinText3 = "Link EF";
drawCircleText(textKreis, meinText, meinKreis);
drawCircleText(textKreis2, meinText2, meinKreis2);
drawCircleText(textKreis3, meinText3, meinKreis3); 

[hgseib]

"..für zwei aufrufe brauchts auch zwei objekte, bzw. die funktion entsprechend ändern.."
du hast deine funktion so erstellt, das sie unbedingt ein mc als grundlage benötigt. wenn du also 3mal runden willst, dann benötigst du auch drei unterschiedliche ausgangs-mc's. oder

"..bzw. die funktion entsprechend ändern.."
du musst deine funktion entsprechend ändern, das sie auch ohne mc auskommt. also das da z.b.

// set position of this clip
this._x = meinKreis.x;
this._y = meinKreis.y;

warum this._x wenn dir doch meinKreis.x bekannt ist?

[RustyCake]

@ Nwesdesigner
So wie der hgseib des gemacht hat funzt des doch, auch mit der for-schleife

PHP-Code:

// function zum zeichen eines Kreises
function drawCircleText(vThis, text, meinKreis) {
    // apply colour
    var col = new Color(vThis);
    col.setRGB(meinKreis.col);
    // convert angle
    var theta = (meinKreis.angle+180)*Math.PI/180;
    // set position of vThis clip
    vThis._x = meinKreis.x;
    vThis._y = meinKreis.y;
    // make var names more manageable
    var r = meinKreis.radius;
    var spac = meinKreis.spacing, fID = meinKreis.fontID, size = meinKreis.size;
    var L = text.length;
    // store the number of characters globally for easy removal
    _root.noChars = L;
    // width of previous(0) and current(1) character
    var cWidth0 = 0, cWidth1 = 0;
    // c takes value of each character
    var c;
    // for each letter in the text
    for (var i = 0; i<L; i++) {
        c = text.substr(i, 1);
        if (c == " ") {
            // width of a <space> 
            cWidth0 = size/2+spac;
        } else {
            // attach "font"
            vThis.attachMovie(fID, i, i);
            // send to correct character frame
            vThis[i].gotoAndStop(ord(c));
            // set size
            vThis[i]._xscale = size;
            vThis[i]._yscale = size;
            // find width of vThis character
            cWidth1 = vThis[i]._width/2;
            // increment angle
            theta += Math.atan((cWidth1+cWidth0+(i ? spac : 0))/r);
            // keep width for use with next character
            cWidth0 = cWidth1;
            // find new position and rotation
            vThis[i]._x = Math.cos(theta)*r;
            vThis[i]._y = Math.sin(theta)*r;
            vThis[i]._rotation = theta*180/Math.PI+90;
            var theta0 = meinKreis.drehung-(vThis[0]._rotation+450)%360;
            var theta1 = meinKreis.drehung-(vThis[_root.noChars-1]._rotation+450)%360;
            thetaMax = Math.max(theta1, theta0);
            thetaMin = Math.min(theta1, theta0);
            vThis._rotation = (thetaMin-(meinKreis.drehung+thetaMin-thetaMax)/2);
        }
    }
}
/*
meinKreis1 = {x:200, y:200, radius:30, angle:0, drehung:0, size:16, spacing:1, fontID:"font1", col:0x996633};
meinKreis2 = {x:300, y:200, radius:30, angle:0, drehung:90, size:16, spacing:1, fontID:"font1", col:0x996633};
inputText = "Link AB";
inputText2 = "Link CD";
drawCircleText(textKreis, inputText, meinKreis1);
drawCircleText(textKreis2, inputText2, meinKreis2);

*/
meinKreis0 = {x:200, y:200, radius:30, angle:0, drehung:0, size:16, spacing:1, fontID:"font1", col:0x996633};
meinKreis1 = {x:300, y:200, radius:30, angle:0, drehung:90, size:16, spacing:1, fontID:"font1", col:0x663399};
meinKreis2 = {x:400, y:200, radius:30, angle:0, drehung:180, size:16, spacing:1, fontID:"font1", col:0x669933};
var textKreise = [_root.textKreis1, _root.textKreis2, _root.textKreis3];
var meinKreis = [meinKreis0, meinKreis1, meinKreis2];
var inputText = ["Link AB", "Link CD", "Link EF"];
for (var i = 0; i<textKreise.length; i++) {
    drawCircleText(textKreise[i], inputText[i], meinKreis[i]);
} 


[Newsdesigner]

@RustyCake:

Vielen Dank für die Hilfe, ich habe versucht den Aufruf der Funktion zu vereinfachen. Allerdings scheitert es an dem MovieClip "textKreis". Was steckt da drin. Wenn ich mir ihn anschaue, ist er leer. Also müsste es doch reichen diesen einfach mit

_root.createEmptyMovieClip("textKreis"+i, 50+i); 

zu erzeugen. Funktioniert aber nicht. Hab ich da etwas übersehen?

[Der Frager]

...guck mal in die Einstellungen für die Veröffentlichung. Da steht "Flash5". createEmptyMovieClip() gab's da noch nicht. Also einfach auf 6 umstellen...

[Newsdesigner]

So einfach sind die kleinen Freude! Und schon funktioniert es. Ich arbeite nie mit Flash 5 und habe daran nicht gedacht. Danke!!!

[hgseib]

tja lesen, siehe hier #5

"..und das fla ist für flash5 eingestellt..."

[Newsdesigner]

Da hätte ich noch mal eine ganz blöde Frage. Warum kann ich über das folgende Script das Menü nicht laden, es ist doch nichts aussergewöhnliches dran. Andere movies lassen sich laden, das hier nicht:

_root.createEmptyMovieClip("navigation_mc", 3);
navigation_mc._x =  20;
navigation_mc._y =  20;
navigation_mc.loadMovie("menue6.swf"); 

Könnt ihr nocheinmal einen Blick drauf werfen?

[RustyCake]

Du arbeitest in der "menue6.fla" mit _root da mußte die timeline des menue6 verwenden, mach mal so!

PHP-Code:

function viewLinkText() {
    meinKreis0 = {x:75, y:75, radius:30, angle:0, drehung:90, size:13, spacing:1, fontID:"font1", col:0x000000};
    meinKreis1 = {x:75, y:75, radius:30, angle:0, drehung:-90, size:13, spacing:1, fontID:"font1", col:0x000000};
    meinKreis2 = {x:75, y:75, radius:30, angle:0, drehung:270, size:13, spacing:1, fontID:"font1", col:0x000000};
    meinKreis3 = {x:75, y:75, radius:30, angle:0, drehung:-270, size:13, spacing:1, fontID:"font1", col:0x000000};
    meinKreis4 = {x:75, y:75, radius:52, angle:0, drehung:90, size:15, spacing:2, fontID:"font1", col:0x000000};
    meinKreis5 = {x:75, y:75, radius:52, angle:0, drehung:-90, size:15, spacing:2, fontID:"font1", col:0x000000};
    meinKreis6 = {x:75, y:75, radius:52, angle:0, drehung:270, size:15, spacing:2, fontID:"font1", col:0x000000};
    meinKreis7 = {x:75, y:75, radius:52, angle:0, drehung:-270, size:15, spacing:2, fontID:"font1", col:0x000000};
    var inputText = ["Link AB", "Link CD", "Link EF", "Link GH", "Link IJ", "Link KL", "Link MN", "Link OP"];
    var timeline = this;
    meinKreis = new Array();
    for (var i = 0; i<inputText.length; i++) {
        timeline.createEmptyMovieClip("textKreis"+i, 100+i);
        meinKreis[i] = timeline["meinKreis"+i];
        drawCircleText(timeline["textKreis"+i], inputText[i], meinKreis[i]);
    }
}
viewLinkText();