Dynamisch erzeugten MC einzeln anclicken - warum geht dat nicht??????

[tomtom69]

Moin,

es sollen MC's dynamisch erstellt werden. Und zwar so viele, wie Einträge in einer Datenbank. Diese werden über die Bühne verteilt und mit einem Zufallswert skaliert. Diese MC's sollen klickbar sein. Bei klick, wird der betreffende MC auf 100% skaliert. Alles funzt, nur das ALLE MC's skaliert werden.

Kann mir jemand bei der Fehlersuche helfen??? Biiiittööööööö
Der Fehler muss in Nähe der onMouseDown Anweisung liegen (denke ich). Es werden alle Instanzen auf einmal angesprochen, nicht jede für sich :?

Hier ist das AS:

//textfeld zur Ausgabe der "Datensätze"
this.createTextField("params_txt", 99, 10, 10, 100, 21);
params_txt.autoSize = "left";
//diverse Variablen deklarieren und initialisieren
//Zum speichern der Bühenbreite
var buehnenbreite:Number = Stage.width;
trace(buehnenbreite);
//hilfsvariable
var i:Number = 1;
//datensatzzeiger aus der PHP Datei
var variable:String = "vorname" + i;
 
//neues LoadVars(my_lv) Object deklarieren
var my_lv:LoadVars = new LoadVars();
//HTTP Status abfragen
my_lv.onHTTPStatus = function(httpStatus:Number) {
    trace("HTTP status is: " + httpStatus);
};
//Daten aus Datei in LV Object laden
my_lv.load("http://localhost:8888/www.leclaire.de/index.php");
//überprüfen, ob erfolgreich geladen ...
my_lv.onLoad = function(success:Boolean) {
    //wenn ok, ...
    if (success) {
        trace("text file successfully loaded");
        // während i kleiner/gleich der Anzahl der Datensätze
        while(i <= my_lv.anzahl) {
            trace(my_lv.anzahl + i);
            //my_lv ist ein Array->[variable] ? my_lv.variable <- funzt nicht! EDIT: wieso funzt es bei my_lv.anzahl???
            //Zuweisung Datensatz an Textfeld + Umbruch
            params_txt.text += my_lv[variable];
            params_txt.text += "\n";
            //Function gruppe mit jedem Durchgang aufrufen
            gruppe();
            trace("name: " + _root["symbol"+i]._name);
            //hilfsvariable um eins in jedem Durchgang erhöhen
            ++i;
        }
    //wenn nicht ok, Fehlermeldung
    } else {
        params_txt.text = "unable to load text file";
    }
};
 
 
 
function gruppe() {
    //Zufallszahl erzeugen, die zwischen 1 und 100 liegt
    var skalierung:Number = Math.floor(Math.random() * 100);
    //MC aus Library hinzufügen - da Function in Schleife aufgerufen wird, werden my_lv.anzahl MC's erstellt mit Intanznamen "symbol"+i
    _root.attachMovie("kreis_mc","symbol"+i,i);
    //x/y Koordinaten festlegen und hochzählen (MC's nebeneinander positionieren)
    _root["symbol"+i]._x = 10 + (i*80);
    _root["symbol"+i]._y = 10;
    //MC's Skalierung mit der Zufallszahl festlegen
    _root["symbol"+i]._xscale = skalierung;
    _root["symbol"+i]._yscale = skalierung;
    //JEDEM MC's einen Listener zuweisen (für spätere Mouseaktionen)
    Mouse.addListener(_root["symbol"+i]);
    //die x-Koordinate in einer Var speichern
    var xkoord:Number = _root["symbol"+i]._x;
    trace(xkoord);
    //Wenn die x-Koordinate größer als die Bühnenbreite mal q ist (wenn MC's außerhalb Bühne) ...
    for (q = 1; xkoord > buehnenbreite*q; q++) {
        //positioniere die MC's, die außerhalb der Bühne liegen, mit einer x-Koordinate, von der die Bühnenbreite mal q abgezogen wurde ...
        //... q wird bei jedem Durchgang um eins erhöht
        //... danach wird xkoord zurückgesetzt (xkoord - buehnenbreite*q) (1. Durchgang(wo die x-koordinate größer als die Bühnenbreite ist)-
        //-Bühnenbreite mal 1; 2. Durchgang Bühnenbreite mal 2 etc.)
        _root["symbol"+i]._y += 40;
        _root["symbol"+i]._x = xkoord - buehnenbreite*q;
    }
    //überprüfen der symbolnamen
    trace("Akt. Symbol=" + _root["symbol"+i]._name);
    //Wenn ein MC's geklickt wird, skaliere diesen auf 100%
    _root["symbol"+i].onMouseDown = function() {
        trace("klick vom " + this._name);
        this._xscale = 100;
        this._yscale = 100;
    }
    trace("Skalierung=" + skalierung);
}; 

Wer sich nach dem Sinn fragt: es soll evtl. mal eine Site für einen Fotografen werden - in die MC's werden dann Bilder geladen, die in einer DB hinterlegt sind - sofern es denn mal so funzt, wie ich's mir vorstell

Sonnige Grüße,

das Tom

[ricardo]

hi,
setz das ganze in eine Schleife:

PHP-Code:


function gruppe() {
    for (var i = 0; i < my_lv.anzahl; i++) {
        //MC aus Library hinzufügen - da Function in Schleife aufgerufen wird, werden my_lv.anzahl MC's erstellt mit Intanznamen "symbol"+i
// habe die attachten mc's in ne variable zum besseren handling gepackt...
        var myMcs:MovieClip = _root.attachMovie("kreis_mc", "symbol" + i, i);
        //Zufallszahl erzeugen, die zwischen 1 und 100 liegt
        var skalierung:Number = Math.floor(Math.random() * 100);
        myMcs._x = 10 + (i * 80);
        myMcs._y = 10;
        //MC's Skalierung mit der Zufallszahl festlegen
        myMcs._xscale = skalierung;
        myMcs._yscale = skalierung;
        //Wenn ein MC's geklickt wird, skaliere diesen auf 100%

//.. dein MouseDown in OnPress geändert...
        myMcs.onPress = function() {
            trace("klick vom " + this._name);
            this._xscale = 100;
            this._yscale = 100;
        };
        //x/y Koordinaten festlegen und hochzählen (MC's nebeneinander positionieren)
        //JEDEM MC's einen Listener zuweisen (für spätere Mouseaktionen)
        Mouse.addListener(myMcs);
        //die x-Koordinate in einer Var speichern
        var xkoord:Number = myMcs._x;
        trace(xkoord);
        //Wenn die x-Koordinate größer als die Bühnenbreite mal q ist (wenn MC's außerhalb Bühne) ...
        for (q = 1; xkoord > buehnenbreite * q; q++) {
            //positioniere die MC's, die außerhalb der Bühne liegen, mit einer x-Koordinate, von der die Bühnenbreite mal q abgezogen wurde ...
            //... q wird bei jedem Durchgang um eins erhöht
            //... danach wird xkoord zurückgesetzt (xkoord - buehnenbreite*q) (1. Durchgang(wo die x-koordinate größer als die Bühnenbreite ist)-
            //-Bühnenbreite mal 1; 2. Durchgang Bühnenbreite mal 2 etc.)
            myMcs._y += 40;
            myMcs._x = xkoord - buehnenbreite * q;
        }
        //überprüfen der symbolnamen
        trace("Akt. Symbol=" + myMcs._name);
        trace("Skalierung=" + skalierung);
    }
} 


hope it helps

ricardo