Dynamisch erzeugte MCs mit Klick versehen?

[Tom(2)]

Hi,

irgendwie stehe ich schonwieder auf dem Schlauch...

for(var a=0;a<clips.length;a++){
    var myThumb = "thumb_mc_"+a;    
    _root.createEmptyMovieClip(myThumb, _root.getNextHighestDepth());
    var myListener:Object = new Object();
    myListener.onLoadInit = function(targetMC:MovieClip) {
        targetMC._width = thumbWidth;
        targetMC._height = thumbHeight;
    }
    var imageLoader:MovieClipLoader = new MovieClipLoader();
    imageLoader.addListener(myListener);
    imageLoader.loadClip(thumbPath+clips[a][2], myThumb);   
    
    _root[myThumb]._x=a*thumbWidth+vidDisplayWidth+10;
    _root[myThumb]._y=10;
    
    _root[myThumb].onRelease = function(){
        trace("CLICKED: "+ myThumb);
    };
    
} 

Ich erzeuge damit Thumbnails, funktioniert auch soweit... aber wie bekomme ich diese jetzt dazu, auf den MouseClick zu reagieren?
Das

_root[myThumb].onRelease = function(){
        trace("CLICKED: "+ myThumb);
    }; 

macht leider nichts....?

gruss
Tom

[Deluxe]

nach der zuweisung mal ein
trace(_root[myThumb]) ergibt das ne funktion?
bezweifle ich mal nicht.
Hast du dem root einen mousevent gegeben? der würde als unterhalb in der hierarchie überdecken(beim root jeden )
testweise mal nen neuen film anlegen und dort die funktion testen..

im übrigen solltest du per
_root[myThumb].id=myThumb den namen explizit im button hinterlegen.
so wie es jetzt ist würdest du den letzten erstellten namen ausgeben

ich bin zwar noch nen MX2004loser aber lädst du in den leeren film etwas rein?
damit wird der onRelease (zumidnest in MX) gelöscht.
umgehe das über de doppelte hierarchie.
estelle movieclip
und erstelle in diesem movieclip noch einen clip in den du den content lädst
auf den zuerst erstellten legste deine variablen und mouseEvents.
dann wird da nichts gelsöcht

deluxe

[rendner[i]]

Warum muss das Object myListener in der for-Schleife immer wieder generiert werden?
Kannste das nicht ausserhalb der for-Schleife anlegen?

Wenn Du einen mc in einen anderen reinlädtst überschreibst Du dessen eigenschaften ( Funktionen, Variablen ) darum funktioniert das nicht.

[Tom(2)]

Zitat von Redner[i]

Warum muss das Object myListener in der for-Schleife immer wieder generiert werden?

Hm, stimmt, das Objekt ansich muss ja nur einmal da sein, lediglich das initLoad will ich für jeden in der Schleife erzeugten MC haben.

Zitat von Redner[i]

Wenn Du einen mc in einen anderen reinlädtst überschreibst Du dessen eigenschaften ( Funktionen, Variablen ) darum funktioniert das nicht.

ok, in meinem Fall lade ich nach dem Erstellen des leeren MCs jpg Bilder in diesen, deshalb klappt das nicht?

Zitat von Deluxe

damit wird der onRelease (zumidnest in MX) gelöscht. umgehe das über de doppelte hierarchie. estelle movieclip und erstelle in diesem movieclip noch einen clip in den du den content lädst auf den zuerst erstellten legste deine variablen und mouseEvents.
dann wird da nichts gelsöcht

Wie müsste ich denn den Aufruf gestalten, dass ich für jeden MCs einen weiteren darin bekomme?

(...)
_root.createEmptyMovieClip(myThumb, _root.getNextHighestDepth());
_root[myThumb].createEmptyMovieClip(myThumbImgHolder, _root[myThumb].getNextHighestDepth());
(...) 

und den jpg krempel lade ich dann in den myThumbImgHolder MC?

Zitat von Deluxe

