Dynamische Variablen in Flash

[Marc Weller]

Guten Morgen,

suche seit gestern im Internet wie man in Flash Dynamische Variablen schreibt.

Sprich mein Variablen Name ist halt immer anders...

z.B.

var test1 = hallo;
 
for (var i = 1; i <= 2; i++) 
{
_root.gotoAndStop (test+i);
} 

Danke ....

Mfg
Marc

[Alois]

var test1 = "hallo";
 
for (var i = 1; i <= 2; i++)
{
        _root.gotoAndStop (this["test"+i]);//es geht auch: _root.gotoAndStop (_root["test"+i]);
} 

...und 'nein, es fehlt kein Punkt..'

Gruß

Alois

Edit: ...wobei der Code wenig Sinn macht...

[Marc Weller]

Hi,

dass hatte ich auch shcon ausprobiert geht aber bei mir nicht ..?? warum?

hier das script

//frame 1 auf _root
var activ = this;
var clicked;
var gehe1 = "20";
var gehe2 = "40";
//
for (var i = 1; i <= 2; i++) 
{
    this["btn" + i].onRollOver = function () 
    {
        if (this != activ.clicked) 
        {
            this.gotoAndStop (2);
        }
    };
    this["btn" + i].onRollOut = this["btn" + i].onReleaseOutside = function () {
        if (this != activ.clicked) {
            this.gotoAndStop (1);
        }
    };
    this["btn" + i].onRelease = function () {
        if (this != activ.clicked) {
            //hier die Navigations-Aktion...
            _root.gotoAndStop (this["gehe"+i]);
            activ.clicked.gotoAndStop (1);
            activ.clicked.useHandCursor = true;
            activ.clicked = this;
            this.useHandCursor = false;
        }
    };
} 

[Alois]

Zwei Gründe:
- in diesem Fall geht 'this["gehe"...' nicht weil Du das ja im this["btn" + i].onRelease-Handler schreibst und this dan entsprechend this.btn1 oder this.btn2 ist
-ausserdem steht im this.btnX.onRelease-Handler theoretisch folgender Code:

if (this != activ.clicked) {
    //hier die Navigations-Aktion...
    _root.gotoAndStop(this["gehe"+_root.i]);//weil der Code von _root kommt
    activ.clicked.gotoAndStop(1);
    activ.clicked.useHandCursor = true;
    activ.clicked = this;
    this.useHandCursor = false;
} 

und nach Vollendung der Schleife wird die _root.i als lokale Variable nicht mehr existieren oder (wenn du auf das var verzichtest) für alle buttons auf 3 stehen...
Hier mal 'korrigiert':

//frame 1 auf _root
var activ = this;
var clicked;
var gehe1 = "20";
var gehe2 = "40";
//
for (var i = 1; i <= 2; i++)
{
this["btn" + i].i=i;//jeder Button bekommt ein eigenes i...
        this["btn" + i].onRollOver = function ()
        {
                if (this != activ.clicked)
                {
                        this.gotoAndStop (2);
                }
        };
        this["btn" + i].onRollOut = this["btn" + i].onReleaseOutside = function () {
                if (this != activ.clicked) {
                        this.gotoAndStop (1);
                }
        };
        this["btn" + i].onRelease = function () {
                if (this != activ.clicked) {
                        //hier die Navigations-Aktion...
                        _root.gotoAndStop (_root["gehe"+this.i]);
                        activ.clicked.gotoAndStop (1);
                        activ.clicked.useHandCursor = true;
                        activ.clicked = this;
                        this.useHandCursor = false;
                }
        };
} 

....wobei dann die Frage bleibt, warum nicht direkt die Werte aus den variablen....

//frame 1 auf _root
var activ = this;
var clicked;
var gehe = [20,40];
 
//
for (var i = 1; i <= 2; i++)
{
this["btn" + i].i=gehe[i-1];//jeder Button bekommt ein eigenes i...
        this["btn" + i].onRollOver = function ()
        {
                if (this != activ.clicked)
                {
                        this.gotoAndStop (2);
                }
        };
        this["btn" + i].onRollOut = this["btn" + i].onReleaseOutside = function () {
                if (this != activ.clicked) {
                        this.gotoAndStop (1);
                }
        };
        this["btn" + i].onRelease = function () {
                if (this != activ.clicked) {
                        //hier die Navigations-Aktion...
                        _root.gotoAndStop (this.i);
                        activ.clicked.gotoAndStop (1);
                        activ.clicked.useHandCursor = true;
                        activ.clicked = this;
                        this.useHandCursor = false;
                }
        };
} 

[Marc Weller]

Hey, danke..

also Version 1 Geht leider nciht, aber die Version 2 geht supi!!

Danke .. werde jetzt mal versuchen zu verstehen was du da gemacht hast :-)

Mfg
Marc