dynamische buttons aus einer textdatei

[lx_1]

schönen tag!

bastle schon seit einiger zeit an einem problem herum... vielleicht habt's ihr ja eine idee:

ich will dynamische buttons in AS aus einer textdatei "test.txt" erzeugen. in der textdatei stehen die bezeichnungen für die buttons. zB:

[textfile]
&button1=home
&button2=news
...
[/textfile]

wenn das swf geöffnet wird, soll sich dyn. die richtige anzahl von textfeldern mit der richtigen bezeichnung(s.o.) auf der bühne befinden und natürlich als button fungieren.

das ziel ist vor augen, aber funzn tut's nicht:

ich lass mittels einer schleife die textfelder mit namen "textfeld1_txt", "textfeld2_txt" etc. erzeugen.

dann werden sie positioniert.

aus der textdatei werden die bezeichnungen eingelesen werden. und das ist meine frage: wie mach ich das dynamisch? er gibt mir immer nur eine bezeichnung aus. die anderen textfelder sind zwar da, aber ohne bez., weil i immer auf 3 stehen bleibt.

for (i=1; i<=3; i++) {
    
    var name_str = "textfeld"+i;
    
    this.createTextField(name_str+"_txt", i+100, 300, 300+i*30, 150, 50);
    var textfeld_str = name_str+"_txt";
    
    var txt = new LoadVars();
    txt.load("test.txt");
    txt.onLoad = function() {
    var temp="button"+i; //i bleibt immer auf 3
    _root[textfeld_str].text = txt[temp];
 
};
} 

das die dinger dann als buttons funken is eh eine andere sache

danke für eure hilfe!!

lg
alex

[sonar]

Schau dir mal deinen Code an:
Du erzeugst 3mal die selbe LoadVars-Instanz (bzw. überschreibst sie), gibst 3mal die Ladeanweisung und definierst 3mal den onLoad-Handler... Das kann ja so irgendwie nicht ganz gehen, oder...

[sonar]

Hab mal bissl gebastelt... (ich hoffe ich verderbe dir jetzt nicht die Freude )
txt sieht so aus, wie von dir genannt:

&button1=home
&button2=news
&button3=profile
&

Dann in Flash:

var tl:MovieClip = this;
var labelsArr:Array = new Array();
var txtLoader:LoadVars = new LoadVars();
txtLoader.onLoad = function(OK:Boolean) {
    if (OK) {
        for (var i in this) {
            if (typeof this[i] == "string") {
                labelsArr.unshift(this[i].split("\n").join(""));
            }
            makeButtons(labelsArr.length);
        }
    } else {
        trace("Fehler beim Laden...");
    }
};
txtLoader.load("test.txt");
function makeButtons(pNum:Number) {
    while (pNum > 0) {
        // MCs und Textfelder erstellen:
        tl.createEmptyMovieClip("btn_" + pNum, pNum);
        tl["btn_" + pNum]._x = 50;
        tl["btn_" + pNum]._y = 20 * pNum;
        tl["btn_" + pNum].createTextField("txt", pNum, 0, 0, 120, 20);
        tl["btn_" + pNum].txt.border = true;
        tl["btn_" + pNum].txt.background = true;
        tl["btn_" + pNum].txt.backgroundColor = 0xEEEEEE;
        tl["btn_" + pNum].txt.text = labelsArr[pNum - 1];
        //btn-Aktionen zuweisen:
        tl["btn_" + pNum].onRollOver = function() {
            this.txt.backgroundColor = 0x996666;
            this.txt.textColor = 0xFFFFFF;
        };
        tl["btn_" + pNum].onRollOut = function() {
            this.txt.backgroundColor = 0xEEEEEE;
            this.txt.textColor = 0x000000;
        }
        tl["btn_" + pNum].onDragOut = tl["btn_" + pNum].onRollOut;
        tl["btn_" + pNum].onRelease = function() {
            trace(this._name + ": " + this.txt.text);
        }
        pNum--;
    }
} 

Kannst beliebig viele Vars in der txt haben...
Viel Spaß!

[lx_1]

oh man...

da gehen mir ja die augen über!
jetzt geh ich mal auf nen kaffee und dann schau ich da mal genau drüber! brauch nen freien kopf!

lg

alex(jaja, der schon wieder

[lx_1]

hallo sonar! danke nochmal für deinen code! hab den mal durchgeackert... funkt prima und spass haben tu ich mehr als davor!

[sonar]

Na dann is ja gut

[jotti]

[Stuff] Release-Status für Buttons


Button(Aktiv)