dynamische Bildergalerie

[Blade[A.D.]]

Ich hoffe Ihr könnt mir helfen, da ich in AS nicht so bewandert bin.
Ich sitze nun schon seit 2 Tagen an folgendem script(von flahstar gezogen), was auch funtzt. Lade ich die swf als Untermovie in einen anderen Film, geht nix mehr. Ich weiß nicht woran das liegen könnte.

PHP-Code:

meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load("bilderx.xml");
loadstatus.text = "LOADING...";
meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        anzahl = tempxml.length;
        _root.slideBand("container", "bild", 10, 0, 10.0, anzahl, 200, 1, 1.01, 120);
        loadstatus.text = "";
        delete meinXML;
    }
};

function slideBand(obj, clip, tiefe, ziel, speed, bildanzahl, bildbreite, bildnummer, abstand, posY) {
    createEmptyMovieClip(obj, tiefe);
    for (var i = 1; i <= bildanzahl; i++) {
        this[obj].attachMovie(clip, clip + i, i);
        this[obj][clip + i]._x = bildbreite * -i * abstand;
        this[obj][clip + i]._y = posY;
        this[obj][clip + i].bild = i;
        this[obj][clip + i].titel.text = tempxml[i-1].attributes.titel;
        this[obj][clip + i].link = tempxml[i-1].attributes.url;
        this[obj][clip + i].onRelease = function() {
            //bildnummer = this.bild;
            getURL(this.link,"_blank");
        };
        this[obj][clip + i].onRollOver = function() {
            bildnummer = this.bild;
            //getURL(this.link,"_blank");
        };
        
        
        
        
        this[obj][clip + i].mc.loadMovie("BilderKunden/" + tempxml[i-1].firstChild);
        this[obj][clip + i].balken_mc._xscale = 0
        this[obj][clip + i].onEnterFrame = function() {
            if (this.mc.getBytesLoaded() > 10) {
            this.gesamt = this.mc.getBytesTotal();            
            this.bereits = this.mc.getBytesLoaded();        
            this.prozent = this.bereits*100/this.gesamt;
            this.balken_mc._xscale = this.prozent;
            if (this.prozent == 100) { 
                this.balken_mc._visible = 0;
                delete this.onEnterFrame;
            }
            }
        };
    }
    this[obj].onEnterFrame = function() {        
        this.xdiff = this[clip + bildnummer]._x - ziel;        
        if (this.xdiff != 0) {            
            this.xdiff = Math.round(this.xdiff) / Math.round(speed);            
            for (var i = 1; i <= bildanzahl; i++) {
                this[clip + i]._x -= this.xdiff;
                if (this[clip + i]._x <= (ziel - bildbreite)) {
                    this[clip + i]._x += bildanzahl * bildbreite * abstand;
                }
                
            }
        }
    };
} 


[atothek]

wahrscheinlich liegt es an dieser kleinen zeile

PHP-Code:

 _root.slideBand("container", "bild", 10, 0, 10.0, anzahl, 200, 1, 1.01, 120); 


dies bezieht sich auf root aber die function slideBand liegt nicht in root hier mal ein kleiner trick um das prob zu lösen

PHP-Code:

 meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load("bilderx.xml");
loadstatus.text = "LOADING...";
// nen scope setzen
var _s=this;

meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        anzahl = tempxml.length;
        _s.slideBand("container", "bild", 10, 0, 10.0, anzahl, 200, 1, 1.01, 120);
        _s.loadstatus.text = "";
        delete meinXML;
    }
}; 


wenn du glück hast wars das schon

[Blade[A.D.]]

Yupp, daran lag es, danke vielmals.
Manchmal ist man halt blind.