ein Bild laden und verlinken (mit PDF Datei)

[rok°!]

Hallo!

Ich versuche schon den ganzen Tag ein simples Bild zu laden und dieses dann zu verlinken (mit einer PDF-Datei). Bis zum Bild laden bin ich gekommen, ich schaffe es aber nicht, dieses dann noch zu verlinken...

//Deutsche Umlaute
System.useCodepage = true;
 
m = new LoadVars();
m.cmd = "getDates";
m.sendAndLoad("termine.php", m, "POST");
m.onLoad = function(ok) 
{
    if (ok == true) 
    {
        Header=m.termin;
 
        createEmptyMovieClip("container_mc",1);
        container_mc._x=12;
        container_mc._y=30;
        container_mc.loadMovie(".."+m.img);
        container_mc.onRelease = function()
        {
            getURL(m.href,"_blank");
        };
    }
    else
    {
        Header = "Fehler beim Laden der Datei!!!";
    }
} 

das gibt termine.php aus:

PHP-Code:

&termin=Neue Termine 2007&href=/termin/Neue_Termine_2007.pdf&img=/termin/Neue_Termine_2007.jpg& 


Das ganze spielt sich in _root.fenster ab.

Das Bild wird wie oben schon erwähnt geladen und angezeigt, aber die Verlinkung geht nicht
Leider kann ich die FLA hier nicht anhängen (zu groß).

Was mache ich falsch?

[readme.txt]

wenn du in einem MC dynamische Inhalte lädst werden alle EventHandler des MCs gelöscht ... du musst erst mit einem Preloader testen ob der MC fertig geladen ist und dann kannst du einen onRelease definieren.

[rok°!]

Uhm, ich bin nich so der Crack. Kannst du dich evtl. etwas genauer ausdrücken?

[Der Frager]

Such mal nach "MovieClipLoader".

edit -> Ach, egal:

PHP-Code:

//////////////
var mcl = new MovieClipLoader();
var ml = {};
ml.onLoadInit = function(mc) {
    mc.onRelease = function() {
        getURL(m.href, "_blank");
    };
};
mcl.addListener(ml);
//////////////
m = new LoadVars();
m.cmd = "getDates";
m.onLoad = function(ok) {
    if (ok == true) {
        Header = m.termin;
        createEmptyMovieClip("container_mc", 1);
        container_mc._x = 12;
        container_mc._y = 30;
        mcl.loadClip(".."+m.img, container_mc);
    } else {
        Header = "Fehler beim Laden der Datei!!!";
    }
};
m.sendAndLoad("termine.php", m, "POST"); 


[rok°!]

Tausend Dank! Funktioniert super. Wäre ich nie von allein drauf gekommen...
Darf ich dazu noch eine Frage stellen?
Ich habe das Script noch nicht wirklich verstanden. Klar ist, dass erst was ausgeführt werden kann, wenn alles geladen ist. Dazu o.g. Funktion. Aber wie kann man der einen Wert übergeben (m.href), der erst weiter untenden definiert wird?

[readme.txt]

m ist ja in Fragers beispiel die Instanz der LoadVars-Klasse ... und die hat deine Variablen die du aus der Textdatei lädst so lange gespeichert bis du die Instanz wieder löscht.

Allerdings muss zuerst der onLoad-Handler von LoadVars angesprochen werden. .... vieleicht einfacher, die Reihenfolge:

1.) Du erstellst eine neue Instanz der LoadVars Klasse:

PHP-Code:

  m = new LoadVars() 


2.) Du sagst dieser Instanz sie soll eine Textdatei laden

PHP-Code:

  m.sendAndLoad("termine.php", m, "POST") 


3.) Wenn das Laden abgeschlossen ist und kein Fehler aufgetreten ist:

PHP-Code:

  m.onLoad = function(ok) 
    if (ok == true) { 


4.) Erstellst du einen leeren MC und lädst ein Bild:

PHP-Code:

  createEmptyMovieClip("container_mc", 1);  
  mcl.loadClip(".."+m.img, container_mc); 


5.) Ist das Bild fertig geladen:

PHP-Code:

  ml.onLoadInit = function(mc) { 


6.) Weisst du dem MC den onRelease zu:

PHP-Code:

  mc.onRelease = function() {
    getURL(m.href, "_blank");
  }; 


Das m.href ist an dieser Stelle definiert weil der Ladeaufruf der Bildes ja erst nach dem onLoad der loadVars-Klasse gestartet wurde.

Das ist ein bisschen die "Kunst" bei asynchronen Funktionen da die reihenfolge zu verstehen.

[rok°!]

Dankesehr! Hab's jetzt komplett kapiert! Bis zu 4) hatte ich es schon verstanden, weil das war auf meinem Mist gewachsen
Was mich wohl verwirrte war, dass die Überprüfung, ob das Bild fertig geladen wurde, am Anfang des Scriptes steht (logische Reihenfolge). Aber der Listener muss ja erst mal iniziiert werden!