Frage zu createEmptyMovieClip / dynamische Buttons

[Takuma]

ich möchte eigentlich dynamisch buttons erstellen. diese bekommen ihre eigenschaften über arrays.
ich dachte mir es über createEmptyMovieClip zu realisieren. wie spreche ich den neu erstellten mc an? ich habe es über die übergebene variable, welche den instanznamen darstellt versucht, es hat aber nicht funktioniert.

[Takuma]

achso, hier das script:

grafik = new array();
// xPos, yPos, breite, höhe, tiefe, name 
grafik[0] = [0,0,50,100,10,"grafik1"];
_global.addGrafik = function(xPos,yPos,breite,hoehe,tiefe,name){
    this.createEmptyMovieClip(name, tiefe);
    name._x=xPos;
    name._y=yPos;
    name.width=breite;
    name.height=hoehe;
    trace(xPos);
    pfad="_root."+name;
    trace(pfad);
    pfad.onRollOver=function(){trace("hallo")};
}
addGrafik(grafik[0][0],grafik[0][1],grafik[0][2],grafik[0][3],grafik[0][4],grafik[0][5]); 

[atothek]

Du verwendest die variable als wär es eine referenz ist sie aber nicht es gibt zwei schreibweisen
1. mit referenz

pfad=this["_root."+name]; 

1. ohne referenz eval ähnlich

this[pfad].onRollOver=function(){trace("hallo")}; 

ich würde die erste variante nehmen und nebenbei bemerkt ist das alles ehe ein wenig konfus mit den Array usw. Ich schick noch nen gegenvorschlag

see ya

[atothek]

So nun ein kleiner gegenvorschlag zur
Struktur mit ein paar kommentaren

// Fkt zum zeichnen eines Vierecks
this.square = function(pMc, pThick, pColor, pFillColor, pWidth, pHeight) {
    //
    pMc.lineStyle(pThick, pColor, 100);
    pMc.beginFill(pFillColor, 100);
    pMc.lineTo(pWidth, 0);
    pMc.lineTo(pWidth, pHeight);
    pMc.lineTo(0, pHeight);
    pMc.lineTo(0, 0);
    pMc.endFill();
};
// Fkt zum erzeugen der einzelnen Clips
this.createButtonClip = function(pObj) {
    // erzeugen des MC
    this.createEmptyMovieClip(pObj.clipName, pObj.clipTiefe);
    // lokale variable erzeugen und eine Refernz zuweisen
    var refMc = this[pObj.clipName];
    // kleine Fkt zum hineinzeichnen
    this.square(refMc, pObj.lineThick, pObj.lineColor, pObj.fillColor, pObj.clipW, pObj.clipH);
    // platzieren des clips
    refMc._x = pObj.clipX;
    refMc._y = pObj.clipY;
    // event zuweisen
    refMc.onRollOver = function() {
        trace("jo! das geht");
    };
};
// erzeugen eines neuen clipObjekts
this.obj1 = new Object();
this.obj1.clipName = "mc1";
this.obj1.clipTiefe = 10;
this.obj1.lineThick = 1;
this.obj1.lineColor = 0x226699;
this.obj1.fillColor = 0xff6699;
this.obj1.clipW = 100;
this.obj1.clipH = 16;
this.obj1.clipX = 100;
this.obj1.clipY = 200;
// aufruf der Fkt zum erzeugen der clips
this.createButtonClip(this.obj1); 

Kannste dir makieren und ins erste Frame kopieren.

wenn Fragen dann einfach fragen

see ya

[Takuma]

super, vielen dank.
das array war da, weil ich extern variablen laden muß, welche die informationen für die vierecke haben.
das problem ist, dass es immer unterschiedlich viele sein können. hast du ne idee wie ich das einstellen kann, dass;

1. abgefragt wird, wieviele vierecke gezeichnet werden müssen und
2. er dann dynamisch die jeweiligen mit den dazugehörigen infos anlegt

und warum muß bei:

pfad=this["_root."+name];

this und die eckigen klammern dahin?

vielen dank nochmal!

[atothek]

Heute Abend setze ich mal ran zurzeit bin ich uff arbeit

[atothek]

so ich hab mal schnell eine kleine XML Variante gebastellt

die XML Struktur ist wie Folgt

PHP-Code:

