erweitern des onEnterFrame

[flash bier]

hallo flashforum,

ist es irgendwie möglich ein onEnterFrame zu erweitern ?
Hmmm.... blöd zu erklären, da bin ich nicht so gut drin.

Bsp:
Also, während das hier läuft:

onEnterFrame=function(){
if(_root.einMC._alpha>0){
_root.einMC._alpha-=1;
}
}

könnte es ja sein, dass zusätzlich folgendes passieren soll:

onEnterFrame=function(){
if(_root.einAndererMc._rotation<30){
_root.einAndererMc._rotation+=1;
}
}

Ich weiss schon dass ich das gleich zusammen in ein EnterFrame packen kann,
und kenne auch setInterval.
Aber es wäre eben sehr viel konfortabler, wenn ich zBsp meinen Buttons sagen könnte, wenn du geklickt wirst, füge dem onEnterFrame folgenden Code hinzu.

Fänds eben nicht schlecht, wenns da was gäbe, was mir dieses ermöglichen würde. Habt ihr da eine Idee ?

Danke
MfG flash bier

[thebiz]

Warum willst Du das in ein onEnterFrame reinpacken.
Du kannst ja auf jeden Movieclip ein onEnterFrame packen.
Also wenn Du auf den Button drückst kann es so aussehen:

PHP-Code:

_root.einAndererMc.onEnterFrame=function(){
if(_root.einAndererMc._rotation<30){
_root.einAndererMc._rotation+=1;
}
} 


[Alois]

jepp über einen Umweg:

//vorher:
deinMC.onEnterFrame=function(){
if(_root.einMC._alpha>0){
_root.einMC._alpha-=1;
}
};
//und jetzt erweitern:
deinMC.altEnterFrame=deinMC.onEnterFrame;
deinMC.onEnterFrame=function(){
this.altEnterFrame();
if(_root.einAndererMc._rotation<30){
_root.einAndererMc._rotation+=1;
}
} 

...uuund feddich.

Gruß

Alois

[flash bier]

Prima Alois!
Danke

MfG flash bier

[thebiz]

Bitte.

[flash bier]

@thebiz:
ich arbeite eben nicht gerne mit 50 onEnterFrames, ohne Begründung !!

Aber vielleicht brauch ich das auch garnicht, aber es war eben ein Gedanke, obs denn überhaupt mal Möglich ist und schwupps wollt ichs wissen!

Danke trotzdem für Deine Hilfe

MfG flash bier

[thebiz]

Ist ja auch besser nicht so viele
onEnterFrames laufen zu haben.
Hast scho' Recht.

[Alois]

und noch etwas update...
ad 1) benutze die variable (altEnterFrame) nicht doppelt sonst kommt es zu einer Fehlermeldung (256 Rekursionsstufen....), wenn Du mehrmahls updaten musst machs eventuell mit einem array:

//Vorbereitung
deinMC.altEnterFrame=new Array(); 
_global.zaehler=0;
//vorher:
deinMC.onEnterFrame=function(){ 
if(_root.einMC._alpha>0){ 
_root.einMC._alpha-=1; 
} 
}; 
//und jetzt erweitern:
 
deinMC.altEnterFrame[++_global.zaehler]=deinMC.onEnterFrame; 
deinMC.onEnterFrame=function(){ 
this.altEnterFrame[_global.zaehler](); 
if(_root.einAndererMc._rotation<30){ 
_root.einAndererMc._rotation+=1; 
}
} 

...wenn Du das oft nutzt, wird das natürlich kräftig auf die performance gehen.

für thebiz hier noch ein kleines Beispiel, was vielleicht erklärt, was flash bier will:

x=0;
y=0;
this.onEnterFrame=function(){
    trace("x="+this.x++);
}
this.onMouseDown=function(){
    if(!this.oldEnterFrame){
    this.oldEnterFrame=this.onEnterFrame;
    this.onEnterFrame=function(){
        this.oldEnterFrame();
        trace("......y="+this.y++);
    }
    }else{
        this.onEnterFrame=this.oldEnterFrame;
        delete this.oldEnterFrame;
    }
} 

Gruß

Alois

[kelor]

und wenn du´s ganz geil haben willst, dann arbeite mal mit 'apply'.

und dem ASBroadcaster


greetz

kelor

[thebiz]

@ kelor

Was ist denn das schon wieder
ASBroadcaster und apply.

@ alois

ja danke.

[flash bier]

hi kelor,

Mit ASBroadcaster hab ich noch nie gearbeitet!
Wat issen des, wenn dus in 2 Sätzen erklären könntest ?!

MfG flash bier

[Alois]

@kelor,
kannst Du auch ein Beispiel machen..., ich krieg das so nämlich nicht hin...

[atothek]

der ASBroadcaster ermöglicht es eigene events zu verwalten.

zB.

PHP-Code:

// erzeigen eine _globalen objects
_global.Broadcaster=new Object();
// wird mit dem methoden addListener, removeListener und broadcastMessage beerbt
ASBroadcaster.initialize(Broadcaster);

// einzelner listener
a=new Object();
a.onEvent=function(){
    trace("a: aufgerufen");
}
Broadcaster.addListener(a);

// einzelner listener
b=new Object();
b.onEvent=function(){
    trace("b: aufgerufen");
}
Broadcaster.addListener(b);
mc.onPress=function(){
// auslösen des broadcasters
Broadcaster.broadcastMessage("onEvent");
} 


bei jedem angemeldete listener wird das onEvent ausgelöst sobald ein knopf gedrückt wird.

[thebiz]

thx Mr.atothek

[Deluxe]

und so meinte es kelor?

broadcaster={}
ASBroadcaster.initialize(broadcaster); 
ef0=function(){
    trace("ef0")
}
//objekt welches die funktionen verwaltet
enterFrames={ef0:ef0}
broadcaster.addListener(enterFrames)
 
//
this.onEnterFrame=function(){
    //jeden möglichen aufruf durchlaufen
    for(var i in this.enterFrames){
        this.broadcaster.broadcastMessage(i)
    }
}
 
//nachträgliches hinzufügen
enterFrames.ef1=function(){
    trace("ef1")
} 

deluxe