[denkfehler?] loadMovie + alpha

[haartrockner]

hi zusammen,
bin langsam echt am verzweifeln.
warum geht es so:

stop();
_root.mc1._alpha = 0;
function einblendenmc1() {
    _root.mc1.onEnterFrame = function() {
        if (_root.mc1._alpha<100) {
            _root.mc1._alpha += 5;
        }
    };
}
function ausblendenmc1() {
    _root.mc1.onEnterFrame = function() {
        if (_root.mc1._alpha>0) {
            _root.mc1._alpha -= 5;
        }
    };
}
loadVariables("../inhalte/texte/1.txt", "text");
einblendenmc1();
pause = setInterval(function () {
    ausblendenmc1(), clearInterval(pause);
}, 9000); 

hier wird ein text geladen. dieser wird schön eingeblendet, pause und wieder ausgeblendet, so soll es auch sein.
lade ich dagegen ein swf file oder bild:

stop();
_root.mc1._alpha = 0;
function einblendenmc1() {
    _root.mc1.onEnterFrame = function() {
        if (_root.mc1._alpha<100) {
            _root.mc1._alpha += 5;
        }
    };
}
function ausblendenmc1() {
    _root.mc1.onEnterFrame = function() {
        if (_root.mc1._alpha>0) {
            _root.mc1._alpha -= 5;
        }
    };
}
loadMovie("../inhalte/flash/mc1.swf", "_root.mc1");
einblendenmc1();
pause = setInterval(function () {
    ausblendenmc1(), clearInterval(pause);
}, 9000); 

wird zwar die datei geladen aber das ein und ausblenden funktioniert nicht mehr?
das gibts doch nich? ich hüpp gleich aus dem fenster...

[warrantmaster]

laß die funktion einen dummy ausführen,
da du dem mc1 eine funktion zuweist,
die du durch das laden in diesen mc wider überschreibst !

function einblendenmc1() {
        _root.dummy_mc.onEnterFrame = function() {
                if (_root.mc1._alpha<100) {
                        _root.mc1._alpha += 5;
                }
        };
} 

btw,
du solltest die onenterframes nach getaner arbeit deleten !
die performance wird echt besser durch sowas...

[haartrockner]

so funktioniert es aber leider gar nicht. ich hab zwar verstanden was du meinst, aber so geht es leider gar nicht.
ich hab mal noch ein trace für alpha eingebaut

stop();
_root.mc1._alpha = 0;
function einblendenmc1() {
    _root.mc1.onEnterFrame = function() {
        if (_root.mc1._alpha<100) {
            _root.mc1._alpha += 5;
            trace(_root.mc1._alpha);
        }
    };
} 

in der ausgabe erscheint nur ein einziges mal eine 4.6875. er scheint das enterframe nicht durchzuführen?!???
das gibts doch nicht. mit nem text funktioniert es, aber mit nem anderen inhalt nicht... ahhhh

[HAY]

hi
du machst ja wieder das onenterframe auf deinen mc1.
mach es wie @warrantmaster geschrieben hat.dann gehts.

[haartrockner]

hi hay
von dir hab ich das ganze geklaut
so

stop();
_root.mc1._alpha = 0;
function einblendenmc1() {
    _root.dummy_mc.onEnterFrame = function() {
        if (_root.mc1._alpha<100) {
            _root.mc1._alpha += 5;
            trace(_root.mc1._alpha);
        }
    };
} 

tut sich leider gar nix. ich versteh das nicht.

[HAY]

hi
habe hier nochwas gefunden wie mann das lösen kann.
vieleicht hilfts dir.
1)erstellt mc box
2)wartet bis mc geladen ist
3)einblenden
4)pause
3)ausblenden und oEF löschen

MovieClip.prototype.laden=function (name,fade,pause){
    this.createEmptyMovieClip("box",1)
    this.box.loadMovie(name);
    this._alpha=this.flag=0
    this.onEnterFrame = function(){
        if(this._height>0){
        if(this.flag==0){
            this._alpha<100 ? this._alpha+=fade : (this.flag=1,this.zeit=getTimer()+pause)
            }
        if(this.flag==1){
            if(this.zeit<getTimer()){this.flag=2}
        }
        if(this.flag==2){
            this._alpha>0 ? this._alpha-=fade : delete this.onEnterFrame
            }
        }
    }
}
mc1.laden("1.jpg",3,5000) 

[haartrockner]

hi,
ah. das ist ja super. die funktion könnte ich doch dann praktisch auch auf mehrere verschiedene mit verschiedenen "timer" setzen, oder? ich probiers mal aus.
DANKE.

trotzdem würde es mich interessieren wieso das meinige nicht funktioniert. weil dann müsste ich nicht nochmal alles ändern...

[haartrockner]

boah. habs rausgefunden. wenn ich das oEF mit this anspreche funktioniert es...
EDIT: zu früh gefreut. doch nich... bei mehrere scheint er wieder durcheinander zu kommen

[haartrockner]

ich hab mehreren von den funktionen auf meiner bühne liegen. kann es sein dass er durcheinander kommt? ich muss "einfach" immer zwei mcs unterschiedlich lang einblenden. sechs liegen auf der bühne. einer soll eingeblendet, dann ein zweiter derweil der erste wieder aus der nächste usw...
EDIT: noch was, deshalb hatte ich das ein und ausblenden in jeweils eine funktion gesetzt, damit ich die verschiedenen mcs variabel ein und ausblenden kann. es wird jeweils beim ausblenden der nächste inhalt für den mc geladen...

[HAY]

hi
da kann ich dir jetzt nicht helfen wenn ich nicht genau weiß wie du das machst.
nimm den code von oben da kannst du alle unabhängig steuern.

[haartrockner]

hi,
ok. trotzdem besten dank für deine bemühungen!

[HAY]

hi
hier noch mit verschiedenen aktionen.
aktion=0 (laden,warten,einblenden,pause,ausblenden)
wenn mc geladen ist.
aktion=1 (einblenden,pause,ausblenden)
aktion=3 (ausblenden)

MovieClip.prototype.aktionen=function (name,fade,pause,aktion){
    this.flag=aktion
    if(aktion==0){
    this.createEmptyMovieClip("box",1)
    this.box.loadMovie(name);
    this._alpha=0
    this.flag=1
    }
    this.onEnterFrame = function(){
        if(this._height>0){
        if(this.flag==1){
            this._alpha<100 ? this._alpha+=fade : (this.flag=2,this.zeit=getTimer()+pause)
            }
        if(this.flag==2){
            if(this.zeit<getTimer()){this.flag=3}
        }
        if(this.flag==3){
            this._alpha>0 ? this._alpha-=fade : delete this.onEnterFrame
            }
        }
    }
}
mc1.aktionen("1.jpg",3,5000,0)