Farbe heller berechnen?

[Mr.Twister]

hi,

meine Farbe 0xcc0000 ist mir für einen gewissen Fall zu dunkel. Ich möchte einen Farbwert hinzuaddieren, um einen helleren Ton zu bekommen.

0xcc0000 + 0x333333 = 0xff3333;
Wunderbar!

Nun möchte ich die Farbe aber noch heller haben:
0xcc0000 + 0x444444 = 0x1104444;
PLÖT!

Mir ist zwar klar, wieso das passiert, aber kennt evtl. jemand eine Berechnung, in der die einzelnen Farbkanäle nicht über ff gesteuert werden?

thx 4 tips!

[SpecOps-12]

Hexadezimalzahlen zusammenrechnen ist ja eigentlich auch kaum eine Lösung, weil eine Steigerung um sagen wir 3355443 (0x333333) nicht eine symetrische Helligkeitsveränderung darstellt sondern ne ganz andre Farbe im Farbraum sein kann.

Ich hab für sowas mal ne kleine hex-color-Brightness-Klasse geschrieben, die über den Zwischenschritt geht, die Hex-Zahl in ein rgb-Array umzuwandeln und später wieder zurück.
Allerdings AS3, aber das Prinzip ist auch AS1-tauglich und sollte leicht umschreibbar sein.

[Mr.Twister]

öhm, okay.
du scheinst also einen ähnlichen weg zu gehen, wie ich es im moment mache:

PHP-Code:

function getBrightColor(col, bright){
    if(bright == undefined){
        bright = 0x888888;
    }
    ra = (col & 0xff0000) >> 16;
    ga = (col & 0x00ff00) >> 8;
    ba = col & 0x0000ff;
    
    rb = (bright & 0xff0000) >> 16;
    gb = (bright & 0x00ff00) >> 8;
    bb = bright & 0x0000ff;
    
    rc = ra+rb;
    if(rc > 255){
        rc = 255;
    }
    gc = ga+gb;
    if(gc > 255){
        gc = 255;
    }
    bc = ba+bb;
    if(bc > 255){
        bc = 255;
    }
    
    hex = "0x" + (rc << 16 | gc << 8 | bc).toString(16);

    return hex;
} 


nungut, ich lasse es einfach dabei. dachte, evtl. gibt es einen ganz schlanken weg, aber so ist's auch okay.

thx

[SpecOps-12]

Nicht das ich wüsste.
Ab AS2 kann man natürlich ColorTransform oder ne TweenKlasse direkt auf's Objekt ansetzen.

Außer r,g und b aufzutrennen und einzeln zu berechnen gibt's keinen Weg.
Weil Hex-Zahlen sind für Flash ganz normale Zahlen, das sieht man auch, wenn man mal eine austraced. Und da kann dann im Farbraum, übertrieben gesprochen, 1.225.222 noch kaminrot sein, 1.225.223 dann aber giftgrün.

[mk-anti]

is ja jetzt schon ein paar jahre her. war aber genau das was ich gebraucht habe...Danke. ich war mal so frei und hab die oben gepostete klasse umgeschrieben.

Den Satz habe ich nicht verstanden:
"Außer r,g und b aufzutrennen und einzeln zu berechnen gibt's keinen Weg."

PHP-Code:


package
    {
    import NumberUtil;
    

    public class colorTransform 
        {
            
        public static function brightness(color:uint, amount:Number):uint 
            {
            var rgb:Array = NumberUtil.hexToDec(color);

            for (var i:String in rgb)
                {
                rgb[i] += Math.round(255 / 100 * amount);
                if (rgb[i]> 255) rgb[i] = 255; else if (rgb[i] < 0) rgb[i] = 0;
                }                
                
            return NumberUtil.decToHex(rgb);
            }
            
            
        }
    }



package 
    {        
    public class NumberUtil
        {

        public static function hexToDec(hex:uint):Array 
            {
            var r:int=hex >> 16 & 0xFF;
            var g:int=hex >> 8 & 0xFF;
            var b:int=hex & 0xFF;
            return [r,g,b];
            }

        public static function decToHex(dec:Array):uint 
            {            
            var hex:String = "";
            
            for (var i:String in dec)
                {
                var ff:String = dec[i].toString(16);
                if (ff.length <= 1) ff = "0" + ff;
                hex += ff;
                }
                
            return uint("0x" + hex);
            }
            
        }
    } 


Jetzt gehts dunkler und heller.