[Flash MX] FLV PLAYER und Qualität der Wiedergabe

[keithkeith]

Hallo zusammen,
aus verschiedenen Scripten habe ich mir folgendes zusammengebaut und eigentlich hat es auch die letzten zwei, drei Jahre funktioniert.
Nun habe ich das Problem, dass ein aus youtube runtergeladener Film Pixelig dargestellt wird.

import mx.video.*;
datei = "flv/film.flv";

autostart = true; // true = Autostart, false = kein Autostart 
if(autostart == false){ 
    pauseMovie(); 
}  

//Net-Connection-Objekt
var nc:NetConnection = new NetConnection();
//Streaming Video Lokal
nc.connect(null);
//NetStreamObjekt
var film:NetStream = new NetStream(nc);
//NetStream-Status (onStatus)
film.onStatus = function(info:Object) {
	//Validation durch infoObject
	if (info.code == "NetStream.Play.StreamNotFound") {
		trace("Videodatei nicht vorhanden");
	} else if (info.code == "NetStream.Buffer.Full") {
		clearInterval(statusID);
		statusID = setInterval(videoStatus, 200);
		trace("Buffer voll und Start");
	} else if (info.code == "NetStream.Play.Stop") {
		trace("FilmEnde");
	}
	//Statusausgabe                                        
	trace("NetStream-Status");
	trace("Level: "+info.level);
	trace("Level: "+info.code);
	trace("#-----------------------#");
};
//NetStream-Videosignal an das Video-Objekt anhängen
mc_video.attachVideo(film);
//Zwischenspeicherzeit festlegen
film.setBufferTime(2);
//Videowiedergabe Autostart
film.play(datei);
//Metadaten ermitteln
film.onMetaData = function(infoObject:Object) {
	for (var eigenschaft in infoObject) {
		trace(eigenschaft+" = "+infoObject[eigenschaft]);
	}
	gesamtZeit = infoObject.duration;
};
//Ladebalken beim Start ausblenden
loader_mc.ladeBalken_mc._visible = false;
//Play und play_btn verstecken
play_btn._visible = false;
function playMovie() {
	if (!isStarted) {
		//playText.txt.text = "loading ..";
		film.pause(false);
		isStarted = true;
		starbild._visible = false;

	} else {
		film.pause();
	}
	pause_btn._visible = true;
	play_btn._visible = false;
}
// Pause und pause_btn verstecken
function pauseMovie() {
	film.pause();
	play_btn._visible = true;
	pause_btn._visible = false;
}
// Zurück an Anfang des Film springen play_btn verstecken
function backMovie() {
	film.seek(0);
	film.pause(true);
	play_btn._visible = true;
	pause_btn._visible = false;
	loop2_btn._visible = false;
	loop_btn._visible = true;
	starbild._visible = true;
	clearInterval(statusID);
	clearInterval(loopID);

}
//
//
//
//Button Play Video abspielen
play_btn.onRelease = function() {
	starbild._visible = false;
	playMovie();
};
//Button Stop Video stoppen
pause_btn.onRelease = function() {
	pauseMovie();
};
//Button zurückspulen
zurueck_btn.onRelease = function() {
	backMovie();
	loader_mc.zeiger_mc._x = 0;
	statusID = setInterval(videoStatus, 100);
	clearInterval(loopID);
//	loopStatus_txt.text = "Loop gestopt";
};

//#################################################
//Ladebalken cBL(checkBytesLoaded)
video_iv = setInterval(cBL, 500, film);
function cBL(mein_ns:NetStream) {
	var prozent:Number = Math.round(mein_ns.bytesLoaded*100/mein_ns.bytesTotal);
	loaded_txt.text = Math.round(mein_ns.bytesLoaded/1024)+" of "+Math.round(mein_ns.bytesTotal/1024)+" KB geladen ("+prozent+"%)";
	balkenLaenge = 300;
	loader_mc.ladeBalken_mc._width = prozent*(balkenLaenge/100);
	if (loader_mc.ladeBalken_mc._width>1) {
		loader_mc.ladeBalken_mc._visible = true;
	}
	//kein if(prozent>=100) verwenden, ist ungenau mit der Bytesanzeige   
	if (mein_ns.bytesLoaded>=mein_ns.bytesTotal) {
		clearInterval(video_iv);
		delete video_iv;
	}
}
//Time Aktuelle Spieldauer ermitteln 
var time_interval:Number = setInterval(checkTime, 500, film);
function checkTime(t:NetStream) {
	var t:Number = t.time;
	var m:Number = Math.floor(t/60);
	var s = Math.floor(t%60);
	if (s<10) {
		s = "0"+s;
	}
	var mG:Number = Math.floor(gesamtZeit/60);
	var sG = Math.floor(gesamtZeit%60);
	if (sG<10) {
		sG = "0"+sG;
	}
	time_txt.text = m+":"+s+" / "+mG+":"+sG;
}
//Position dea Abspielknopfes ermitteln
function videoStatus() {
	if (loader_mc.zeiger_mc._x<300) 
	{
		loader_mc.zeiger_mc._x = film.time/gesamtZeit*loader_mc._width;
	}
}
// Abspielknopf mit Maus bewegen
loader_mc.zeiger_mc.onPress = function() {
	clearInterval(statusID);
	film.pause();
	this.onEnterFrame = function() {
		this.startDrag(false, 0, this._y, 300, this._y);
		seekPos = loader_mc.zeiger_mc._x*gesamtZeit/loader_mc._width;
		film.seek(seekPos);
	};
};
// Abspielknopf stoppen
loader_mc.zeiger_mc.onRelease = loader_mc.zeiger_mc.onReleaseOutside=function () {
	delete this.onEnterFrame;
	film.pause(false);
	this.stopDrag();
	pause_btn._visible = true;
	play_btn._visible = false;
};
//############ A U D I O #######################
//Lautstärke bei Start
vol = 50;
vol_txt.text = vol;
sound.attachSound(film);
var audio:Sound = new Sound(sound);
audio.setVolume(vol);
//Sound Buttons
soundAus_btn.onRelease = function() {
	audio.setVolume(0);
	soundAus_btn._visible = false;
	soundAn_btn._visible = true;
};
soundAn_btn.onRelease = function() {
	audio.setVolume(vol);
	soundAus_btn._visible = true;
	soundAn_btn._visible = false;
};

//Lautstaärke Regelung
vol_mc.drag_mc.onPress = function() {
	this.onEnterFrame = function() {
		this.startDrag(false, 0, 0, 100, 0);
		vol = Math.floor(vol_mc.drag_mc._x);
		audio.setVolume(vol);
		vol_txt.text = vol;
	};
};
vol_mc.drag_mc.onRelease = vol_mc.drag_mc.onReleaseOutside=function () {
	delete this.onEnterFrame;
	this.stopDrag();
};
if(autostart == false){ 
    film.pause(); 
    play_btn._visible = true; 
}  
//#323835

Irgendwie hat das vielleicht auch mit der methode zutun, mit der ich den Film, bzw. in welcher Qualität ich den Film runter lade ? Spiele ich Ihn aber in einem fertigen Player ab, sieht alles gut aus.

Liebe Grüße ... Martin

[nalin]

hallo keithkeith.

schreib mal in den ersten frame:
_root.quality="BEST" BZW quality="best"

oder auch als "quality" parameter in dein einbettungs skript.

beste grüße.