[Flash MX] elastischer button

[capten]

hallo leute!

ich habe ein für euch sicherlich einfach zu lösendes problem!
dieses AS liegt direkt auf einem mc und funktioniert auch solange der mc in der root zeitleiste liegt.

onClipEvent (load) {
    defaultX = _x;
    defaultY = _y;
    newXpos = defaultX;
    newYpos = defaultY;
}
//
onClipEvent (enterFrame) {
    if (this.hitTest(_root._xmouse, _root._ymouse, true)) {
        xDifference = _root._xmouse-defaultX;
        yDifference = _root._ymouse-defaultY;
        newXpos = (_root._xmouse-xDifference/maxDistance);
        newYpos = (_root._ymouse-yDifference/maxDistance);
    } else {
        newXpos = defaultX;
        newYpos = defaultY;
    }
    newX = (newX*friction)+((newXpos-_x)*ratio);
    newY = (newY*friction)+((newYpos-_y)*ratio);
    _x += newX;
    _y += newY;
} 

sobald der mc in einem anderen mc liegt funktioniert das nicht mehr richtig. woran liegt das?
ich hab mal die .fla mit einem beispiel angehangen zur verdeutlichung.

ich hoffe es kann jemand helfen!
l.g.
capten

[Der Frager]

So sollte es klappen, denke ich mal:

PHP-Code:

onClipEvent (load) {
    defaultX = _x;
    defaultY = _y;
    newXpos = defaultX;
    newYpos = defaultY;
}
//
onClipEvent (enterFrame) {
    if (this.hitTest(_root._xmouse, _root._ymouse, true)) {
        xDifference = this._parent._xmouse-defaultX;
        yDifference = this._parent._ymouse-defaultY;
        newXpos = (this._parent._xmouse-xDifference/maxDistance);
        newYpos = (this._parent._ymouse-yDifference/maxDistance);
    } else {
        newXpos = defaultX;
        newYpos = defaultY;
    }
    newX = (newX*friction)+((newXpos-_x)*ratio);
    newY = (newY*friction)+((newYpos-_y)*ratio);
    _x += newX;
    _y += newY;
} 


[capten]

EDIT:

so hab es fasst! eine sache bleibt noch zu lösen.
wenn ich über einen mc rolle und danach direkt über einen anderen, wird der auch mit gezogen! (siehe anhang)
woran liegt das und wie bekommt man das weg?

var friction = 0.8;
var ratio = 0.2;
//
var maxDistance = 4;
//
function elast(welcher) {
    defaultX = welcher._x;
    defaultY = welcher._y;
    newXpos = defaultX;
    newYpos = defaultY;
    //
    welcher.onEnterFrame = function() {
        if (welcher.hitTest(_root._xmouse, _root._ymouse, true)) {
            xDifference = welcher._xmouse-defaultX;
            yDifference = welcher._ymouse-defaultY;
            newXpos = (welcher._xmouse-xDifference/maxDistance);
            newYpos = (welcher._ymouse-yDifference/maxDistance);
        } else {
            newXpos = defaultX;
            newYpos = defaultY;
        }
        //
        newX = (newX*friction)+((newXpos-welcher._x)*ratio);
        newY = (newY*friction)+((newYpos-welcher._y)*ratio);
        //
        welcher._x += newX;
        welcher._y += newY;
        //
        if (welcher._x == 0 && welcher._y == 0) {
            delete welcher.onEnterFrame;
        }
        //   
    };
} 

l.g.

[capten]

hat niemand einen kleinen tipp?

[Der Frager]

PHP-Code:

var friction = 0.8;
var ratio = 0.2;
//
var maxDistance = 4;
//
function elast(welcher) {
    var w = welcher;
    w.newX = 0;
    w.newY = 0;
    w.defaultX = w._x;
    w.defaultY = w._y;
    w.newXpos = w.defaultX;
    w.newYpos = w.defaultY;

    //
    w.onEnterFrame = function() {
        if (this.hitTest(_root._xmouse, _root._ymouse, true)) {
            this.xDifference = this._xmouse-this.defaultX;
            this.yDifference = this._ymouse-this.defaultY;
            this.newXpos = (this._xmouse-this.xDifference/maxDistance);
            this.newYpos = (this._ymouse-this.yDifference/maxDistance);
        } else {
            this.newXpos = this.defaultX;
            this.newYpos = this.defaultY;
        }
        //
        this.newX = (this.newX*friction)+((this.newXpos-this._x)*ratio);
        this.newY = (this.newY*friction)+((this.newYpos-this._y)*ratio);
        //
        this._x += this.newX;
        this._y += this.newY;
        //
        if (this._x == 0 && this._y == 0) {
            delete this.onEnterFrame;
        }
        //     
    };
} 


