dynamische bilderblende funzt nur beim ersten mal

[K-Grabowski]

also habe eine Überblende für reingeladene Bilder geschrieben, aber komischerweise funktioniert das ganze nur beim ersten reingeladenen Bild:

script hier:

// der Prototyp ist für die einzelnen Maskenteile.
MovieClip.prototype.scaleXY = function(tarXscale,tarYscale, speed) {
    var curXscale = this._xscale;
    var XDiff = tarXscale-curXscale;
    this._xscale = tarXscale-XDiff/speed;
    
    var curYscale = this._yscale;
    var YDiff = tarYscale-curYscale;
    this._yscale = tarYscale-YDiff/speed;
    
    if (Math.floor(Math.abs(XDiff))<=1 && Math.floor(Math.abs(YDiff))<=1) {
        this._xscale = tarXscale;
        this._yscale = tarYscale;
        delete this.onEnterFrame;
    }
};
 
 
bg_image.startebene = 0;
function loadBackground (pic) {
    bg_image.startebene++;
    var v = bg_image.createEmptyMovieClip("holder" +  bg_image.startebene,bg_image.startebene);
    v.createEmptyMovieClip("checker",133);
    v.createEmptyMovieClip("picture",1);
    v.picture.loadMovie("wallpaper/"+pic);
    
    v.checker.onEnterFrame = function () {
        if (this._parent.picture._height !=0) {
 
// sobald das bild hier geladen wurde soll zur bildaufbau funktion gesprungen werden.
            bildaufbau(this._parent);
            this.removeMovieClip();
                
            
            
            
        }
    }
    
}
 
function bildaufbau (v) {
                // v ist der übergebene MovieClip
     var spalten = 6;
     var zeilen = 5;
     var breite = 700/(spalten+1);
     var hoehe = 440/(zeilen+1);
     var spalte = 0;
                 // m ist der maskenmc
     var m = v.createEmptyMovieClip("maskmc",1000);
     v.picture.setMask(m);
     for (var i = 0; i<((spalten+1)*(zeilen+1));i++) {
// mc ist jedes Viereck des Maskenmcs.     
var mc = m.createEmptyMovieClip("m"+i,i);
         mc._x = spalte * breite;
         mc._y = zeile * hoehe;
         mc._xscale = 0;
         mc._yscale = 0;
         with (mc) {
             moveTo(0,0);
             beginFill("0x000000",100);
             lineTo(breite,0);
             lineTo(breite,hoehe);
             lineTo(0,hoehe);
             lineTo(0,0);
             endFill();
         }
         mc.onEnterFrame = function () {
             this.scaleXY(100,100,1.1);
         }
         spalte == spalten ? (spalte=0,zeile++) : spalte++;
     }
     var u = v.createEmptyMovieClip("aufbaucheck",1555);
     u.anzahl = (spalten+1)*(zeilen+1);
     u.myv = v;
     u.onEnterFrame = function () {
         this.zahl =0;
// in der For-Schleife wird abgefragt ob bei allen Viereck-Mcs die onEnterFrame Funktion gelöscht wurde(was passiert wenn
//die Scalierung bei 100 angelangt ist.   
for (var i=0;i<this.anzahl;i++) {
             if (this.myv.maskmc["m"+i].onEnterFrame == undefined) {
                 
                 this.zahl++;
             }
         }
         if (this.zahl == this.anzahl) {
             this.myv.maskmc.removeMovieClip();
             trace("feddich");
             this.removeMovieClip();
              
     
         }
     }
}
 
 
m = 1;
 
loadBackground(m + ".jpg");
 
mybutton.onRelease = function () {
    m == 4 ? m = 1 : m++;
    loadBackground(m + ".jpg");
} 

Datei ist hier www.webgroove.de/test/finalswf.zip

[tolleiv]

kommentier mal das setMask aus so das du die skalierung der Objekte siehts dann weißte was falsch is

Edit:
eine in die function bildaufbau noch

var zeile = 0;

mit deklarieren dann sollte es laufen

aber is ein netter effekt - damit läßt sich bestimmt ne ganze menge machen



mfg

[K-Grabowski]

@tolleiv

danke danke danke

ja ja die zeile, wenn man den Wald vor lauter Bäumen nicht mehr sieht......ich saß da bestimmt 3 Stunden vor hab das geändert, das komplette ding nachgebaut...und diese verdammte kleinigkeit nicht gesehen.....

[tolleiv]

das kommt mir bekannt vor - den wald vor lauter bäumen nicht zu sehen

wenn davon mal mehrere effekte gibt sag mal bescheid wo man die finden kann

mfg