im übrigen solltest du per
_root[myThumb].id=myThumb den namen explizit im button hinterlegen.
so wie es jetzt ist würdest du den letzten erstellten namen ausgeben

ok...
in meinem Fall wäre das dann für den 2. MC "aufgelöst":
_root.thumb_mc_1.id = thumb_mc_1 ?
Wofür wird das gebraucht? In meinem weiteren Script komme ich an alle Instanzen (thumb_mc_0, thumb_mc_1, usw) und Eigenschaften wie zb thumb_mc_2._alpha ran...

gruss + danke
Tom

[norbman]

wenn ich das richtig verstanden habe, dann kann ich einen per as erzeugten movieclip in dem ich ein externes bild lade nur dann als schaltfläche nutzen, wenn ich ihn in einen container-movieclip packe und auf diesen mit keypress zugreife ?

[Xeef]

nein

das problem ist das wen du ein clip in ein holder rein ladest wird der holder zum geladenen clip (wen es geladen ist)
und da der geladene clip kein onWASauchimmer hat gehts nicht

//loads are asynchronous so this will NOT work
_root.createEmptyMovieClip("test", 9);
test.loadMovie("a.swf");
test.onPress = function() {
 trace("Hallo By Holder-Holder");
};
//
//BUT this
//
_root.createEmptyMovieClip("Clip1", 1);
_root.createEmptyMovieClip("Clip2", 2);
_root.createEmptyMovieClip("Clip3", 3);
_root.createEmptyMovieClip("Clip4", 4);
Clip1._x = 100;
Clip2._x = 200;
Clip3._x = 300;
Clip4._x = 400;
//
// Holder - Holder
//
Clip1.createEmptyMovieClip("H", 1);
Clip1.onPress = function() {
 trace("Hallo By Holder-Holder");
};
Clip1.H.loadMovie("a.swf");
//
//MovieClipLoader
//
Q = new MovieClipLoader();
L = {};
L.onLoadInit = function(_mc) {
 _mc.onPress = function() {
  trace("Hallo By MovieClipLoader");
 };
};
Q.addListener(L);
Q.loadClip("a.swf", Clip2);
//
//loadMovie /onEnterFrame
//
Clip3.loadMovie("a.swf");
onEnterFrame = function () {
 if (Clip3.getBytesLoaded() == Clip3.getBytesTotal() && Clip3.getBytesLoaded()<>0) {
  delete onEnterFrame;
  Clip3.onPress = function() {
   trace("Hallo By loadMovie /onEnterFrame");
  };
 }
};
//
//loadMovie / setInterval
//
Clip4.loadMovie("a.swf");
function Check() {
 if (Clip4.getBytesLoaded() == Clip4.getBytesTotal() && Clip4.getBytesLoaded()<>0) {
  clearInterval(IntVal);
  Clip4.onPress = function() {
   trace("Hallo By loadMovie / setInterval");
  };
 }
}
IntVal = setInterval(Check, 100); 

[Tom(2)]

hi xeef,

danke für die mc-load varianten!!!

[norbman]

@Xeef: Danke für die Antwort, ich finde das aber sehr umständlich,
vor allem, da meine Flash-Applikation selbst nicht einen einzigen
Bibliotheks-Inhalt hat, sondern alles während der Laufzeit,
durch XML-Dateien gesteuert, von AS erzeugt wird...

Dazu kommt ja wohl auch noch das Problem, das Flash asynchron lädt,
ich also bei jedem XML-Objekt, jedem Bild, jedem Sound usw. anscheinend
einen Loader verwenden muß um zu checken, ob der Content im Programm ist...

Gruss, norbman

[Tom(2)]

hi, ich nochmal...

Zitat von xeef

(...)
Q = new MovieClipLoader();
L = {};
L.onLoadInit = function(_mc) {
        _mc.onPress = function() {
                trace("Hallo By MovieClipLoader");
        };
};
Q.addListener(L);
Q.loadClip("a.swf", Clip2);
(...) 

