flexibler ankerpunkt und rotation eines movieclips

[here2stay]

hallöchen,

eine sache bereitet mir gerade etwas kopfzerbrechen. oder vielmehr die mathematik dahinter.

ich habe mal eine "interaktive" skizze gebaut, damit ich nicht lange erklären muss und hoffentlich jeder versteht

http://www.here2stay.com/drehung.swf

es geht darum, dass ich gerne einen mc um genau den punkt drehen lassen möchte, wo mit der maus geklickt wird.
in meinem beispiel funktioniert das beim ersten mal auch tadellos, aber anschließend gerät das koordinatensystem durch die rotation in schieflage und meine simple milchmdächenrechnung greift nicht mehr

hier noch ganz kurz mein bisheriges script dahinter:

PHP-Code:

// dummy = container mc
// dummy.box = eigentlicher clip (grafik)

dummy.onPress = function() {
    
    var mx = this._xmouse;
    var my = this._ymouse;
    
    this.box._x -= mx;
    this.box._y -= my;

    this._x += mx;
    this._y += my;
    
    this.pressed = true;
    
}

dummy.onRelease = dummy.onReleaseOutside = function() {

    this.pressed = false;

}

dummy.onEnterFrame = function() {
    
    if (this.pressed) {
        
        this._rotation += 1;
        
    }
    
} 


ich hoffe, was ich meine ist klar geworden. im prinzip benötige ich eine lösung für "positionierung des ankerpunktes" inkl. der ganzen sinus-/cosinus-berechnungen um die positionen im gedrehten koordinatensystem wieder zu rekonstruieren

hat irgendjemand sowas schon mal gemacht oder hat ansätze?

besten dank und schönen gruß
felix

[thomas_E]

in AS2:

//code liegt bei mir in der Hauptzeitleiste, also nicht direkt auf dem Objekt
import flash.geom.Point;
 
function rotateAroundCenter(target:MovieClip, angle:Number, isRad:Boolean)
{
    var bounds:Object = target.getBounds(target);
    var center:Point = new Point((bounds.xMin+bounds.xMax)/2,(bounds.yMin+bounds.yMax)/2);
 
    rotateAroundPoint(target, angle, isRad, center, false);
}
 
function rotateAroundPoint(target:MovieClip, angle:Number, isRad:Boolean, rotationPoint:Point, rpIsGlobal:Boolean)
{
    var aRad:Number;
    if(!isRad){
        aRad = angle * Math.PI/180;
    }else{
        aRad = angle;
        angle *= 180/Math.PI;
    }
        
    var rp:Point = new Point(0,0);
    if(rotationPoint && !rotationPoint.equals(rp)){
        
        rp = rotationPoint.clone();
        if(!rpIsGlobal){
            target.localToGlobal(rp);
        }
        if(target._parent != _root){
            target._parent.globalToLocal(rp);
        }
        
        var ox:Number = rp.x - target._x;
        var oy:Number = rp.y - target._y;
        
        var d:Number = Math.sqrt(ox*ox+oy*oy);
        var a:Number = Math.atan2(oy,ox) + aRad;
        
        target._x = (rp.x - Math.cos(a)*d);
        target._y = (rp.y - Math.sin(a)*d);
    }
 
    target._rotation += angle;  
}
 
dummy.onPress = function() {
    this.rp = new Point(_root._xmouse, _root._ymouse);
    this.pressed = true;
}
 
dummy.onRelease = dummy.onReleaseOutside = function() {
    this.pressed = false;
}
 
dummy.onEnterFrame = function() {
    if(this.pressed) {
        rotateAroundPoint(dummy.box, 1, false, this.rp, true);
    }else{
        rotateAroundCenter(dummy.box, 1, false);
    }
} 

AS3 hab ich hier mal gebaut: Parent aus Klasse / Funktion ansprechen

[here2stay]

super! das es mit der matrx in as3 so einfach geht, wusste ich mal wieder nicht kleiner wink mit dem zaunpfahl dahin, hätte auch gereicht danke dir vielmals!

[here2stay]

mittlerweile bin ich durch zufall auch noch auf eine andere lösung gestoßen... das ganze funktioniert praktisch nur mit localToGlobal bzw globalToLocal... auch ganz nett

as2:
Dynamic MovieClip Registration with AS2 - darron schall

as3:
Oscar Trelles - Interaction Architect, Flash Developer

wurde an anderer stelle hier auch schon im forum verlinkt, aber da ich es über die suche nicht gefunden habe, füge ich es hier der vollständigkeithalber nochmal an

[thomas_E]

ey, danke für die Links, hatte ich bisher auch nicht gekannt.
ist ein genial einfacher Ansatz.

ich werd am WE mal nen Performancevergleich zu meinem Code mit der Matrix machen. bin echt gespannt.

[thomas_E]

kurzer Nachtrag, für alle die es interessiert:
hatte den Post leider vergessen. bin erst durch einen anderen wieder daran erinnert worder.

ich wollte ja einen Vergleich zu meiner Variante mit transform.matrix machen.
mein Ergebnis: die Variante mit der transform.matrix war im Durchschnitt um ~50% langsamer als die zuletzt verlinkte.

getestet hab ich 50 Durchläufe a 10000 drehungen desselben Objektes.
transform.matrix: ~90ms/10000 drehungen.
verschieben: ~60ms/10000 drehungen.