eigenschaften (-animation) mit AS eingrenzen

[LarsSchuett]

hallo
Ich habe im Forum entdeckt wie ich Eigenschaften auch animierend verändern kann. Also statt nur

_width = 100; zu verwenden,
_width = _width +10

und das alles auf einem onClipEvent (enterframe).

Aaber: Das dingt hört ja dannleider nicht mehr auf zu wachsen.
Wie kann ich es erreichen, dass es nur bis zur gewünschten Breite anwächst?!

Dankeschön
Lars

[salazar]

kannst auch statt:

PHP-Code:

_width = _width +10 


folgendes schreiben

PHP-Code:

_width += 10 


und abfangen kannste das z.B. mit ner if bedingung...
if(_width > 100)

cya, sal

[salazar]

kleine bsp function:

PHP-Code:

//function ins erste frame
function mcwidth(mc, width){
    mc.onEnterFrame = function(){
        this._width += 10;
        if(this._width >= width){
            delete this.onEnterFrame;
            this._width = width;
        }
    }
}

//function wird aufgerufen. aufruf natürlich auch im ersten frame
mcwidth(_root.deinmc, 200);//deinmc der instanzname des movieclips, bis 200 soll er breit werden 


cya, sal

[LarsSchuett]

Perfekt und Dankeschön..
Hab es sogar alleine hinbekommen, das ganze für das Kleinerwerden des Objektes zu ergänzen. Ist das so ok oder geht das noch eleganter?


function mcwidth(mc, width){
mc.onEnterFrame = function(){

if (this._width < width) {

this._width += 3;
if(this._width >= width){
delete this.onEnterFrame;
this._width = width;
}}
if (this._width > width) {

this._width -= 3;
if(this._width <= width ) {
delete this.onEnterFrame;
this._width = width;
}
}
}
}


Fertig sieht das übrigens so aus (im Menüpunkt "artists" die Menüleiste mitte-unten)

www.camonmdedia.de/energy

[salazar]

eleganter gehts immer
hier mal ein schöner prototype...

PHP-Code:

MovieClip.prototype.setsize = function(xs, ys, br) {
    var mc = this;
    var mz = mc.createEmptyMovieClip("setsize"+mc._name, 999);
    mc.dx = 0;
    mc.dy = 0;
    mz.onEnterFrame = function() {
        mc.dx = -mc._width + xs;
        mc.dy = -mc._height + ys;
        if (int(Math.abs(mc.dx)) > 0 || int(Math.abs(mc.dy)) > 0) {
            mc._width += mc.dx / br;
            mc._height += mc.dy / br;
        } else {
            mz.removeMovieClip();
            mc._width = xs;
            mc._height = ys;
            delete mc.dx;
            delete mc.dy;
            delete mz;
        }
    };
}

deinmc.setsize(200, 200, 8);//breite, höhe, bremsspeed 


cya, sal

[LarsSchuett]

ui. Da steig ich auf die Schnelle nicht durch. Aber das werde ich mir mal in Ruhe anschauen...
Jetzt bin ich erstmal froh, dass es überhaupt geht.

Also besten Dank nochmal!

[salazar]

oder hier... ohne onEnterFrame aber stattdessen mit einem interval:

PHP-Code:

MovieClip.prototype.setsize = function(xs, ys, br, sp) {
    var mc = this;
    clearInterval(mc["setsize" + mc._name]);
    mc.dx = 0;
    mc.dy = 0;
    mc["setsize" + mc._name] = setInterval(function () { 
        mc.dx = -mc._width + xs;
        mc.dy = -mc._height + ys;
        if (int(Math.abs(mc.dx)) > 0 || int(Math.abs(mc.dy)) > 0) {
            mc._width += mc.dx / br;
            mc._height += mc.dy / br;
        } else {
            clearInterval(mc["setsize" + mc._name]);
            mc._width = xs;
            mc._height = ys;
            delete mc.dx;
            delete mc.dy;
        }
    }, sp); 
}

deinmc.setsize(500, 390, 8, 40);//breite, höhe, bremsspeed, interval speed 


cya, sal

[salazar]

Zitat von LarsSchuett

ui. Da steig ich auf die Schnelle nicht durch. Aber das werde ich mir mal in Ruhe anschauen...
Jetzt bin ich erstmal froh, dass es überhaupt geht.

Also besten Dank nochmal!

ja büddeschön
cya, sal