[capten]

danke für deine antwort! allerdings funktioniert das auch nicht richtig.

wenn man etwas wilder zwischen den mc's hin und her wechselt gehen die nicht zur ihrem ursprungsort zurück.
es kommt auch vor wenn man die maus öfter über einen mc drüber und wieder raus bewegt.

woran könnte das liegen?

[Der Frager]

Liegt am defaultX und Y. Kannste ja einfach auf 0 setzen:

PHP-Code:

w.defaultX = 0
w.defaultY = 0 


[capten]

danke! jetzt funktioniert es!

eine kurze frage noch:
ich hatte probiert anstatt dem _xmouse/_ymouse einen mc als cursor zu nehmen.
der hitTest funktioniert auch aber das ziehen des buttons nicht mehr.

if (this.hitTest(eigenercursor._x, eigenercursor._y, true)) {
            this.xDifference = this.eigenercursor._x-this.defaultX;
            this.yDifference = this.eigenercursor._y-this.defaultY;
            this.newXpos = (this.eigenercursor._x-this.xDifference/maxDistance);
            this.newYpos = (this.eigenercursor._y-this.yDifference/maxDistance); 

was hab ich da übersehen?

[Der Frager]

Kannst doch einen eigenen Cursor verwenden und trotzdem _x/_ymouse benutzen?

[capten]

ich würde trotzdem sehr gerne wissen wie man das NUR mit einem mc machen könnte.
muss man in jeden elastischen button dann einen eigenen mc als cursor packen damit es funktioniert?

[Der Frager]

Ich denke mal, da du dann die lokalen Koordinaten (innerhalb des MCs) brauchst, solltest du dir mal globalToLocal angucken.

[capten]

ich hab noch nie mit globalToLocal gearbeitet.
das ist mein zwischenstand der noch nicht funktioniert. geht das in die richtige richtung?
muss man bei "myPoint" noch ein _x oder _y mitgeben?

var friction = 0.8;
var ratio = 0.2;
//
var maxDistance = 4;
//
function elast(welcher) {
    var w = welcher;
    w.newX = 0;
    w.newY = 0;
    w.defaultX = w._x;
    w.defaultY = w._y;
    w.newXpos = w.defaultX;
    w.newYpos = w.defaultY;
//
    var myPoint:Object = {x:w._x, y:w._y};
    // Create your generic point object.
    meincursor.globalToLocal(myPoint);
    //
    w.onEnterFrame = function() {
        if (this.hitTest(meincursor._x, meincursor._y, true)) {
            this.xDifference = myPoint-this.defaultX;
            this.yDifference = myPoint-this.defaultY;
            this.newXpos = (myPoint-this.xDifference/maxDistance);
            this.newYpos = (myPoint-this.yDifference/maxDistance);
        } else {
            this.newXpos = this.defaultX;
            this.newYpos = this.defaultY;
        }
        //
        this.newX = (this.newX*friction)+((this.newXpos-this._x)*ratio);
        this.newY = (this.newY*friction)+((this.newYpos-this._y)*ratio);
        //
        this._x += this.newX;
        this._y += this.newY;
        //
        if (this._x == 0 && this._y == 0) {
            delete this.onEnterFrame;
        }
        //     
    };
} 

[Der Frager]

Hmmm...

PHP-Code:

var friction = 0.8;
var ratio = 0.2;
//
meincursor.startDrag(true);
//
var maxDistance = 4;
//
function elast(welcher) {
    var w = welcher;
    w.newX = 0;
    w.newY = 0;
    w.defaultX = w._x;
    w.defaultY = w._y;
    w.newXpos = w.defaultX;
    w.newYpos = w.defaultY;

    w.onEnterFrame = function() {
        //
        var myPoint = {x:_root.meincursor._x, y:_root.meincursor._y};
        this.globalToLocal(myPoint);
        //
        if (this.hitTest(meincursor._x, meincursor._y, true)) {
            this.xDifference = myPoint.x-this.defaultX;
            this.yDifference = myPoint.y-this.defaultY;
            this.newXpos = (myPoint.x-this.xDifference/maxDistance);
            this.newYpos = (myPoint.y-this.yDifference/maxDistance);
        } else {
            this.newXpos = this.defaultX;
            this.newYpos = this.defaultY;
        }
        //
        this.newX = (this.newX*friction)+((this.newXpos-this._x)*ratio);
        this.newY = (this.newY*friction)+((this.newYpos-this._y)*ratio);
        //
        this._x += this.newX;
        this._y += this.newY;
        //
        if (this._x == 0 && this._y == 0) {
            delete this.onEnterFrame;
        }
        //          
    };
} 


[capten]

tausend dank!
ganz schön verwirrend mit ".x" und "._x" aber wieder was gelernt.