Formel für Kurvenberechnung ändern - zu hoch für mich ;)

[djdwarf]

Moinsen FF!

Hab vor ner Zeit hier im Forum von jemanden ne nette Formel bekommen, die eine schön bewegung berechnet. Folgendes Script:

PHP-Code:

        if (this._rotation<rotate_to) {
            this._rotation += (rotate_to-this._rotation)/4;
        };
        if (this._rotation>rotate_to) {
            this._rotation -= (this._rotation-rotate_to)/4;
        };
        if (Math.round(this._rotation) == rotate_to) {
                    this._rotation = rotate_to;
        } 


Dieses Script lässt sich auf jegliche Animationen anwenden. Bewegungen, Skalierungen, Drehungen oder sonst was. Die Werte für die Geschwindigkeit der Bewegung, also die Kurve, sehen z.B. so aus:
1000, 250, 62.5, 15.625, 3.90625, 0.9765625.

Wert wird also smooth kleiner. Nun hätte ich die Kurve gerne geändert, in etwa so:
0.9765625, 3.90625, 15.625, 62.5, 250, 1000, 250, 62.5, 15.625, 3.90625, 0.9765625.

Der Wert wird langsam gesteiert und dann wieder geschwächt. Leider ist mein Mathe und damit Kurvenberechnung recht schwach und muss mich damit hier leider geschlagen geben ... ^^ Könnte mir jemand, der bei sowas Durchblick hat dabei helfen? Vielen Dank!

Gruß,
Dwarf

[Der Frager]

Tag!

Nimm einfach irgendeine Easing-Geschichte. Dann kannst du dir das Rechnen schenken...

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
new Tween(this.mc, "_rotation", Strong.easeInOut, 0, 360, 20); 


Noch einen MovieClip mit dem Instanznamen "mc" auf die Bühne packen und gut...

[djdwarf]

Hi ho Frager!


wow .... was es alles gibt nice
Ist bei mir aber schwer anzuwenden, wäre schon nötig, das irgendwie mit dem Script hinzubekommen, weil ich einen onEnterFrame benötige. Ansonsten aber echt nice!

[Der Frager]

Naja, kannst du ja z.B. zusätzlich nehmen:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
var nt = new Tween(this.mc, "_rotation", Strong.easeInOut, 0, 360, 20);
mc.onEnterFrame = function() {
    trace(this._rotation);
};
nt.onMotionFinished = function() {
    delete mc.onEnterFrame;
}; 


[Xeef]

da ich dieses ganze mathe zeug verdauen muss
hab ich mall ein bischen geubt

//das ganze nent sich so ehnilich wie "bezierTween"
_root.createEmptyMovieClip("_mc", 0);
Show(1000, 333, 666);
function Show(lenge, Begin, End) {
    _mc.clear();
    _mc.lineStyle(2, 0, 100);
    //von "+= 0.05" hengt es ab wiviele srite es sind
    for (S=0; S<1; S += 0.05) {
        var cx = 3*Begin;
        var bx = 3*(End-Begin)-cx;
        var ax = lenge-cx-bx;
        //
        var S2 = S*S;
        var S3 = S2*S;
        //
        var X = (ax*S3)+(bx*S2)+(cx*S);
        _mc.moveTo(X, 100);
        _mc.lineTo(X+1, 100);
    }
}
//
_root.createEmptyMovieClip("Start", 1);
Start.beginFill(0, 100);
Start.lineTo(20, 0);
Start.lineTo(20, 20);
Start.lineTo(0, 20);
Start.lineTo(0, 0);
Start.endFill();
Start._y = 200;
Start._x = 333;
Start.onPress = function() {
    this.X = _xmouse;
    Start.onEnterFrame = function() {
        this._x -= this.X-_xmouse;
        this.X = _xmouse;
        Show(1000, _root.Start._x, _root.End._x);
    };
};
Start.onRelease = Start.onReleaseOutside=function () {
    this.onEnterFrame = null;
};
//
_root.createEmptyMovieClip("End", 2);
End.beginFill(0, 100);
End.lineTo(20, 0);
End.lineTo(20, 20);
End.lineTo(0, 20);
End.lineTo(0, 0);
End.endFill();
End._y = 200;
End._x = 666;
End.onPress = function() {
    this.X = _xmouse;
    End.onEnterFrame = function() {
        this._x -= this.X-_xmouse;
        this.X = _xmouse;
        Show(1000, _root.Start._x, _root.End._x);
    };
};
End.onRelease = End.onReleaseOutside=function () {
    this.onEnterFrame = null;
};