<?xml version="1.0" ?>
<navigation>
    <items linethick="1" linecolor="0x000000" fillcolor="0xff6699" overcolor="0x0000ff">
        <item titel="navipunkt1" w="100" h="20" x="0" y="0" />
        <item titel="navipunkt2" w="100" h="20" x="0" y="22" />
        <item titel="navipunkt3" w="100" h="20" x="0" y="44" />
        <item titel="navipunkt4" w="100" h="20" x="0" y="66" />
    </items>

    <items linethick="1" linecolor="0x000000" fillcolor="0x006699" overcolor="0xff00ff">
        <item titel="navipunkt1" w="100" h="20" x="102" y="0" />
        <item titel="navipunkt2" w="100" h="20" x="102" y="22" />
    </items>

    <items linethick="1" linecolor="0x000000" fillcolor="0xff6699" overcolor="0x33ffff">
        <item titel="navipunkt1" w="100" h="20" x="204" y="0" />
        <item titel="navipunkt2" w="100" h="20" x="204" y="22" />
        <item titel="navipunkt3" w="100" h="20" x="204" y="44" />
        <item titel="navipunkt4" w="100" h="20" x="204" y="66" />
        <item titel="navipunkt5" w="100" h="20" x="204" y="88" />
        <item titel="navipunkt6" w="100" h="20" x="204" y="110" />
    </items>
</navigation>

und das passende ActionScript

// Fkt zum zeichnen eines Vierecks
this.square = function(pMc, pThick, pColor, pFillColor, pWidth, pHeight) {
    //
    pMc.lineStyle(pThick, pColor, 100);
    pMc.beginFill(pFillColor, 100);
    pMc.lineTo(pWidth, 0);
    pMc.lineTo(pWidth, pHeight);
    pMc.lineTo(0, pHeight);
    pMc.lineTo(0, 0);
    pMc.endFill();
};
// Fkt zum erzeugen der einzelnen Clips
this.createButtonClip = function(pObj) {
    //
    this.createEmptyMovieClip(pObj.clipName, pObj.clipTiefe);
    var refMc = this[pObj.clipName];
    //
    this.square(refMc, pObj.lineThick, pObj.lineColor, pObj.fillColor, pObj.w, pObj.h);
    //
    refMc._x = pObj.x;
    refMc._y = pObj.y;
    refMc.obj = pObj;
    refMc.parentObj = this;
    //
    refMc.onRollOver = function() {
        //
        this.clear();
        this.parentObj.square(this, this.obj.lineThick, this.obj.lineColor, this.obj.overColor, this.obj.w, this.obj.h);
    };
    //
    refMc.onRollOut = function() {
        //
        this.clear();
        this.parentObj.square(this, this.obj.lineThick, this.obj.lineColor, this.obj.fillColor, this.obj.w, this.obj.h);
    };
};
// Fkt um diverse xml dokument zu laden
this.xmlLoader = function(pXmlFile, pXmlVar, pCallBack) {
    //
    this[pXmlVar] = new XML();
    this[pXmlVar].ignoreWhite = true;
    this[pXmlVar].parentObj = this;
    this[pXmlVar].onLoad = function() {
        //
        this.parentObj[pCallBack]();
    };
    this[pXmlVar].load(pXmlFile);
};
// callback parser Fkt zum erzeugen der clips und der passenden Objekte
this.naviXmlParser = function() {
    //
    var xml = this.naviData.firstChild.childNodes;
    var mainLength = xml.length;
    //
    if (this.naviClipObj == undefined) {
        this.naviClipObj = new Object();
    }
    //
    var k = 0;
    for (var i = 0; i<mainLength; i++) {
        //
        var subLength = xml[i].childNodes.length;
        //
        for (var j = 0; j<subLength; j++) {
            //
            var objTitel = "naviObj_"+i+"_"+j;
            //
            this.naviClipObj[objTitel] = new Object();
            this.naviClipObj[objTitel].clipName = xml[i].childNodes[j].attributes.titel+"_"+i;
            this.naviClipObj[objTitel].clipTiefe = k++;
            this.naviClipObj[objTitel].lineThick = xml[i].attributes.linethick;
            this.naviClipObj[objTitel].lineColor = xml[i].attributes.linecolor;
            this.naviClipObj[objTitel].fillColor = xml[i].attributes.fillcolor;
            this.naviClipObj[objTitel].overColor = xml[i].attributes.overcolor;
            //
            this.naviClipObj[objTitel].w = xml[i].childNodes[j].attributes.w;
            this.naviClipObj[objTitel].h = xml[i].childNodes[j].attributes.h;
            this.naviClipObj[objTitel].x = xml[i].childNodes[j].attributes.x;
            this.naviClipObj[objTitel].y = xml[i].childNodes[j].attributes.y;
            //
            this.createButtonClip(this.naviClipObj[objTitel]);
        }
    }
};
this.xmlLoader("xmlNaviAndShape.xml", "naviData", "naviXmlParser"); 

so ich hab mir einstweilen erklärungen gespart wenn fragen sind immer stellen

see ya

[atothek]

Noch mal ne kleine zip zum runterladen