Flashforum - Die Community zu Adobe Flash, Flex AIR. Web Design und Inspiration.

pejot · 25-06-2005, 12:15

Servus

Ich habe ein dynamisches Menü gescriptet, in welchem die Informationen zu Format und Anordnug des Menüs aus einer XML-Datei bezogen werden.
Mein Problem ist jetzt, das die Menüeigenschaften einwandfrei aus der XML ausgelesen werden; sie lassen sich auch ohne Probleme austracen.
Allerdings werden sie nicht verarbeitet bzw. die Buttons werden nicht angezeigt.
Ich denke mal, dass es sich nur um ein kleinen Flüchtigkeitsfehler handelt, da vor der XML-Anbindung (fast) alles wunschgemäß funktionierte.
Wahrscheinlich sehe ich mal wwieder den Wald vor lauter Bäumen nicht.

Mein Actionscript:

ActionScript:

///////////////////////////////// OPTIK ///////////////////////////////////
// XML
format_xml = new XML();
format_xml.ignoreWhite = true;
format_xml.load("format.xml");
format_xml.onLoad = function(status) {
    if (status && this.loaded) {
        trace('format.xml geladen');
        //++++++++++++++++++++++++++++++ optik des menues +++++++++++++++++++++++++
        format_menue = format_xml.firstChild.childNodes[0].attributes;
        _global.abstand_menuepunkte = format_menue.buttonabstand;
        _global.xposition_menue = format_menue.xposition;
        _global.yposition_menue = format_menue.yposition;
        _global.buttonhoehe = format_menue.buttonhoehe;
        _global.buttonbreite = format_menue.buttonbreite;
        _global.buttonfarbe = format_menue.buttonfarbe;
        _global.buttonfarbe_rand = format_menue.buttonrandfarbe;
        _global.buttontransparenz = format_menue.buttontransparenz;
        _global.buttonrandtransparenz = format_menue.buttonrandtransparenz;
        _global.randbreite = format_menue.buttonrandtransparenz;
        //++++++++++++++++++++++++++++++ optik des balkens +++++++++++++++++++++++++
        format_balken = format_xml.firstChild.childNodes[1].attributes;
        _global.startx = format_balken.xposition;
        _global.starty = format_balken.yposition;
        _global.breite = format_balken.breite;
        _global.hoehe = format_balken.hoehe;
        _global.farbe = format_balken.farbe;
        _global.alpha = format_balken.transparenz;
        //++++++++++++++++++++++++++++++ schriftformatierung ++++++++++++++++++++++
        format_text = format_xml.firstChild.childNodes[2].attributes;
        _global.textfarbe = format_text.farbe;
        _global.schriftart = format_text.schriftart;
        _global.schriftgroesse = format_text.schriftgroesse;
        _global.schriftfett = format_text.schriftfett;
        _global.schriftkursiv = format_text.schriftkursiv;
        _global.schriftunterstrichen = format_text.schriftunterstrichen;
        _global.textausrichtung = format_text.textausrichtung;
        //++++++++++++++++++++++++++++++ ziel mc format ++++++++++++++++++++++
        format_ziel = format_xml.firstChild.childNodes[3].attributes;
        _global.ziel_xpos = format_ziel.xposition;
        _global.ziel_ypos = format_ziel.yposition;
        var geladen = true;
        createziel();
    }
};
stop();
///////////////////////////////// TECHNIK //////////////////////////////////
createziel = function () {
    // ++++++++++++++++++++++++++++++ externe dateien +++++++++++++++++++++++++++
    _root.createEmptyMovieClip("ziel", 2);
    _root.ziel._x = ziel_xpos;
    _root.ziel._y = ziel_ypos;
    _root.ziel.loadMovie("test.swf");
    preloader();
};
// XML
pfade_xml = new XML();
pfade_xml.ignoreWhite = true;
pfade_xml.load("pfade.xml");
pfade_xml.onLoad = function(status) {
    if (status && this.loaded) {
        _global.anzahl_menuepunkte = pfade_xml.firstChild.childNodes.length;
        var geladen = true;
        buttons();
    }
};
//
buttons = function () {
    for (var i = 0; i<anzahl_menuepunkte; i++) {
        _global.path = pfade_xml.firstChild.childNodes[i].attributes.pfad;
        // +++++++++++++++++++++++++++++ buttons zeichnen ++++++++++++++++++++++++++
        _root.createEmptyMovieClip("btnFill"+i, i+1000);
        mcName = "btnFill"+i;
        trace(xposition_menue);
        trace(buttonhoehe);
        trace(abstand_menuepunkte);
        trace(buttonfarbe);
        trace(buttonbreite);
        trace(buttontransparenz);
        this[mcName]._x = xposition_menue;
        this[mcName]._y = yposition_menue+buttonhoehe*(i)+abstand_menuepunkte*(i);
        with (this[mcName]) {
            beginFill(buttonfarbe, buttontransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
            endFill;
        }
        _root.createEmptyMovieClip("btnBorder"+i, i+2000);
        mcName2 = "btnBorder"+i;
        this[mcName2]._x = xposition_menue;
        this[mcName2]._y = yposition_menue+buttonhoehe*(i)+abstand_menuepunkte*(i);
        with (this[mcName2]) {
            lineStyle(randbreite, buttonfarbe_rand, buttonrandtransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
        }
        trace(path);
        // ++++++++++++++++++++++++++++++ buttonereignisse ++++++++++++++++++++++++++
        this[mcName].onPress = function() {
            ziel.loadMovie(path);
            preloader();
        };
    }
    // Ende For-Schleife
};
//////////////////////////////// PRELOADER ////////////////////////////////
preloader = function () {
//+++++++++++++++++++++++++++++++ der balken +++++++++++++++++++++++++++++++++
      _root.createEmptyMovieClip("balken_mc",1);
        balken_mc._x = startx;
        balken_mc._y = starty;
        with(balken_mc){
        beginFill(farbe,alpha);
        lineTo(0,hoehe);
        lineTo(breite,hoehe);
        lineTo(breite,0);    
        lineTo(0,0);
        endFill();
        };
//++++++++++++++++++++++++++++++ die anzeige +++++++++++++++++++++++++++++++++
         for(var i = 1;i <= 5;i++){
         _root.createTextField("anzeige"+i,20+i,startx,starty+(20*i),300,20);
         anzeigeformat = new TextFormat();
         anzeigeformat.color = textfarbe;
         anzeigeformat.font = schriftart;
         anzeigeformat.size = schriftgroesse;
         anzeigeformat.bold = schriftfett;
         anzeigeformat.italic = schriftkursiv;
         anzeigeformat.underline = schriftunterstrichen;
         anzeigeformat.align = textausrichtung;
         }
         _root.onEnterFrame = function(){
         var total = _root.ziel.getBytesTotal();
         var geladen = _root.ziel.getBytesLoaded();
         var zeit = getTimer();
         var sekunden = Math.round((zeit-at)/1000);
         var b = Math.round((total*sekunden)/geladen);
         var togo = Math.round(-(sekunden-b));
         if(geladen == total){
         for(var i = 1;i <= 5;i++){
            _root["anzeige"+i].removeTextField();
         }
         balken_mc.clear();
         delete this.onEnterFrame;
         }
         else {var prozent = (geladen/total)*100;
         anzeige1.text = "Es wurden "+Math.round(geladen/1024)+" Kb von "+Math.round(total/1024)+" Kb geladen";
         anzeige1.setTextFormat(anzeigeformat);
         anzeige2.text = "Das sind nach Adam Riese "+Math.round(prozent)+" %";
         anzeige2.setTextFormat(anzeigeformat);
         anzeige3.text = "Die abgelaufene Zeit beträgt "+sekunden+" Sekunden";
         anzeige3.setTextFormat(anzeigeformat);
         anzeige4.text = "Sie müssen sich noch ca. "+togo+" Sekunden gedulden";
         anzeige4.setTextFormat(anzeigeformat);
         balken_mc._xscale = prozent;
        }
 
}
};

die XML-Datei:

PHP-Code:

  <?xml version='1.0' encoding='utf-8'?>
  <format>
    <menue buttonabstand="5" xposition="20" yposition="20" buttonhoehe="20" buttonbreite="80" buttonfarbe="0x009900" buttonrandfarbe="0x000000" buttontransparenz="100" buttonrandtransparenz="100" randbreite="1" />
    <balken xposition="290" yposition="190" breite="250" hoehe="10" farbe="0x009900" transparenz="100" />
    <schrift farbe="0x009900" schriftart="'Verdana'" schriftgroesse="10" schriftfett="0" schriftkursiv="0" schriftunterstrichen="0" textausrichtung="'left'"/>
    <container xposition="150" yposition="20" breite="" hoehe="" />
</format>

Ich bedanke mich schon mal für eure Hilfe.

Gruß PeJot

pejot · 27-06-2005, 16:25

Keiner ne Idee?

Der Frager · 27-06-2005, 16:41

Hi!
Lad doch mal die "pfade_xml" hoch. Das scheint doch das Problemkind zu sein!?

pejot · 27-06-2005, 16:50

PHP-Code:

  <?xml version='1.0' encoding='utf-8'?>
  <pfade>
    <video pfad="test1.swf" beschreibung="test1" />
    <video pfad="test2.swf" beschreibung="test2" />
    <video pfad="test3.swf" beschreibung="test3" />
    <video pfad="test4.swf" beschreibung="test4" />
    <video pfad="test5.swf" beschreibung="test5" />
</pfade>

Ich denke aber nicht, dass hier der Hund begraben liegt. Die Pade.xml brauche ich ja erst, wenn ich einen Button betätige, die aber wiederum nicht dargestellt werden.
Hab mal gehört, das ne XML desöfteren nen kleinen Augenblick zum Laden braucht. Ist da was dran?
Hab nämlich, ehrlich gesagt nie Probleme mit XML-Anbindungen gehabt.
Steh irgendwie auf dem Schlauch.

Gruß PeJot

Der Frager · 27-06-2005, 16:53

Nee, lag daran:

ActionScript:

_root.createEmptyMovieClip("btnFill"+i, i+1000);
mcName = _root["btnFill"+i];

Das war vorher für Flash nur ein String...

pejot · 27-06-2005, 17:16

Stimmt, hab ich übersehen. Danke

Will trotzdem nicht so recht funktionieren. Hmmm.

Der Frager · 27-06-2005, 17:26

Hi!
Hättest die mal die Y-Position tracen sollen, das waren vielleicht Werte

. Ging los mit 2000

ActionScript:

///////////////////////////////// OPTIK ///////////////////////////////////
// XML
format_xml = new XML();
format_xml.ignoreWhite = true;
format_xml.load("format.xml");
format_xml.onLoad = function(status) {
    if (status && this.loaded) {
        trace('format.xml geladen');
        //++++++++++++++++++++++++++++++ optik des menues +++++++++++++++++++++++++
        format_menue = format_xml.firstChild.childNodes[0].attributes;
        _global.abstand_menuepunkte = format_menue.buttonabstand;
        _global.xposition_menue = format_menue.xposition;
        _global.yposition_menue = format_menue.yposition;
        _global.buttonhoehe = format_menue.buttonhoehe;
        _global.buttonbreite = format_menue.buttonbreite;
        _global.buttonfarbe = format_menue.buttonfarbe;
        _global.buttonfarbe_rand = format_menue.buttonrandfarbe;
        _global.buttontransparenz = format_menue.buttontransparenz;
        _global.buttonrandtransparenz = format_menue.buttonrandtransparenz;
        _global.randbreite = format_menue.buttonrandtransparenz;
        //++++++++++++++++++++++++++++++ optik des balkens +++++++++++++++++++++++++
        format_balken = format_xml.firstChild.childNodes[1].attributes;
        _global.startx = format_balken.xposition;
        _global.starty = format_balken.yposition;
        _global.breite = format_balken.breite;
        _global.hoehe = format_balken.hoehe;
        _global.farbe = format_balken.farbe;
        _global.alpha = format_balken.transparenz;
        //++++++++++++++++++++++++++++++ schriftformatierung ++++++++++++++++++++++
        format_text = format_xml.firstChild.childNodes[2].attributes;
        _global.textfarbe = format_text.farbe;
        _global.schriftart = format_text.schriftart;
        _global.schriftgroesse = format_text.schriftgroesse;
        _global.schriftfett = format_text.schriftfett;
        _global.schriftkursiv = format_text.schriftkursiv;
        _global.schriftunterstrichen = format_text.schriftunterstrichen;
        _global.textausrichtung = format_text.textausrichtung;
        //++++++++++++++++++++++++++++++ ziel mc format ++++++++++++++++++++++
        format_ziel = format_xml.firstChild.childNodes[3].attributes;
        _global.ziel_xpos = format_ziel.xposition;
        _global.ziel_ypos = format_ziel.yposition;
        var geladen = true;
        createziel();
    }
};
stop();
///////////////////////////////// TECHNIK //////////////////////////////////
createziel = function () {
    // ++++++++++++++++++++++++++++++ externe dateien +++++++++++++++++++++++++++
    _root.createEmptyMovieClip("ziel", 2);
    _root.ziel._x = ziel_xpos;
    _root.ziel._y = ziel_ypos;
    _root.ziel.loadMovie("test.swf");
    preloader();
};
// XML
pfade_xml = new XML();
pfade_xml.ignoreWhite = true;
pfade_xml.load("pfade.xml");
pfade_xml.onLoad = function(status) {
    if (status && this.loaded) {
        _global.anzahl_menuepunkte = pfade_xml.firstChild.childNodes.length;
        var geladen = true;
        buttons();
    }
};
//
buttons = function () {
    for (var i = 0; i<anzahl_menuepunkte; i++) {
        _global.path = pfade_xml.firstChild.childNodes[i].attributes.pfad;
        // +++++++++++++++++++++++++++++ buttons zeichnen ++++++++++++++++++++++++++
        _root.createEmptyMovieClip("btnFill"+i, i+1000);
        mcName = _root["btnFill"+i];
        //trace(xposition_menue);
        //trace(buttonhoehe);
        //trace(abstand_menuepunkte);
        //trace(buttonfarbe);
        //trace(buttonbreite);
        //trace(buttontransparenz);
        mcName._x = xposition_menue;
        mcName._y = Number(yposition_menue)+Number(buttonhoehe)*(i)+Number(abstand_menuepunkte)*(i);
        trace(Number(buttonhoehe))
        trace(mcName._y)
        with (mcName) {
            beginFill(buttonfarbe, buttontransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
            endFill;
        }
        _root.createEmptyMovieClip("btnBorder"+i, i+2000);
        mcName2 = _root["btnBorder"+i];
        mcName2._x = xposition_menue;
        mcName2._y = yposition_menue+buttonhoehe*(i)+abstand_menuepunkte*(i);
        with (mcName2) {
            lineStyle(randbreite, buttonfarbe_rand, buttonrandtransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
        }
        trace(path);
        // ++++++++++++++++++++++++++++++ buttonereignisse ++++++++++++++++++++++++++
        mcName.onPress = function() {
            ziel.loadMovie(path);
            preloader();
        };
    }
    // Ende For-Schleife
};
//////////////////////////////// PRELOADER ////////////////////////////////
preloader = function () {
    // +++++++++++++++++++++++++++++++ der balken +++++++++++++++++++++++++++++++++
    _root.createEmptyMovieClip("balken_mc", 1);
    balken_mc._x = startx;
    balken_mc._y = starty;
    with (balken_mc) {
        beginFill(farbe, alpha);
        lineTo(0, hoehe);
        lineTo(breite, hoehe);
        lineTo(breite, 0);
        lineTo(0, 0);
        endFill();
    }
    // ++++++++++++++++++++++++++++++ die anzeige +++++++++++++++++++++++++++++++++
    for (var i = 1; i<=5; i++) {
        _root.createTextField("anzeige"+i, 20+i, startx, starty+(20*i), 300, 20);
        anzeigeformat = new TextFormat();
        anzeigeformat.color = textfarbe;
        anzeigeformat.font = schriftart;
        anzeigeformat.size = schriftgroesse;
        anzeigeformat.bold = schriftfett;
        anzeigeformat.italic = schriftkursiv;
        anzeigeformat.underline = schriftunterstrichen;
        anzeigeformat.align = textausrichtung;
    }
    _root.onEnterFrame = function() {
        var total = _root.ziel.getBytesTotal();
        var geladen = _root.ziel.getBytesLoaded();
        var zeit = getTimer();
        var sekunden = Math.round((zeit-at)/1000);
        var b = Math.round((total*sekunden)/geladen);
        var togo = Math.round(-(sekunden-b));
        if (geladen == total) {
            for (var i = 1; i<=5; i++) {
                _root["anzeige"+i].removeTextField();
            }
            balken_mc.clear();
            delete this.onEnterFrame;
        } else {
            var prozent = (geladen/total)*100;
            anzeige1.text = "Es wurden "+Math.round(geladen/1024)+" Kb von "+Math.round(total/1024)+" Kb geladen";
            anzeige1.setTextFormat(anzeigeformat);
            anzeige2.text = "Das sind nach Adam Riese "+Math.round(prozent)+" %";
            anzeige2.setTextFormat(anzeigeformat);
            anzeige3.text = "Die abgelaufene Zeit beträgt "+sekunden+" Sekunden";
            anzeige3.setTextFormat(anzeigeformat);
            anzeige4.text = "Sie müssen sich noch ca. "+togo+" Sekunden gedulden";
            anzeige4.setTextFormat(anzeigeformat);
            balken_mc._xscale = prozent;
        }
    };
};

EDIT: Würde schon bei der Übergabe aus der XML ein Number davor setzen. Das hier war nur zum Tersten...

Der Frager · 27-06-2005, 17:36

So, nochmal angepasst...

ActionScript:

///////////////////////////////// OPTIK ///////////////////////////////////
// XML
format_xml = new XML();
format_xml.ignoreWhite = true;
format_xml.load("format.xml");
format_xml.onLoad = function(status) {
    if (status && this.loaded) {
        trace('format.xml geladen');
        //++++++++++++++++++++++++++++++ optik des menues +++++++++++++++++++++++++
        format_menue = format_xml.firstChild.childNodes[0].attributes;
        _global.abstand_menuepunkte = Number(format_menue.buttonabstand);
        _global.xposition_menue = Number(format_menue.xposition);
        _global.yposition_menue = Number(format_menue.yposition);
        _global.buttonhoehe = Number(format_menue.buttonhoehe);
        _global.buttonbreite = Number(format_menue.buttonbreite);
        _global.buttonfarbe = format_menue.buttonfarbe;
        _global.buttonfarbe_rand = format_menue.buttonrandfarbe;
        _global.buttontransparenz = Number(format_menue.buttontransparenz);
        _global.buttonrandtransparenz = Number(format_menue.buttonrandtransparenz);
        _global.randbreite = Number(format_menue.buttonrandbreite);
        //++++++++++++++++++++++++++++++ optik des balkens +++++++++++++++++++++++++
        format_balken = format_xml.firstChild.childNodes[1].attributes;
        _global.startx = Number(format_balken.xposition);
        _global.starty = Number(format_balken.yposition);
        _global.breite = Number(format_balken.breite);
        _global.hoehe = Number(format_balken.hoehe);
        _global.farbe = format_balken.farbe;
        _global.alpha = Number(format_balken.transparenz);
        //++++++++++++++++++++++++++++++ schriftformatierung ++++++++++++++++++++++
        format_text = format_xml.firstChild.childNodes[2].attributes;
        _global.textfarbe = format_text.farbe;
        _global.schriftart = format_text.schriftart;
        _global.schriftgroesse = format_text.schriftgroesse;
        _global.schriftfett = format_text.schriftfett;
        _global.schriftkursiv = format_text.schriftkursiv;
        _global.schriftunterstrichen = format_text.schriftunterstrichen;
        _global.textausrichtung = format_text.textausrichtung;
        //++++++++++++++++++++++++++++++ ziel mc format ++++++++++++++++++++++
        format_ziel = format_xml.firstChild.childNodes[3].attributes;
        _global.ziel_xpos = Number(format_ziel.xposition);
        _global.ziel_ypos = Number(format_ziel.yposition);
        var geladen = true;
        createziel();
    }
};
stop();
///////////////////////////////// TECHNIK //////////////////////////////////
createziel = function () {
    // ++++++++++++++++++++++++++++++ externe dateien +++++++++++++++++++++++++++
    _root.createEmptyMovieClip("ziel", 2);
    _root.ziel._x = ziel_xpos;
    _root.ziel._y = ziel_ypos;
    _root.ziel.loadMovie("test.swf");
    preloader();
};
// XML
pfade_xml = new XML();
pfade_xml.ignoreWhite = true;
pfade_xml.load("pfade.xml");
pfade_xml.onLoad = function(status) {
    if (status && this.loaded) {
        _global.anzahl_menuepunkte = pfade_xml.firstChild.childNodes.length;
        var geladen = true;
        buttons();
    }
};
//
buttons = function () {
    for (var i = 0; i<anzahl_menuepunkte; i++) {
        _global.path = pfade_xml.firstChild.childNodes[i].attributes.pfad;
        // +++++++++++++++++++++++++++++ buttons zeichnen ++++++++++++++++++++++++++
        _root.createEmptyMovieClip("btnFill"+i, i+1000);
        mcName = _root["btnFill"+i];
        // trace(xposition_menue);
        // trace(buttonhoehe);
        // trace(abstand_menuepunkte);
        // trace(buttonfarbe);
        // trace(buttonbreite);
        // trace(buttontransparenz);
        mcName._x = xposition_menue;
        mcName._y = yposition_menue+buttonhoehe*(i)+abstand_menuepunkte*(i);
        with (mcName) {
            beginFill(buttonfarbe, buttontransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
            endFill;
        }
        _root.createEmptyMovieClip("btnBorder"+i, i+2000);
        mcName2 = _root["btnBorder"+i];
        mcName2._x = xposition_menue;
        mcName2._y = yposition_menue+buttonhoehe*(i)+abstand_menuepunkte*(i);
        with (mcName2) {
            lineStyle(randbreite, buttonfarbe_rand, buttonrandtransparenz);
            moveTo(0, 0);
            lineTo(buttonbreite, 0);
            lineTo(buttonbreite, buttonhoehe);
            lineTo(0, buttonhoehe);
            lineTo(0, 0);
        }
        trace(path);
        // ++++++++++++++++++++++++++++++ buttonereignisse ++++++++++++++++++++++++++
        mcName.onPress = function() {
            ziel.loadMovie(path);
            preloader();
        };
    }
    // Ende For-Schleife
};
//////////////////////////////// PRELOADER ////////////////////////////////
preloader = function () {
    // +++++++++++++++++++++++++++++++ der balken +++++++++++++++++++++++++++++++++
    _root.createEmptyMovieClip("balken_mc", 1);
    balken_mc._x = startx;
    balken_mc._y = starty;
    with (balken_mc) {
        beginFill(farbe, alpha);
        lineTo(0, hoehe);
        lineTo(breite, hoehe);
        lineTo(breite, 0);
        lineTo(0, 0);
        endFill();
    }
    // ++++++++++++++++++++++++++++++ die anzeige +++++++++++++++++++++++++++++++++
    for (var i = 1; i<=5; i++) {
        _root.createTextField("anzeige"+i, 20+i, startx, starty+(20*i), 300, 20);
        anzeigeformat = new TextFormat();
        anzeigeformat.color = textfarbe;
        anzeigeformat.font = schriftart;
        anzeigeformat.size = schriftgroesse;
        anzeigeformat.bold = schriftfett;
        anzeigeformat.italic = schriftkursiv;
        anzeigeformat.underline = schriftunterstrichen;
        anzeigeformat.align = textausrichtung;
    }
    _root.onEnterFrame = function() {
        var total = _root.ziel.getBytesTotal();
        var geladen = _root.ziel.getBytesLoaded();
        var zeit = getTimer();
        var sekunden = Math.round((zeit-at)/1000);
        var b = Math.round((total*sekunden)/geladen);
        var togo = Math.round(-(sekunden-b));
        if (geladen == total) {
            for (var i = 1; i<=5; i++) {
                _root["anzeige"+i].removeTextField();
            }
            balken_mc.clear();
            delete this.onEnterFrame;
        } else {
            var prozent = (geladen/total)*100;
            anzeige1.text = "Es wurden "+Math.round(geladen/1024)+" Kb von "+Math.round(total/1024)+" Kb geladen";
            anzeige1.setTextFormat(anzeigeformat);
            anzeige2.text = "Das sind nach Adam Riese "+Math.round(prozent)+" %";
            anzeige2.setTextFormat(anzeigeformat);
            anzeige3.text = "Die abgelaufene Zeit beträgt "+sekunden+" Sekunden";
            anzeige3.setTextFormat(anzeigeformat);
            anzeige4.text = "Sie müssen sich noch ca. "+togo+" Sekunden gedulden";
            anzeige4.setTextFormat(anzeigeformat);
            balken_mc._xscale = prozent;
        }
    };
};

pejot · 27-06-2005, 17:37

Der Hammer

Danke!!!

Wohin geht das Bier?

Lag das jetzt nur an dem „Number(…“?

Gruß Patrick

Der Frager · 27-06-2005, 17:45

Jepp!
Das hier machte zwar auch keinen Sinn,

ActionScript:

_global.randbreite = format_menue.buttonrandtransparenz;

aber das hättest du wohl selber gesehen! Ansonsten kommen aus der XML halt Strings an. Die müssen dann noch umgewandelt werden.

pejot · 27-06-2005, 17:49

Zitat:

Zitat von Der Frager

Jepp!
Das hier machte zwar auch keinen Sinn,

ActionScript:

_global.randbreite = format_menue.buttonrandtransparenz;

aber das hättest du wohl selber gesehen! Ansonsten kommen aus der XML halt Strings an. Die müssen dann noch umgewandelt werden.

Ups, ein Rotwerd-Smilie wäre jetzt angebracht. Hast mir ja das letzte mal schon bei nem ähnlichen Problem geholfen.

Hab mich noch nicht mit der Number-Klasse beschäftigt, was ich wohl jetzt unverzüglich nachholen muss.

Nochmal tausend Dank. Schöne Woche noch.

27-06-2005, 16:25	#2 (permalink)
pejot Flash addicted Registriert seit: Apr 2004 Ort: Luxembourg-Trier-Berlin Beiträge: 486	Keiner ne Idee? __________________ … wortkarge Signatur

27-06-2005, 16:41	#3 (permalink)
Der Frager ................ Registriert seit: Jun 2004 Beiträge: 15.890	Hi! Lad doch mal die "pfade_xml" hoch. Das scheint doch das Problemkind zu sein!? __________________ ternärer Konditionaloperator +++ Bitte keine Privat-Nachrichten bezüglich Flashfragen! +++

27-06-2005, 16:50	#4 (permalink)
pejot Flash addicted Registriert seit: Apr 2004 Ort: Luxembourg-Trier-Berlin Beiträge: 486	PHP-Code: `<?xml version='1.0' encoding='utf-8'?> <pfade> <video pfad="test1.swf" beschreibung="test1" /> <video pfad="test2.swf" beschreibung="test2" /> <video pfad="test3.swf" beschreibung="test3" /> <video pfad="test4.swf" beschreibung="test4" /> <video pfad="test5.swf" beschreibung="test5" /> </pfade>` Ich denke aber nicht, dass hier der Hund begraben liegt. Die Pade.xml brauche ich ja erst, wenn ich einen Button betätige, die aber wiederum nicht dargestellt werden. Hab mal gehört, das ne XML desöfteren nen kleinen Augenblick zum Laden braucht. Ist da was dran? Hab nämlich, ehrlich gesagt nie Probleme mit XML-Anbindungen gehabt. Steh irgendwie auf dem Schlauch. Gruß PeJot __________________ … wortkarge Signatur

27-06-2005, 16:53	#5 (permalink)
Der Frager ................ Registriert seit: Jun 2004 Beiträge: 15.890	Nee, lag daran: ActionScript: _root.createEmptyMovieClip("btnFill"+i, i+1000); mcName = _root["btnFill"+i]; Das war vorher für Flash nur ein String... __________________ ternärer Konditionaloperator +++ Bitte keine Privat-Nachrichten bezüglich Flashfragen! +++

27-06-2005, 17:16	#6 (permalink)
pejot Flash addicted Registriert seit: Apr 2004 Ort: Luxembourg-Trier-Berlin Beiträge: 486	Stimmt, hab ich übersehen. Danke Will trotzdem nicht so recht funktionieren. Hmmm. __________________ … wortkarge Signatur

27-06-2005, 17:37	#9 (permalink)
pejot Flash addicted Registriert seit: Apr 2004 Ort: Luxembourg-Trier-Berlin Beiträge: 486	Der Hammer Danke!!! Wohin geht das Bier? Lag das jetzt nur an dem „Number(…“? Gruß Patrick __________________ … wortkarge Signatur

27-06-2005, 17:45	#10 (permalink)
Der Frager ................ Registriert seit: Jun 2004 Beiträge: 15.890	Jepp! Das hier machte zwar auch keinen Sinn, ActionScript: _global.randbreite = format_menue.buttonrandtransparenz; aber das hättest du wohl selber gesehen! Ansonsten kommen aus der XML halt Strings an. Die müssen dann noch umgewandelt werden. __________________ ternärer Konditionaloperator +++ Bitte keine Privat-Nachrichten bezüglich Flashfragen! +++

Themen-Optionen
Druckbare Version zeigen Jemanden per E-Mail auf dieses Thema hinweisen
Ansicht
Linear-Darstellung Zur Hybrid-Darstellung wechseln Zur Baum-Darstellung wechseln