wie kann ich denn die so in einer for schleife erzeugten buttons ne funktion auslösen lassen, die als parameter die iteration der for schleife enthält?
ich habe n thumbnails, die n .flv filme triggern sollen. die trigger funktion lautet getMovie(mov), wobei mov der position im array entspricht, in dem filmdatei, filmlänge und thumbdatei drin stehen...

hier ist nochmal die momentane for schleife:

var clips = [
    ["film1.flv",22.793,"film1.jpg"],
    ["film2.flv",13.040,"film2.jpg"],
    ["film3.flv",35.000,"film3.jpg"]
];
for(var a=0;a<clips.length;a++){ 
// im moment drei movies/längen/thumbs im array 
    var myThumb = "thumb_mc_"+a;
    _root.createEmptyMovieClip(myThumb, _root.getNextHighestDepth());
    
    thumbListener.onLoadInit = function(targetMC:MovieClip) {
        targetMC._width = thumbWidth;
        targetMC._height = thumbHeight;
        
        targetMC.onRelease = function(){
            // wie bekomme ich den wert "a" aus der Schleife hier             
                        // rein? das da geht nicht:
                        getMovie(a);
                        // da haben alle thumbs ne "3" als parameter stehen
        };
        
    }
    
    var imageLoader:MovieClipLoader = new MovieClipLoader();
    imageLoader.addListener(thumbListener);
    imageLoader.loadClip( thumbPath+clips[a][2], myThumb);  
    
    _root[myThumb]._x=a*thumbWidth+vidDisplayWidth+10;
    _root[myThumb]._y=10;
    _root[myThumb].id = myThumb;
 
}
function getMovie(mov) {
        (...)
}; 

Tom

[Xeef]

Hmm

es wundert mich ein bischen das das wie du es gerade machst uberhaupt halbwegs richtig funktionirt


hiermit wird jede runde ein neues erzeugt und der alte uberschrieben
var imageLoader:MovieClipLoader = new MovieClipLoader();

normal brauchst nur EIN MovieClipLoader der kan mehrere clips laden


langer rede kurzer sin
hier wie ichs auf die schnele machen wurde :

var imageLoader:MovieClipLoader = new MovieClipLoader();
thumbListener = {};
thumbListener.onLoadInit = function(targetMC:MovieClip) {
 targetMC._width = thumbWidth;
 targetMC._height = thumbHeight;
 targetMC.onRelease = function() {
  trace(Revers[this._name]);
  trace("undefined -->"+this.id);
 };
};
imageLoader.addListener(thumbListener);
Revers = {};
var clips = ["a.jpg", "b.jpg", "c.jpg"];
for (var a = 0; a<clips.length; a++) {
 var myThumb = "thumb_mc_"+a;
 Revers[myThumb] = a;
 _root.createEmptyMovieClip(myThumb, _root.getNextHighestDepth());
 imageLoader.loadClip(clips[a], myThumb);
 _root[myThumb]._x = a*50;
 _root[myThumb]._y = 10;
 // id wird hier nich functioniren weil es vom loaded clip uberschrieben wird
 _root[myThumb].id = myThumb;
} 

[Tom(2)]

Zitat von Xeef

es wundert mich ein bischen das das wie du es gerade machst uberhaupt halbwegs richtig funktionirt

*hüstel*... ich bin auch verdammt am schwimmen.
meine AS kenntnisse sind total eingerostet, und hinter jeder code ecke lauern neue überaschungen...

was macht den das hier: Revers = {}; ?

ich probiere es mal mit deinem ansatz, ich dachte, ich müsste für jedes thumb so ein movieCliip loader ding machen...

[Xeef]

sind abkurzungen --->

a = new Object();
A = {};
b = new Array();
B = [];

[Tom(2)]

ah, ok, verstehe, danke!

Dein Code funktioniert 1a, juhu.
Vielen, vielen Dank.

Tom