extern bilder laden ->preloader

[destroy90210]

hi ich mache ne bildgallerie grade und möchte die bilder beim reinladenmit nem preloader versehn

der code

_root.picsPreloader = function(dataArray) {
    //speichert den pfad in mc ab
    mc = _root.photoDummy;
    //erstellt den genauen pfad mit bildname
    newPicName = "../bilder/photos/"+[dataArray[0]]+".jpg";
    //laden des photos
    mc.loadMovie(newPicName);
    //prelaoder
    total = mc.getBytesTotal();
    geladen = mc.getBytesLoaded();
    prozent_str = Math.round((geladen/total)*10000);
    trace(_root.photoDummy.getBytesTotal());
    onEnterFrame = function () {
        if (geladen == total) {
            ...
        }
    };
}; 

leider bekomme ich immer 10 getraced und nie die richtigen kb's des bildes

weiss wer warum ??

mfg,
destroy90210

[Alphanimal]

weil der dummy MC 10 Bytes hat (möglicherweise)

Beim externen Laden mit Preloader würde ich MovieLoader verwenden.

also:

ml = new MovieLoader()

oder sowas, weiss jetzt nicht wies genau funzt. schau in die Hilfe!

dann kannst du mit Events den Status abfragen

ml.onProgress = function()....
wird jedes mal aufgerufen wenn sich die geladenen Bytes verändern...

[destroy90210]

ok
habs gefunden heisst new MovieClipLoader(); echt geil habe nicht gewusst das es sowas gibt, werds ma gleich mal anschaun

mfg,
destroy90210

[nullidee]

du fragst ja nur einmal ab. schau dir mal diese ladefunction an.
Ist von Salazar aus diesem Forum.

PHP-Code:

ladestatus = function () {
        // Einen onEnterFrame-Event erstellen, so dass nun
        // der Ladezustand kontinuierlich abgefragt und
        // angezeigt wird
        loader.onEnterFrame = function() {
                // Geladene und zu ladenede Bytetes abfragen
                geladen = _root.ladeziel.getBytesLoaded();
                zuladen = _root.ladeziel.getBytesTotal();
                // Sicherheitsabfrage, da ein leerer MC so ungefähr
                // 4 bis 5 Bytes hat und zu Verfälschungen führen könnte
                if (geladen>=10) {
                        // Ladeanzeige sichtbar machen
                        loader._visible = true;
                        // Berechnung der bereits geladenen Prozent
                        prozent = Math.round(geladen/zuladen*100);
                        // Ausgabe im dynamischen Textfeld "prozentanzeige"
                        this.prozentanzeige.text = prozent+" Prozent geladen";
                        // Skalierung des Balkens anhand der Prozentzahl
                        this.balken._xscale = prozent;
                        // Wenn komplett geladen
                        if (prozent>=100) {
                                // den EnterFrame-Event löschen um Performance zu sparen
                                delete this.onEnterFrame;
                                // die Ladeanzeige wieder unsichtbar machen
                                this._visible = false;
                        }
                }
        };
};
ladeziel.loadMovie("film2.swf");
ladestatus(); 


[destroy90210]

so, ich habe es jetzt schon mal geschafft mit der classe bilder zu laden nur leider geht da irgendwas nicht so genau wie ich mag bzw. ich mache nen fehler, weiss aber nicht welchen

