createEmptyMovieClip verliert seine position

[wiredmaegges]

Hallo erstmal,

so ich habe da ein Problem.

Das funzt:

createEmptyMovieClip("container1",1);
    container1._y = 100;
    container1._x = 100;
    loadMovie("bild1.jpg","container1");
 
    createEmptyMovieClip("container2",2);
    container2._y = 100;
    container2._x = 200;
    loadMovie(["bild2.jpg"],"container2");
 
    createEmptyMovieClip("container3",3);
    container3._y = 100;
    container3._x = 300;
    loadMovie(["bild3.jpg"],"container3"); 

Das net:

for(i=1;i<=3;i++){
    createEmptyMovieClip("container"+i,i);
    ["container"+i]._y = 100;
    ["container"+i]._x = 100*i;
    loadMovie("bild"+i+".jpg","container"+i);
    trace(i);
    trace(["container"+i]);
    trace(["container"+i]._x);
    } 

Das ach net:

for(i=1;i<=3;i++){
    createEmptyMovieClip("container"+i,i);
    strposx = ["container"+i]._x
    strposy = ["container"+i]._y
    strposx = 100*i;
    strposy = 100;
    loadMovie("bild"+i+".jpg","container"+i);
    trace(i);
    trace(["container"+i]);
    trace(strposx);
    trace(strposy);
    } 

Und ich verstehe nicht warum! Vielleicht kann mal einer drüber schauen, ich habe auch alles nochmal in eine ZIP eingepackt.

[nanodesigner]

for(i=1;i<=3;i++){
    createEmptyMovieClip("container"+i,i);
    this["container"+i]._y = 100;
    this["container"+i]._x = 100*i;
    loadMovie("bild"+i+".jpg","container"+i);
    trace(i);
    trace(["container"+i]);
    trace(["container"+i]._x);
    } 

[Alois]

Also im Prinzip ist das Problem hier:

["container"+i]._y =.... 

...das funktioniert so nicht, da muss eine eindeutige Zuordnung vor den eckigen Klammern stehen (this oder _root) so würde es schon gehen:

this["container"+i]._y =.... 

...aber da Du eh den mc dynamisch erstellst und bei createEmptyMovieClip der target zurückgegeben wird empfehle ich die das so zu machen:

for(i=1;i<=3;i++){
        var ziel=createEmptyMovieClip("container"+i,i);
        ziel._y = 100;
        ziel._x = 100*i;
        loadMovie("bild"+i+".jpg",ziel);
        trace(i);
        trace(ziel);
        trace(ziel._x);
} 

Gruß

Alois

[wiredmaegges]

Super, das klappt!

Mmmmh, jetzt wollte ich das ganze noch dynamisch machen, indem ich eine ASP-Seite öffne die mir die Anzahl der zu erzeugenden Movieclips(anz=) und die Bildernamen(bild1=xyz.jpg&bild2=zyx.jpg) liefert. Das klappt aber nicht so ganz! Schaut mal:

loadVariables("asp.asp","");
 
for(i=1;i<=anz;i++){
        createEmptyMovieClip("container"+i,i);
        this["container"+i]._y = 100;
        this["container"+i]._x = 100*i;
        loadMovie(bild+i,"container"+i);
        trace(i);
        trace(["container"+i]);
        trace(["container"+i]._x);
} 

Die ASP Seite liefert folgenden String zurück:

&bild1=xyz.jpg&bild2=yxz.jpg&bild3=zyx.jpg&anz= 3

Die Bilder liegen auch da wo Sie sollen.

[wiredmaegges]

Keiner eine Idee?

[wiredmaegges]

Ok Problem gefunden!
Muss auf einen MC gelgt werden das Script.

Jetzt habe ich aber gleich das nächste Prob........

onClipEvent (load) {
    loadVariables("asp.asp", "");
}
onClipEvent (data) {
    for (i=1; i<=anz; i++) {
        var ziel = createEmptyMovieClip("container"+i, i);
        ziel._y = 100;
        ziel._x = 100*i;
        loadMovie("bild"+i, ziel);
        trace(i);
        trace(ziel);
        trace(ziel._x);
    }
} 

asp.asp gibt die Variablen ja in der Form bild1=&bild2= usw. zurück.

Schreibe ich beim loadmovie "bild"+i müsste ja eigentlich im 1. Durchlauf Bild1 drinnen stehen. Das funzt aber nicht.
Schreibe ich loadMovie(bild1, ziel); klappt es, nutzt nur nichts da ich ja die Variable bild mit i hochzählen will um immer neue Bilder zu laden und nicht immer nur eins. Habe auch schon versucht eine Variable zielbild = "bild"+i; zu setzen und dann loadMovie(zielbild, ziel); zu verwenden klappt aber auch net.

P.S.: Warum habe ich dieses Projekt nur jemals angenommen......

[wiredmaegges]

Ok, warum poste ich eigentlich, wenn ich die Lösung dann selbst finde ???

Na ja, ich rede auch gerne mit mir selbst!

Auf jeden Fall die Lösung meines Problems:

onClipEvent (load) {
    loadVariables("asp.asp", "");
}
onClipEvent (data) {
    for (i=1; i<=anz; i++) {
        var ziel = createEmptyMovieClip("container"+i, i);
        var zielbild = this["bild"+i]
        ziel._y = 100;
        ziel._x = 100*i;
        loadMovie(zielbild, ziel);
        trace(i);
        trace(ziel);
        trace(ziel._x);
        trace(zielbild)
    }
} 

Wobei ich nicht wirklich verstehe wieso es damit klappt: this["bild"+i]

Aber ich weiß, wie ich das Forum durchforstet habe nach Lösungen und meistens diese zwar gefunden wurden aber nicht veröffentlicht wurden (Mit Script und allem).