AS-Code ausführen?!

[chrisTheMan]

Hallo,

ich baue mir ActionScript-Code in einer Schleife zusammen und will diesen, nachdem die Schleife durchgelaufen ist, ausführen. Gibt es da eine Möglichkeit?

Bsp.:

var x = "";
for(i = 0; i < de_navi.length; i++) {
temp = eval("naviName"+i);
x += temp1+".onEnterFrame = function() { if ("+temp1+".hitTest(_root._xmouse, _root._ymouse, true)) "+temp+".setTextFormat(over); else "+temp+".setTextFormat(out);};";
} // end for 
 

Jetzt würde ich gerne den Inhalt der Variablen x ausführen...

Freue mich über Eure Hilfe.

Vielen Dank,
chris

[atothek]

was spricht gegen

for (i=0; i<5; i++) {
    temp = this["naviName"+i];
    temp.onEnterFrame = function() {
        if (this.hitTest(_root._xmouse, _root._ymouse, true)) {
            trace(this._name);
        }
    };
} 

????

[lepimax]

mußte so machen wie atothek schreibt.
in laufzeit complieren geht so nicht.
eval ist in as nicht so mächtig wie im javascript.
javascript wird ja auch im browser compiliet. wenn man das so sagen darf.

Gruß
Lepi

[chrisTheMan]

Vielen Dank atothek! Dein Beispiel funktioniert wunderbar. Wie kriege ich mein Beispiel zum Laufen???

Der folgende Code funktioniert leider nur zum Teil. Ich schätze, dass ich bei

temp1.onEnterFrame = function() {
if (this.hitTest(_root._xmouse, _root._ymouse, true)) temp.setTextFormat(over);
else temp.setTextFormat(out);
};

die Variable temp irgendwie anders ansprechen muss. Aber wie?

for(i = 0; i < de_navi.length; i++) {
    depth = "10"+i;
 
    _root.createTextField("naviName"+i,depth,0,0,200,100);
    temp = this["naviName"+i];
    temp.autoSize = true;
    temp.selectable = false;
    temp.html = true;
    temp.htmlText ="<a href=\"asfunction:_root.doNavi,"+ temp +"\">"+ de_navi[i] +" .  </a>";
    
    temp.setTextFormat(myFormat);
    temp._x = xPos;
    temp._y = 154;
    
    clipWidth = temp._width;
    
    _root.attachMovie("bt_bg", "bt_bg"+i, depth-100);
    temp1 = this["bt_bg"+i];
    temp1._xscale = clipWidth;
    temp1._yscale = 20;
    temp1._x = xPos;
    temp1._y = 154;
    temp1._visible = false;
    xPos += temp._width;
 
    temp1.onEnterFrame = function() {
        if (this.hitTest(_root._xmouse, _root._ymouse, true)) temp.setTextFormat(over);
        else temp.setTextFormat(out);
    };
} 

Vielen Dank für die Hilfe!

[atothek]

füg mal folgende zeile über das onEnterFrame

temp1.tf=temp; 

und das onEnterFrame in

temp1.onEnterFrame = function() {
                if (this.hitTest(_root._xmouse, _root._ymouse, true)) this.tf.setTextFormat(over);
                else this.tf.setTextFormat(out);
        }; 

dann müßte es laufen aber ich frag mich jetzt mal warum du ein onEnterFRame für das alles brauchst für mich siht das alles nach einem einfachen RollOver effekt aus oder wie?????

[chrisTheMan]

supercool, genau, das war's

Vielen Dank!!!

[chrisTheMan]

@atothek: Jetzt hatte ich ganz vergessen auf Deine Frage zu antworten, warum ich das mit dem onEnterFrame mache. Ich habe es mit einem onRollOver versucht, was aber nicht funktioniert hat, weil die Funktion beim Draufrollen und Rausrollen aufgerufen wird...

temp1.onRollOver = function() {
this.tf.setTextFormat(over);
};
temp1.onRollOut = function() {
this.tf.setTextFormat(out);
}; 

Ist ein onEnterFrame mit einem hitTest sehr viel rechenaufwendiger?

[atothek]

versuch das ganze mal mit

this.tf.setNewTextFormat(out);

this.tf.setNewTextFormat(over);

[chrisTheMan]

ich fürchte, ich weiss nicht genau was Du meinst.

was bingt das für Vorteile, ob ich setTextFormat oder setNewTextFormat verwende?