//resizen
MovieClip.prototype.resizen = function(width, height, delay) {
    var mc = this;
    _root.resizeFinish = false;
    onEnterFrame = function () {
        mc._width += (width-mc._width)/delay;
        mc._height += (height-mc._height)/delay;
        if (Math.abs((width-mc._width))<=1 && Math.abs((height-mc._height))<=1) {
            mc._width = width;
            mc._height = height;
            delete onEnterFrame;
            _root.resizeFinish = true;
        }
    };
};
//fade
MovieClip.prototype.fade = function(step, end) {
    var mc = this;
    _root.alphaFinish = false;
    //startwert des alphawerts des mc's
    start = mc._alpha;
    //wieviel loops durchlaufen werden müssen bis der enwert erreicht worden ist
    loops = Math.abs((start-end)/step);
    i = 0;
    onEnterFrame = function () {
        i++;
        mc._alpha += step;
        if (i>=loops) {
            mc._alpha = end;
            delete onEnterFrame;
            _root.alphaFinish = true;
        }
    };
};
var my_mcl = new MovieClipLoader();
myListener = new Object();
myListener.onLoadStart = function(target_mc) {
    trace("onlodstart");
    _root.photoDummy._alpha = 0;
    loadProgress = my_mcl.getProgress(target_mc);
};
myListener.onLoadProgress = function(target_mc, loadedBytes, totalBytes) {
    trace("onLoadProgress");
    _root.test.text = loadedBytes;
};
myListener.onLoadComplete = function(target_mc) {
    trace("onLoadComplete");
 
};
myListener.onLoadInit = function(target_mc) {
    trace("onLoadInit");
    width = target_mc._width;
    height = target_mc._height;
    _root.bgContent.resizen(width, height, 5);
//sobald ich das onEnterFrame hier ausführe, will er meinen hintergund nicht mehr resizen, wenn ich ds auskommentiere dann resizt er...
//er scheint nicht mal ins onEnterFrame hinzugehen, weill wenn ich da was tracen mag dann traced er nix
    onEnterFrame = function () {
trace("irgendwas");
        if (_root.resizenFinish == true) {
            delete onEnterFrame;
            _root.bgContent.fade(5, 100);
        }
    };
};
myListener.onLoadError = function(target_mc, errorCode) {
    trace("onLoadError");
};
my_mcl.addListener(myListener);
// laden des ersten bildes
my_mcl.loadClip("../bilder/photos/lisi1.jpg", _root.photoDummy); 

die frage ist im code kommentiert

weiss wer was da falsch ist bzw. wie man das richtig lösen könnte
hoffe man erkennt was ich vorhabe.


mfg,
destroy90210

[Alphanimal]

so wie ich das sehe versuchst du dem Listener ein onEnterFrame Event zu verpassen.
Das hat keinen Sinn, weil der Listener nicht für einen MC ist, sondern für den MovieClipLoader...

versuch mal
_root.photoDummy.onEnterFrame = ...

oder nur
_root.onEnterFrame = ...

sollte halt ein MC sein! ein MovieClipLoader hat kein onEnterFrame Event

[velmts]

hallo,

entschuldigung wenn ich einfach mal so diesen thread einnehme
aber ich hab ebenfalls ein problem mit externen bildern und preloadern

mein skript funktioniert eigentlich, aber nur wenn ich die if schleife weg lassen
warum gibts ein problem mit dieser schleife? kann sich das vielleicht jemand mal anschauen:

var i:Number = 0;
test_btn.onRelease = function() {
    //if (i < 35) {
        
        i++;
        
        image_str = "images/" + i + ".jpg";
 
        
        _root.inhalt_mc.loadMovie(image_str);
        var kbgeladen_num:Number;
        var kbgesamt_num:Number;
        
        var id = setInterval(pruefen, 100);
        function pruefen() {
            
            kbgesamt_num = Math.round(_root.inhalt_mc.getBytesTotal() / 1024);
            kbgesamt_str = kbgesamt_num.toString();
            kbgeladen_num = Math.round(_root.inhalt_mc.getBytesLoaded() / 1024);
            kbgeladen_str = kbgeladen_num.toString();
            _root.proz_num = Math.round((kbgeladen_num / kbgesamt_num) * 100);
            if (kbgeladen_num > 0 && kbgeladen_num == kbgesamt_num) {
                clearInterval(id);
            }
        }
    //}
}; 

[Alphanimal]

versuch mal statt:

var i:Number = 0;

einfach nur:

 i = 0;

kann sein dass da derGültigkeitsbereich von i anders definiert wird, ich kenn mich da auch nicht si genau aus.
(kann sein dass i ausserhalb der Funktion eine andere Variable ist als i in der Funktion)

[velmts]

hm, nein bringt leider auch nicht
wenn ich das if weglasse läuft alles
perfekt, aber ich kann so die anzahl der zu ladenen bilder ja nicht mehr einschränken ..

[Der Frager]

