Button Status bei dynamischen Menu?

[Jenz]

Hallo,

habe folgendes Problem. Der Button Status bei meinem dynamischen Menu will
nicht funktionieren. Was mache ich falsch? Kriegs einfach nicht hin!


Hier mal das AS:

PHP-Code:

//------------------------------------------------------------------
// Array
//------------------------------------------------------------------
    MenuItem = new Array(); 
//------------------------------------------------------------------
        MenuItem[0] = {label:"BUTTON 01", data:"test1.swf"}; 
        MenuItem[1] = {label:"BUTTON 02", data:"test2.swf"}; 
        MenuItem[2] = {label:"BUTTON 03", data:"test3.swf"}; 
        MenuItem[3] = {label:"BUTTON 04", data:"test4.swf"}; 
        MenuItem[4] = {label:"BUTTON 05", data:"test5.swf"}; 
        MenuItem[5] = {label:"BUTTON 06", data:"test6.swf"}; 
        MenuItem[6] = {label:"BUTTON 07", data:"test7.swf"};
        MenuItem[6] = {label:"BUTTON 08", data:"test8.swf"};

//------------------------------------------------------------------
// Action
//------------------------------------------------------------------
    MenuAction="loadMovie";
    Target="ContentMC";

//------------------------------------------------------------------
// Position der Navigation (X,Y) und Höhe der Buttons
//------------------------------------------------------------------
    MenuXPos=100;
    MenuYPos=100;
    MenuHoehe=15;
//------------------------------------------------------------------
PerformAction = function () {
    if (MenuAction=="loadMovie"){
        _root[Target].loadMovie(Content);
    }
    if (MenuAction=="gotoAndStop"){
        gotoAndStop(Content);
    }
    if (MenuAction=="gotoAndPlay"){
        gotoAndPlay(Content);
    }
    if (MenuAction=="loadMovieNum"){
        loadMovieNum(Content, Target);
    }
}
//------------------------------------------------------------------
// Erstellung der Navigation
// 

    for(i=0; i<MenuItem.length; i++){
        _root.createEmptyMovieClip("MenuHolder"+i, i+1);
        _root["MenuHolder"+i]._x=MenuXPos;
        _root["MenuHolder"+i]._y=MenuYpos+(i*MenuHoehe);
        _root["MenuHolder"+i].attachMovie("Button", "button", i+1);
        _root["MenuHolder"+i].button.buttonlabel=MenuItem[i]["label"];
        _root["MenuHolder"+i].button.buttondata=MenuItem[i]["data"];
//------------------------------------------------------------------
// Legt den Button Status fest
//------------------------------------------------------------------

var tl = _root["MenuHolder"+i]["button"];
var clicked;

for (var i = 1; i <= 8; i++) {
    _root["MenuHolder"+i]["button"].onRollOver = function () {
        if (this != tl.clicked) {
            this.gotoAndStop (2);
        }
    };
    _root["MenuHolder"+i]["button"].onRollOut = _root["MenuHolder"+i]["button"].onReleaseOutside = function () {
        if (this != tl.clicked) {
            this.gotoAndStop (1);
        }
    };
    _root["MenuHolder"+i]["button"].onRelease = function () {
        if (this != tl.clicked) {
            //hier die Navigations-Aktion...
            this.gotoAndStop (3);
            tl.clicked.gotoAndStop (1);
            tl.clicked.useHandCursor = true;
            tl.clicked = this;
            this.useHandCursor = false;
        }
    };
}

//------------------------------------------------------------------
// onRelease actions
//------------------------------------------------------------------
        _root["MenuHolder"+i]["button"].onRelease = function() {
            Content = this.buttondata;
            PerformAction(Content);
        }
}; 


Datei hab ich auch mal angehängt.


Vielen Dank schon mal!!!!

Viele Grüße Jenz

[Der Frager]

Hallo!

Da funzt ja gar nix... Eine Schleife in einer Schleife und beide sollen "i" hochzählen?
Eine 2te onRelease-Aktion so einsam am Ende??? Da würde dann die erste wieder überschrieben werden (wenn du nich 2x "i" verwendet hättest).
Solltest bei MX 2004 auch mal auf Groß-/Kleinschreibung achten.
"button" ist kein so toller Name (data, label und Content auch nicht).
Ansonsten habe ich so das Gefühl, du verstehst dein eigenes Script nicht so wirklich...

PHP-Code:

var tl = this;
for (i=0; i<MenuItem.length; i++) {
    var mc = tl.createEmptyMovieClip("MenuHolder"+i, i+1);
    mc._x = MenuXPos;
    mc._y = MenuYPos+(i*MenuHoehe);
    var btn = mc.attachMovie("Button", "button", i+1);
    btn.buttonlabel = MenuItem[i]["label"];
    btn.buttondata = MenuItem[i]["data"];
    //------------------------------------------------------------------ 
    // Legt den Button Status fest 
    //------------------------------------------------------------------ 
    btn.onRollOver = function() {
        if (this != tl.clicked) {
            this.gotoAndStop(2);
        }
    };
    btn.onRollOut = btn.onReleaseOutside=function () {
        if (this != tl.clicked) {
            this.gotoAndStop(1);
        }
    };
    btn.onRelease = function() {
        if (this != tl.clicked) {
            //hier die Navigations-Aktion... 
            this.gotoAndStop(3);
            tl.clicked.gotoAndStop(1);
            tl.clicked.useHandCursor = true;
            tl.clicked = this;
            this.useHandCursor = false;
            Content = this.buttondata;
            PerformAction(Content);
        }
    };
} 


edit: Nochmal etwas gekürzt...

[Jenz]

Hallo Frager,

das Menü funzt, nur im Zusammenspiel mit meiner Status-Abfrage nicht.
Außerdem bin ich mit meinem Menü ja noch am Anfang.

Dann denk doch, dass ich mein Script nicht verstehe!
Wenn ich AS-Experte wäre, bräuchte ich hier nichts mehr zu posten!
Das ist doch der Sinn solcher Foren?

Für den Tip Groß-/Kleinschreibung. Danke, wusste ich noch nicht.


Grüsse Jenz

[Der Frager]

...funktioniert doch jetzt aber - also auch der Status für die Buttons. Oder etwa nicht?

Übrigens ist die Groß-/Kleinschreibung erst ab MX 2004 relevant. Da ist's dann ein Unterschied, ob man z.B. "MenuYPos" oder "MenuYpos" schreibt.
Bei dir stand Flash 6 in den Veröffentlichungseinstellunge. Deshalb ging das halt noch...

edit: Ich wollte dich übrigens nicht anpflaumen oder so.

[Jenz]

funktioniert leider noch nicht! Hab das nach Deinem Code abgeändert, aber
es klappt nicht. Ich versteh nicht woran das liegen kann.

edit: Ich wollte dich übrigens nicht anpflaumen oder so.

>> Habe ich auch nicht so aufgefasst. Gruss

[Der Frager]

[Jenz]

Super es funzt, tausend Dank!!!!!!


Viele Grüße

Jenz

[Jenz]

Ich hab da noch mal eine generelle Frage.
Würdest du sagen das, dass Menü generell, gut angelegt ist
(bis auf die Sachen, die du vorher im posting schon genannt hast)?

Oder würdest du komplett anders an solch ein Menü herangehen?