button effekt

[joya]

hat jemand von euch vielleich einen script mit dem ich einfachen button rollover effekt erstellen kann.

ich will nur dass eine einzige linie den button überfliegt , und wiederholt sich solang wie on(rollover) funktion geht


ich kann das mit tweening und gotoAndPlay befehle machen, aber das sollte mit AC einfacher sein. aber wie?

[warrantmaster]

grz

[joya]

button ist gut, aber das mit visible gefählt mir nicht. ich will dass eine dünne linie (etwa 1px hoch, und genau wie button breit), dass die von unten nach oben geht, und das soll sich wiederholen solang wie maus drauf ist

ich habe ein tweening beispiel gemacht

[warrantmaster]

dann so.

[joya]

ja ok, so konnte ich auch das lösen, aber ich wollte eigentlich die linie nicht mit tweening bewegen sonder irgendwie nur mit AC und positioning.

(wenn das möglich ist)

trotzdem danke für die mühe

[warrantmaster]

das geht, dann mußt du allerdings doch mit _visible leben !

[joya]

ok, aber wie kann ich mit _visible , eine linie z.B. von links nach recht bewegen?

[warrantmaster]

....überhaupt nicht...

starty = mc1._y;
ziely = starty-25;
mc1._visible=0;
MovieClip.prototype.moveup = function() {
    this._visible = 1;
    this.onEnterFrame = function() {
        if (this._y>ziely) {
            this._y -= 3;
        } else {
            delete this.onEnterFrame;
            this.movedown();
        }
    };
};
MovieClip.prototype.movedown = function() {
    this._visible = 1;
    this.onEnterFrame = function() {
        if (this._y<starty) {
            this._y += 3;
        } else {
            delete this.onEnterFrame;
            this.moveup();
        }
    };
};
MovieClip.prototype.move_end = function() {
    this.onEnterFrame = function() {
        this._visible = 0;
        this._y = starty;
    };
    delete this.onEnterFrame();
};
mc.onRollOver = function() {
    mc1.moveup();
};
mc.onRollOut = function() {
    mc1.move_end();
}; 

grz

[sectore]

Nur mal ein Gedanke, dies ohne _visible zu lösen. Alles weitere in Kommentaren oder angehänger Datei:

// Tempo
var tempo = 3;
// Startrichtung
var richtung = "rechts";
// Rollover
meinButton.onRollOver = function ()
{
    // Linie anzeigen
    _root.attachMovie ("linie", "linie1", 1);
    with (_root.linie1)
    {
        // Linie positionieren
        _x = this._x;
        _y = this._y;
        // max. Werte fuer links + rechts festlegen
        minX = _x;
        maxX = _x + this._width;
    }
    // Linie bewegen
    linie1.onEnterFrame = function ()
    {
        // nach Rechts
        if (richtung == "rechts")
        {
            this._x += tempo;
            if (this._x >= maxX)
            {
                richtung = "links";
                trace (richtung);
            }
        }
        // nach Links
        if (richtung == "links")
        {
            this._x -= tempo;
            if (this._x <= minX)
            {
                richtung = "rechts";
                trace (richtung);
            }
        }
    };
};
// Rollout
meinButton.onRollOut = function ()
{
    // "onEnterFrame" entfernen
    delete _root.linie1.onEnterFrame ();
    // Entfernen der Linie
    removeMovieClip ("linie1");
}; 

[warrantmaster]

ok, dann mal etwas mehr dynamisch

hoehe = 15;
breite = 100;
startx = 200;
starty = 50;
anzahl = 15;
abstand = 3;
farbe = 0xFFCC33;
rand = 0x000000;
strichfarbe = 0xFF0000;
speed = 1;
arr = [];
for (var i = 1; i<=anzahl; i++) {
    arr.push("hallo"+i);
}
//
//
//
//
_root.createEmptyMovieClip("mc1", 0);
m = _root.mc1;
m.moveTo(0, 0);
m.lineStyle(1, rand, 100);
m.beginFill(farbe, 100);
m.lineTo(breite, 0);
m.lineTo(breite, hoehe);
m.lineTo(0, hoehe);
m.lineTo(0, 0);
m.endFill();
m._x = startx;
m._y = starty;
//
//
//
//
for (var i = 2; i<=anzahl; i++) {
    _root.mc1.duplicateMovieClip("mc"+i, i);
    _root["mc"+i]._x = startx;
    _root["mc"+i]._y = starty+((i-1)*(hoehe+abstand));
    for (var j = 1; j<=anzahl; j++) {
        _root["mc"+j].createTextField("txt", 1, 10, -3, 100, 20);
        _root["mc"+j].txt.text = arr[j-1];
        _root["mc"+j].onRollOver = function() {
            this.build();
        };
        _root["mc"+j].onRollOut = function() {
            this.createEmptyMovieClip("kill", 0);
        };
    }
}
//
//
//
//
//
MovieClip.prototype.build = function() {
    this.createEmptyMovieClip("strich", 0);
    this.strich.moveTo(_x, _y+(hoehe/2));
    this.strich.lineStyle(1, strichfarbe, 100);
    this.strich.lineTo(_x+breite, _y+(hoehe/2));
    this.strich.move("hoch", _y-(hoehe/2), _y+(hoehe/2));
};
//
//
//
//
MovieClip.prototype.move = function(richtung, oben, unten) {
    this.onEnterFrame = function() {
        if (richtung == "hoch") {
            if (this._y>oben) {
                this._y -= speed;
                if (this._y<=oben) {
                    richtung = "runter";
                }
            }
        }
        if (richtung == "runter") {
            if (this._y<unten) {
                this._y += speed;
                if (this._y>=unten) {
                    richtung = "hoch";
                }
            }
        }
    };
}; 

grz

[Schnitzel]

wow!

[soundpixler]

ihr könnt ja ganz schön gut AC. *g*