FileReference wartet auf "onComplete"

[ingohill]

hi,

ich benutze das as aus der hilfe, jedoch warte ich vergebens auf "onComplete" oder "onProgress", jedoch kommt auch keine fehlermeldung.
das bild wird auch sauber übertragen, nur flash weiß das nicht.

import flash.net.FileReference;
 
var allTypes:Array = new Array();
var imageTypes:Object = new Object();
imageTypes.description = "Images (*.jpg, *.jpeg, *.gif, *.png)";
imageTypes.extension = "*.jpg; *.jpeg; *.gif; *.png";
allTypes.push(imageTypes);
 
var textTypes:Object = new Object();
textTypes.description = "Text Files (*.txt, *.rtf)";
textTypes.extension = "*.txt;*.rtf";
allTypes.push(textTypes);
 
var listener:Object = new Object(); 
 
listener.onSelect = function(file:FileReference):Void {
    trace("onSelect: " + file.name);
    if(!file.upload("http://www.meinserver.de/flash/bild-upload.php?id=1&nn=123456.jpg")) {
        trace("Upload dialog failed to open.");
    }
}
 
listener.onCancel = function(file:FileReference):Void {
    trace("onCancel");
}
 
listener.onOpen = function(file:FileReference):Void {
    trace("onOpen: " + file.name);
}
 
listener.onProgress = function(file:FileReference, bytesLoaded:Number, bytesTotal:Number):Void {
    trace("onProgress with bytesLoaded: " + bytesLoaded + " bytesTotal: " + bytesTotal);
}
 
listener.onComplete = function(file:FileReference):Void {
    trace("onComplete: " + file.name);
}
 
listener.onHTTPError = function(file:FileReference):Void {
    trace("onHTTPError: " + file.name);
}
 
listener.onIOError = function(file:FileReference):Void {
    trace("onIOError: " + file.name);
}
 
listener.onSecurityError = function(file:FileReference, errorString:String):Void {
    trace("onSecurityError: " + file.name + " errorString: " + errorString);
}
 
var fileRef:FileReference = new FileReference();
fileRef.addListener(listener);
 
// button liegt auf  der bühne!
my_button.onRelease = function(){
    fileRef.browse(allTypes);   
}
 
stop(); 

wie kann ich das ändern?
vielen dank im voraus,

ingo

[ingohill]

ja, ich weiß: die SuFu.
jetzt habe ich auch besser gesucht:

PHP-Code:

echo " "; 


fördert das "onComplete".

-ingo