flashstar - xml laden as optimieren

[canon]

hallo forum!

ich hab hier über das forum ein tolles tutorial von "flashstar" gefunden in dem ein xml text geladen wird.
da ich das ganze jetzt mit zwei xml dateien in verschiedenen mc's benutze
kamen bei mir 2 fragen dazu auf:

frage 1:
ist es möglich news2.xml erst zu laden wenn news1.xml fertig geladen ist?


frage 2:
bis auf meinXML.load("news1.xml") bzw. meinXML.load("news2.xml") ist das AS bei beiden gleich. deshalb meine frage: kann man da nicht den AS block für beide benutzen?
(irgendwie so in den mc's nur noch das meinXML.load("news1.xml") nötig ist)

hier mal das ganze AS:

meinXML = new XML();
//
meinXML.load("news1.xml");
//
meinXML.ignoreWhite = true;
meinXML.onLoad = function(status) {
    if (status) {
        tempXML = meinXML.firstChild.childNodes;
        titel = tempXML[0].attributes.titel;
        datum = tempXML[0].attributes.datum;
        verweis = tempXML[0].attributes.url;
        autor_mc.gotoAndStop(tempXML[0].attributes.autor);
        delete meinXML;
    }
};
aktNews = 0;
aktNewsNr = aktNews+1;
this.onEnterFrame = function() {
    if (aktNews<tempXML.length-1 && signal) {
        aktNews++;
        aktNewsNr = aktNews+1;
        titel = tempXML[aktNews].attributes.titel;
        datum = tempXML[aktNews].attributes.datum;
        verweis = tempXML[aktNews].attributes.url;
        autor_mc.gotoAndStop(tempXML[aktNews].attributes.autor);
        signal = 0;
        clearInterval(iv);
    }
    if (aktNews>=tempXML.length-1 && signal) {
        aktNews = -1;
        aktNewsNr = 1;
    }
}; 

hab auch mal direkt ein aufgeräumtes beispiel angehangen. würde mich über tipps sehr freuen!

schönen tag! canon

[psyk]

Lege das Ganze in eine Funktion ruf dann nachdem fertig laden des
ersten nochmals auf.

PHP-Code:

var xmlSuccess1 = false;
var xmlSuccess2 = false;
myLoad("news1.xml");

function = myLoad( url ) { ...
   meinXML.load( url );
   meinXML.onLoad = function(status) 
   {
      if (status) 
      {
         if( !xmlSuccess1 ) // wenn erste gelanden
         {
            xmlSuccess1 = true;
            _root.myLoad( "news2.xml" );
         }
         else xmlSuccess2 = true; // setzt beide auf geladen
         // etc. ... 


[canon]

hi!
danke damit wäre meine frage 1 schon mal abgehackt!


hat jemand denn auch eine antwort zu meiner frage 2:?
bis auf meinXML.load("news1.xml") bzw. meinXML.load("news2.xml") ist das andere AS bei beiden gleich. deshalb meine frage: kann man da nicht das AS für beide benutzen?
(irgendwie so das in den mc's nur noch das meinXML.load("news1.xml") nötig ist - siehe angehangendes beispiel)

wäre doch super wenn man sich die 35 zeilen code in beiden für beide sparen könnte!

mfg
canon

[psyk]

Meine Lösung umfasst beide Fragen.

[Omega Psi]

Ich habe mal eine OOP-Lösung dazu geschrieben:

/** */
class MyXML extends XML {
    /** */
    private var files:Array;
    /** */
    private var index:Number;
    /** */
    public function MyXML(files:Array) {
        trace("class MyXML: constructor");
        this.index = 0;
        this.files = files;
        this.init();
    }
    /** */
    public function init() {
        trace("class MyXML: function init");
        this.load(files[index]);
    }
    /** */
    public function onLoad(success:Boolean) {
        trace("class MyXML: listener onLoad");
        if (success) {
            this.parseFile(this);
            this.index++;
            if (this.index<this.files.length) {
                this.load(files[index]);
            }
        } else {
            trace("class MyXML: listener onLoad - an error occured: no file '"+files[index]+"' found.");
            this.index++;
            if (this.index<this.files.length) {
                this.load(files[index]);
            }
        }
    }
    /** */
    public function parseFile(xml:XML):Void {
        trace("class MyXML: function parseFile");
        if (this.index == 0) {
            this.parseFirstFile(xml);
        } else if (this.index == 1) {
            this.parseSecondFile(xml);
        } else if (this.index == 2) {
            this.parseThirdFile(xml);
        }
    }
    /** */
    public function parseFirstFile(xml:XML):Void {
        trace("class MyXML: function parseFirstFile");
        trace(xml);
    }
    /** */
    public function parseSecondFile(xml:XML):Void {
        trace("class MyXML: function parseSecondFile");
        trace(xml);
    }
    /** */
    public function parseThirdFile(xml:XML):Void {
        trace("class MyXML: function parseThirdFile");
        trace(xml);
    }
} 

Hier die Initialisierung des Objektes:

var myxml:MyXML = new MyXML(new Array("xml1.xml", "xml2.xml", "xml3.xml")); 

Es ist kaum ein Unterschied zu dem, was in ActionScript 1 passiert, nur dass alles etwas besserer strukturiert ist, und Scope Probleme wegfallen. Da du nur einen Parse-Vorgang hast, reicht bei dir die Verarbeitung in parseFile:

/** */
public function parseFile(xml:XML):Void {
    trace("class MyXML: function parseFile");
    trace(xml);
} 

In dem Fall werden alle drei Dateien per XML ausgelesen obwohl du nur eine Funktion hast. Du musst die Daten aber in einer neuen datenstruktur übertragen/verarbeiten, da nach jedem neuen load() der Inhalt des Objektes überschrieben wird.

Anwendung (Flash 8) und Code + XML-Dateien im Attachment

[psyk]

Du hast scheinbar viel zu viel Zeit.

Hübsch, hübsch.



psyk
... der auch schon auf rise of the silver surfer freut

[canon]

hallo zusammen!

also die lösung von Omega Psi ist mir als anfänger viel zu viel. ich blicke schon nicht bei der vermeitlich "einfacheren" variante vom psyk richtig durch!

ich hab probiert das AS einzubauen und bekomme immer den fehler:

PHP-Code:

**Fehler** Symbol=TypoClip, Ebene=Actions, Bild=1:Zeile 8: Funktionsname erwartet
     function = myLoad( url ) { 


was hab ich da falsch gemacht?

mfg

[psyk]

Ich wollte mir ja eigentlich das ganze Geschreibe sparen.

PHP-Code:

var xmlSuccess1 = false;
var xmlSuccess2 = false;
xmlLoad( "news1.xml" );

function xmlLoad( url ) 
{
    var meinXML = new XML();
    //
    meinXML.load( url );
    //
    meinXML.ignoreWhite = true;
    meinXML.onLoad = function(status) 
    {
        if (status) 
        {
            if( !xmlSuccess1 ) // wenn erste gelanden
            {
            xmlSuccess1 = true;
            _root.myLoad( "news2.xml" );
            }
            else xmlSuccess2 = true; // setzt beide auf geladen

            tempXML = meinXML.firstChild.childNodes;
            titel = tempXML[0].attributes.titel;
            datum = tempXML[0].attributes.datum;
            verweis = tempXML[0].attributes.url;
            autor_mc.gotoAndStop(tempXML[0].attributes.autor);
            delete meinXML;
        }
    };
    aktNews = 0;
    aktNewsNr = aktNews+1;
    this.onEnterFrame = function() 
    {
        if (aktNews<tempXML.length-1 && signal) 
        {
            aktNews++;
            aktNewsNr = aktNews+1;
            titel = tempXML[aktNews].attributes.titel;
            datum = tempXML[aktNews].attributes.datum;
            verweis = tempXML[aktNews].attributes.url;
            autor_mc.gotoAndStop(tempXML[aktNews].attributes.autor);
            signal = 0;
            clearInterval(iv);
        }
        
        if (aktNews>=tempXML.length-1 && signal) 
        {
            aktNews = -1;
            aktNewsNr = 1;
        }
    };
} 


[Omega Psi]

var counter:Number = 0;
var urls:Array = new Array("xml1.xml", "xml2.xml", "xml3.xml");
var xml:XML = new XML();
xml.ignoreWhite = true;
xml.onLoad = function(success:Boolean) {
    trace("listener onLoad called");
    if (success) {
        parseXML(this);
        counter++;
        if (counter<urls.length) {
            this.load(urls[counter]);
        }
    } else {
        trace("No files found.");
    }
};
xml.load(urls[counter]);
/** */
function parseXML(xml:XML) {
    trace("function parseXML() called");
    trace(xml);
} 

Hier die Ausgabe meiner Testdateien.

listener onLoad called
function parseXML() called
<?xml version="1.0" encoding="utf-8"?><test id="1">Dies ist der erste Test.</test>
listener onLoad called
function parseXML() called
<?xml version="1.0" encoding="utf-8"?><test id="2">Dies ist der zweite Test.</test>
listener onLoad called
function parseXML() called
<?xml version="1.0" encoding="utf-8"?><test id="3">Dies ist der dritte Test.</test>

Das ganz ist eigentlich sehr einfach gehalten:

1. Zähler deklarieren und initialisieren: Zeile 1
2. Array deklarieren und initialisieren, in dem die Pfade zu den XML-Dateien gespeichert sind: Zeile 2
3. XML-Objekt deklarieren, initialisieren und konfigurieren. Dazu gehören auch die Listener: Zeile 3-5
4. In der onLoad() wird nun nach erfolgreichem Ladevorgang (Start des Ladevorganges Zeile 17) die Funktion parseXML() aufgerufen. Da diese in deinem Fall immer gleich ist, muss nur noch dein Code eingefügt werden.
5. Nach der Verarbeitung der XML-Daten wird der Zähler hochgezählt und falls das Ende des Array noch nciht erreicht ist, wird die nächste Referenz auf eine Datei geladen und ein weiteres mal XML.load() ausgeführt. Das ganze passiert dann so oft, wie Dateien im Array referenziert werden.

ToDos:

• Sollen verschiedene Dateien geladen werden, kann man mit Hilfe des counter Fallunterscheidungen machen.
• Fehlerbehandlungen: wenn keine Dateigefunden wurde - nächste Datei laden?

[canon]

wow erstmal vielen dank an euch beiden für die tolle hilfe bisher!

ich hab nur noch eine frage:
wenn ich die xml dateien dann in der root timeline vorgeladen habe - wie weise ich den geladenen inhalt dann auf die textfelder der verschiedenen mc's zu?

(ich hoffe ich hab das nicht übersehen - ist halt alles noch etwas zu heavy für mich )

mfg