buttons mit url link dynamisch erzeugen?

[echo5-7]

hi,
ich habe ein script, in dem mehrere mc's generiert werden, die auf verschiedene urls verweisen sollen. die urls kommen aus ner xml datei.

das hier ist das script.

PHP-Code:

tl = this;
meinxml = new XML();
meinxml.ignoreWhite = true;
meinxml.onLoad = function() {
    anzahl = this.firstChild.childNodes.length;
    tl.createEmptyMovieClip("container", 15);
    for (x=0; x<anzahl; x++) {
        tl.container.createEmptyMovieClip(["buttonmc"+x], x+(anzahl+1));
    link =this.firstChild.childNodes[x].attributes.link;
        tl["link"+x] = link;
//hier traced er mir noch die richtigen URLs
        trace(tl["link"+x]);
//füllt die pseudo buttons mit ein bissle was
        tl.container["buttonmc"+x].moveTo(0, 0);
        tl.container["buttonmc"+x].beginFill(0x000000, 0);
        tl.container["buttonmc"+x].lineTo(220, 0);
        tl.container["buttonmc"+x].lineTo(220, parseInt(this.firstChild.childNodes[x].attributes.hoehe));
        tl.container["buttonmc"+x].lineTo(0, parseInt(this.firstChild.childNodes[x].attributes.hoehe));
        tl.container["buttonmc"+x].lineTo(0, 0);
        tl.container["buttonmc"+x].endFill();
// hier die button funktion
        tl.container["buttonmc"+x].onRelease = function() {
            trace(tl["link"+x]);
            getURL(tl["link"+x],"_blank");
        };
        
        ywert = ((x)*(parseInt(this.firstChild.childNodes[x].attributes.hoehe)))+15;
        tl.container["buttonmc"+x]._y = ywert;


    }
    };
meinxml.load("xml.xml");
stop(); 


die urls liegen als attribut in der xml wie folgt : link="http://www.eineurl.de"

problem ist, wenn ich jetzt auf die buttons klicke, traced er mir, das tl["link"+x] undefiniert ist. und ich hab nicht die leiseste ahnung warum...

kann mir da jemand helfen?

gruß echo

[:: RK ::]

hi,

hast du das mal versucht ???

tl.link =this.firstChild.childNodes[x].attributes.link; 

[echo5-7]

ehm, ja.
da verweist er mir immer auf das link atribut im letzten knoten, also auf das am ende der for schleife, weil link ja dann eben auf dem wert bleibt (in dem fall google.de )
deswegen wollte ich ja die variablen dynamisch generieren um das problem zu umgehen, aber da bleiben sie undefined.....

[:: RK ::]

ah ich weis wo das problem liegt, dass hat ich auch schon öfters.
(voll übersehen ich blindfisch )

du weist ja dem Button das hier als link zu

tl["link"+x]); 

Jedoch wird "x" nicht als feste Zahl reingeschrieben, is ja nur ne Referenz
auf "x" was ja in der for-schleife immer weiter hochgezählt wird. Wenn also
"x" z.B. 2 seien soll, dann muss du das in deinen Button als zusätzliche Variable
übernehmen, sonst ist "x" nicht 2, sondern so groß wie "anzahl".

also musst du das so machen:

tl.container["buttonmc"+x].index = x;
tl.container["buttonmc"+x].onRelease = function() { 
    trace(tl["link"+this.index]); 
    getURL(tl["link"+this.index],"_blank"); 
}; 

hoffe du hast verstanden, was ich meinte

[echo5-7]

wow, coole sache
funktioniert.
bin an so ner stelle schonmal hängen geblieben, merci für die lösung

[:: RK ::]

np