[atothek]

Ja sorry mein Fehler hab mich mal wieder nur zur hälftew mitgeteilt

temp1.onRollOver = function() {
        this.tf.setNewTextFormat(over);
};
temp1.onRollOut = function() {
        this.tf.setNewTextFormat(out);
}; 

Versuch doch mal die rollOvers mit setNewTextFormat. Den dauernd Laufende onEnterframes sind Performancekiller nr1 und gerade bei solch
na ich sage mal "ridimentären" sachen wie eine art Rollover effekt

[chrisTheMan]

ok, das habe ich verstanden :-)

Das Problem, dass ich habe ist, dass das onRollOut auch beim draufrollen (und nicht nur beim "runterRollen", wie der Name doch eigentlich sagt) ausgeführt wird. Das bedeutet, dass ein onRollOver nur kurz angezeigt und sofort wieder rückgängig gemacht wird.

Mache ich etwas falsch, oder muss ich etwas zusätzliches beachten???

[atothek]

ne das geht nicht da muß der wurm woanders drin sein schick doch mal ne datei oder sowas zum anschauen weil das mit nem onEnterFrame zu lösen ist echt nicht clever

[chrisTheMan]

ok, hier die Datei. Habe das für mich funktionierende Script auskommentiert dringelassen.

Danke, dass Du reinschaust!

[atothek]

so eine etwas aufgeräumtere Version

this.getTextWidth = function(pText) {
    //
    this.createEmptyMovieClip("__TFWidth", 16547);
    this.__TFWidth.createTextField("txt", -2654, 0, 0, 0, 0);
    var tempTf = this.__TFWidth["txt"];
    tempTf.autoSize = true;
    tempTf.html = true;
    tempTf.htmlText = pText;
    tempTf.setTextFormat(this.myFormat);
    var w = tempTf._width;
    _root.__TFWidth.removeMovieClip();
    return w;
};
//
this.setPosition = function(pClip, pX, pY) {
    pClip._x = pX;
    pClip._y = pY;
};
//
this.initSwf = function() {
    //
    this.de_navi = new Array("Produkte", "Neu", "Profil", "Termine", "Kontakt", "Impressum");
    this.myFormat = new TextFormat();
    this.myFormat.embedFonts = true;
    this.myFormat.bold = false;
    this.myFormat.font = "Verdana";
    this.myFormat.size = 12.5;
    //
    this.over = new TextFormat();
    this.over.bold = true;
    //
    this.out = new TextFormat();
    this.out.bold = false;
    //
    this.xPos = 140;
    //
    for (var i = 0; i<this.de_navi.length; i++) {
        //
        var depth = "10"+i;
        var aktName = "butMc"+i;
        var w = this.getTextWidth("<a href=\"asfunction:_root.doNavi,"+temp._name+"\">"+de_navi[i]+" .  </a>");
        // container für bg clip und tf
        this.createEmptyMovieClip(aktName, depth);
        _root[aktName].attachMovie("bt_bg", "bt_bg"+i, 1);
        this.setPosition(_root[aktName], this.xPos, 154);
        //
        var tempMc = _root[aktName]["bt_bg"+i];
        //
        tempMc._xscale = w;
        tempMc._yscale = 20;
        //
        this.xPos += _root[aktName]._width;
        //
        _root[aktName].createTextField("naviName", 2, 0, 0, 0, 0);
        this.setPosition(_root[aktName].naviName, 0, 0);
        //
        var tf = _root[aktName].naviName;
        //
        tf.selectable = false;
        tf.html = true;
        tf.autoSize = true;
        tf.htmlText = "<a href=\"asfunction:_root.doNavi,"+tempMc._name+"\">"+de_navi[i]+" .  </a>";
        tf.setTextFormat(this.myFormat);
        //
        _root[aktName].onRollOver = function() {
            this.naviName.setTextFormat(this._parent.over);
        };
        _root[aktName].onRollOut = function() {
            this.naviName.setTextFormat(this._parent.out);
        };
    }
};
this.initSwf(); 

[chrisTheMan]

supercool, atothek, was soll ich dazu noch sagen??? Von mir würdest Du eine 1 kriegen !

Merke halt schon, dass ich sehr lange kein Flash mehr gemacht habe und mich da erst wieder reinfuxen muss

Aber es macht Spass.

Vielen vielen Dank!!!