Flächenfüllung mit Loch

[Papa_Lars]

Hallo,

vielleicht kann mir jemand weiterhelfen?
Es wird interaktiv so etwas erstellt, wie weiter unten zu sehen ist.
Ich habe folgendes Problem: Die grüne Füllung soll nicht grün, sondern durchsichtig sein - also das Hintergrundbild zu sehen sein.
Der Code dazu sieht so aus:

PHP-Code:

function fuellen(){
mc.createEmptyMovieClip("polygon"+objekt, 300-objekt);
    with(mc["polygon"+objekt]){
        lineStyle(1, 0x000000);
        if(objekt==0){
            beginFill(0x00ff00,100);
        }
        else if(objekt==1){
            beginFill(0x0000ff,100);
        }
        moveTo(punkt[objekt][0][0], punkt[objekt][0][1]);
        for(var i=1; i<zaehler[objekt]; i++){
            lineTo(punkt[objekt][i][0], punkt[objekt][i][1]);
        }
        endFill();
    }
    objekt += 1;
} 


Wenn ich den Alphawert der grünen Füllung auf 0 setze, erscheint natürlich die blaue Farbe - gut, das war mir ja schon fast klar.
Wie aber kann ich das grüne Polygon durchsichtig machen, so dass das darunter liegende Bild sichtbar wird?

[ingohill]

unction fuellen(){
mc.createEmptyMovieClip("polygon"+objekt, 300-objekt);
    with(mc["polygon"+objekt]){
        lineStyle(1, 0x000000);
        if(objekt==0){
            beginFill(0x00ff00,0);
        }
        else if(objekt==1){
            beginFill(0x0000ff,100);
        }
        moveTo(punkt[objekt][0][0], punkt[objekt][0][1]);
        for(var i=1; i<zaehler[objekt]; i++){
            lineTo(punkt[objekt][i][0], punkt[objekt][i][1]);
        }
        endFill();
    }
    objekt += 1;
} 

-ingo

[Papa_Lars]

Ja, das hatte ich ja schon versucht - da besteht allerdings das Problem, dass das grüne Polygon zwar durchsichtig wird, dann aber die blaue Farbe des darunter liegenden blauen Polygons zum Vorschein kommt.
Irgendwie müsste ein Loch von der Größe des grünen Polygons in das blaue geschnitten werden?

[readme.txt]

Solange du nicht mit endFill das füllen beendest wird nur der Teil befüllt der innerhalb deiner gezeichneten Linien existiert ... hier mal ein vereinfachte sBeispiel mit 2 Quadraten:

PHP-Code:

var quad:MovieClip = _root.createEmptyMovieClip("quad",_root.getNextHighestDepth());
    quad._x = 50;
    quad._y = 50;

quad.lineStyle(1,0xFF0000,100);
quad.beginFill(0xFF0000,100);

// -> Erstmal das äußere Quadrat zeichenen
quad.moveTo(0,0);
quad.lineTo(200,0);
quad.lineTo(200,200);
quad.lineTo(0,200);
quad.lineTo(0,0);
// <- Erstmal das äußere Quadrat zeichenen

// -> jetzt innen ein Quadrat "rausschneiden"
quad.moveTo(50,50);
quad.lineTo(100,50);
quad.lineTo(100,100);
quad.lineTo(50,100);
quad.lineTo(50,50);
// <- jetzt innen ein Quadrat "rausschneiden"

quad.endFill(); 


[Papa_Lars]

Vielen Dank für die Hilfe!
Für die, die es interessiert - der Code sieht nun so aus ...

PHP-Code:

function fuellen(){
    mc.createEmptyMovieClip("polygon", 3);
    with(mc["polygon"]){
        lineStyle(1, 0x000000);
        beginFill(0xFF0000,100);
        moveTo(punkt[0][0][0], punkt[0][0][1]);
        for(var i=1; i<zaehler[0]; i++){
            lineTo(punkt[0][i][0], punkt[0][i][1]);
        }
        moveTo(punkt[1][0][0], punkt[1][0][1]);
        for(var i=1; i<zaehler[1]; i++){
            lineTo(punkt[1][i][0], punkt[1][i][1]);
        }
        endFill();
    }
} 


und erzeugt das hier (siehe Bild unten).
Und nebenbei hat es auch den Effekt, dass ich den hitTest nicht mehr 2x ausführen muss.

Danke
Lars

[Skorpion]

@readme.txt: wuff, hätte nicht geahnt dass es so einfach gehen würde. Klasse!

[readme.txt]

Hehe ... hab ich irgendwann mal durch Zufall rausgefunden ^^