Einfach für euch!!!

[finju]

Hallo brauche Hilfe von euch Actionscript-Checkern,

und zwar will ich einen externe swf in einen Drop laden, der Drop befindet sich schon sichtbar auf der Bühne. Die geladene swf übergibt nun die Neue Position des Drops
Code:
_level0._root.drop._x=200
_level0._root.drop._y=200

Jetzt springt der Drop auf die neue x und y Position.
Ich will aber das der Drop sich in einer flüssigen Bewegung dort hin bewegt,
quasi wie n Tween!!!
Kann man das so umsetzen, das die externen swfs jeweils den Code enthalten?
Wenn ja wie lautet dieser?

Recht herzlichen Dank
Jü

[atothek]

hier hab ich mal nen einfachen prototype basierend auf robert penners Math easy equations.

PHP-Code:

/*
* t==timeline/timebase/framenr
* b==begin/statvalue
* c==course/strecke/oiginal+c
* d==duration/dauer
*/

/*
* robert penner easy equations
*/
_global.easeIn=function(t, b, c, d) {
    return (t == 0) ? b : c*Math.pow(2, 10*(t/d-1))+b;
}
_global.easeOut=function(t, b, c, d) {
    return (t == d) ? b+c : c*(-Math.pow(2, -10*t/d)+1)+b;
}
_global.easeInOut=function(t, b, c, d) {
    if (t == 0) return b;
    if (t == d) return b+c;
    if ((t /= d/2)<1)return c/2*Math.pow(2, 10*(t-1))+b;
    return c/2*(-Math.pow(2, -10*--t)+2)+b;
}

/* neuer prototype zum sliden */
MovieClip.prototype.slideTo = function(pTargetX, pTargetY, pDuration, pMode){
    if(this.inMotion==undefined) this.inMotion=false;
    /* if in motion return because only one motion in time */
    if(this.inMotion) return;
    
    /* reset timebase */
    this.t = 0;
    this.d = pDuration;
    this.inMotion = true;
    
    /* calculate the offset/course */
    var xOffset=pTargetX-this._x;
    var yOffset=pTargetY-this._y;
    
    /* set start/begin position */
    var sX = this._x;
    var sY = this._y;
    
    this.onEnterFrame=function(){
        this._x = _global[pMode](this.t, sX, xOffset, this.d);
        this._y = _global[pMode](this.t, sY, yOffset, this.d);
        
        /* if timebased the same as duration mc its new positon */
        if(this.t==this.d){
            delete this.onEnterFrame;
            this.inMotion = false;
            trace("new xPos: "+this._x+"  // new yPos: "+this._y);
        }
        this.t++;
    }
} 


das ganze kannst du sehr einfach anwenden

PHP-Code:

/*
_level0._root.drop._x=200 == x = 200
_level0._root.drop._y=200  == y = 200
*/

var x = 200;
var y = 200;
var frames = 20; // wie lange dauert deine animation

this.meinMc.slideTo(x, y, frames, "easeOut"); 


[finju]

Hi danke für die schnelle Antwort, aber wie wende ich den Code an. Hab schon einiges ausprobiert will aber nicht klappen!
Danke für die Hilfe!!
MfG ju