Nur mal so: Vielleicht hinter image_str = "images/" + i + ".jpg"; ein trace(image_str); setzten und gucken, was dabei rauskommt...

[velmts]

genau das was ich will: images/1.jpg

das bild wird ja auch geladen usw, nur der preloader
mit prozent anzeige usw funktioniert nicht

[Der Frager]

Vielleicht vorher noch ein

PHP-Code:

_root.inhalt_mc.unloadMovie(); 


reinnehmen und/oder kbgeladen_num und kbgesamt_num auf 0 setzen?

[destroy90210]

also wenn man es ohne den MovieClipLoader

dann geht es so

wobei ich da was nicht so ganz verstehe, ich muss dynamisch nochmal einen MC in meinen Dummy machen das es geht, nur dann zeigt er die kb Anzahl des bildes richtig an, ohne den container photo bekomme ich immer nur 10 als ergebnis....

warum???

_root.picsPreloader = function(dataArray) {
    _root.photoDummy.createEmptyMovieClip("photo", 4);
    mc = _root.photoDummy.photo;
    newPicName = "../bilder/photos/"+[dataArray[0]]+".jpg";
    mc.loadMovie(newPicName);
    onEnterFrame = function () {
        geladen = mc.getBytesLoaded();
        zuladen = mc.getBytesTotal();
        if (geladen>=4) {
            prozent = Math.round(geladen/zuladen*100);
            trace(geladen);
            _root.prozentAnzeige.text = prozent+" Prozent geladen";
            if (prozent>=100) {
                delete onEnterFrame;
            }
        }
    };
}; 

mfg,
destroy90210

[psytr0ll]

nun, da hier schon ne frage zu salazar´s preloader aufgetaucht ist, kann ich ich ja auch gleich mal mitmischen...
Ich habe dessen code abgeändert, so dass mehrere bilder gleichzeitig gepreloaded werden. Das klappt auch wunderbar - die bilder werden geladen, man sieht sie auch wenn
_root["ladeziel"+i]._visible = true;
eingestellt ist. Nur was mir Sorgen bereitet ist die Ladeanzeige : sie zeigt immer nur "818" an. Es kann net an der größe der dateien ("adern"+i) liegen, die ich lade, die sind alle viel größer als 818 byte. Ich verlange ja net, dass der preloader die gesamt byte-zahl aller pics anzeigt, ich weiß ja aus anderen beiträgen(ich mag die suche dass das net geht und alle bilder erst einmal geladen sein müssten. Nur sollte er wenigstens immer von der aktuell zu ladenden datei die richtige größe zeigen.Hier der code:

PHP-Code:

ladestatus = function () {
    
        // Einen onEnterFrame-Event erstellen, so dass nun
        // der Ladezustand kontinuierlich abgefragt und
        // angezeigt wird 
        loader.swapDepths(100);
        loader.onEnterFrame = function() {
            for(i=1;i<6;i++){
                // Geladene und zu ladenede Bytetes abfragen
                geladen = _root["ladeziel"+i].getBytesLoaded();
                zuladen = _root["ladeziel"+i].getBytesTotal();
                _root["ladeziel"+i]._visible = false;
                // Sicherheitsabfrage, da ein leerer MC so ungefähr
                // 4 bis 5 Bytes hat und zu Verfälschungen führen könnte
                if (geladen>=10) {
                        // Ladeanzeige sichtbar machen
                        loader._visible = true;
                        // Berechnung der bereits geladenen Prozent
                        prozent = Math.round(geladen/zuladen*100);
                        // Ausgabe im dynamischen Textfeld "prozentanzeige"
                        this.prozentanzeige.text = geladen+" Prozent geladen"; 
                        
                        // Wenn komplett geladen
                        if (prozent>=100) {
                                // den EnterFrame-Event löschen um Performance zu sparen
                                delete this.onEnterFrame;
                                // die Ladeanzeige wieder unsichtbar machen
                                this._visible = false;
                                
                        }
                }
        };
    }
};
    for(i=1;i<6;i++){
        
_root.createEmptyMovieClip("ladeziel"+i, i);
var pfad = "../../img/tuts/adern/adern"+i+".jpg";
_root["ladeziel"+i].loadMovie(pfad);


}
ladestatus();