bildüberblendung bleibt sichtbar

[ole4]

ich habe ein script zum bildüberblenden.
funtioniert soweit auch super. wenn ich aber nen frame weiter springe, bleibt die animaion weiter bestehen.
wie kann ich sie unsichtbar machen bzw. löschen.

stop();
import mx.transitions.*;
import mx.transitions.easing.*;
Path = "test/";
Pictures = new Array()
Pictures[0] = "bild0.jpg";
Pictures[1] = "bild1.jpg";
Pictures[2] = "bild2.jpg";
Pictures[3] = "bild3.jpg";
for(p = 0; p < Pictures.length; p++){
   _root.createEmptyMovieClip("Pic" + p, 666 + p);
   _root["Pic" + p]._alpha = 0;
   _root["Pic" + p].loadMovie(Path + Pictures[p]);
}
Active = 0;
function switching(){
   Active ++;
   if(Active == Pictures.length){
      Active = 0;
   }
    ActivePic = _root["Pic" + Active]
   fadePic();
}
function fadePic(){
   FadeOut = new mx.transitions.Tween(OldPic, "_alpha", mx.transitions.easing.Regular.easeInOut , 100, 0, 4, true);
    FadeIn = new mx.transitions.Tween(ActivePic, "_alpha", mx.transitions.easing.Regular.easeInOut , 0, 100, 2, true);
   FadeIn.onMotionFinished  = function(){
      OldPic = ActivePic;
   }
}
switching();
setInterval(switching, 8000);

anbei die fla damit es vielleicht direkt klar wird was ich meine.

[salazar]

hi,
das geht so:

PHP-Code:

stop();
import mx.transitions.*;
import mx.transitions.easing.*;
Path = "test/";
Pictures = new Array()
Pictures[0] = "bild0.jpg";
Pictures[1] = "bild1.jpg";
Pictures[2] = "bild2.jpg";
Pictures[3] = "bild3.jpg";
for(p = 0; p < Pictures.length; p++){
   _root.createEmptyMovieClip("Pic" + p, 666 + p);
   _root["Pic" + p]._alpha = 0;
   _root["Pic" + p].loadMovie(Path + Pictures[p]);
}
Active = 0;
function switching(){
    trace("*");
   Active ++;
   if(Active == Pictures.length){
      Active = 0;
   }
    ActivePic = _root["Pic" + Active]
   fadePic();
}
function fadePic(){
   FadeOut = new mx.transitions.Tween(OldPic, "_alpha", mx.transitions.easing.Regular.easeInOut , 100, 0, 4, true);
    FadeIn = new mx.transitions.Tween(ActivePic, "_alpha", mx.transitions.easing.Regular.easeInOut , 0, 100, 2, true);
   FadeIn.onMotionFinished  = function(){
      OldPic = ActivePic;
   }
}
switching();
var myInterval = setInterval(switching, 2000); 
function removeAllPics(){
    clearInterval(myInterval);
    for(p = 0; p < Pictures.length; p++){
        _root["Pic" + p].removeMovieClip()
    }
} 


und natürlich mußte die neue function auch aufrufen:

PHP-Code:

btn.onRelease = function() {
    _root.gotoAndStop(2);
    removeAllPics();
}; 


viel spaß.
cheers, nik

[salazar]

hi nochmal,
ich hab dich mal hierher verschoben.
weil das bei dir mit actionscript2 so gar nix zu tun hat
cheers, sal

[salazar]

hatte irgentwie mal wieder bock so richtig schön actionscript2 timeline zu coden

anbei deine galerie in as2. einfach dein hauptscript mit diesem hier ersetzen

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

import mx.transitions.*;
import mx.transitions.easing.*;

//-------------------------------------

var filePath:String = "test/";
var fileHolder:Array = new Array( "bild0.jpg", "bild1.jpg", "bild2.jpg", "bild3.jpg" );
var arrayPos:Number = -1;
var intervalHolder:Number;
var intervalSpeed:Number = 3000;
var galleryHolder:MovieClip = this.createEmptyMovieClip( "galleryHolder", this.getNextHighestDepth() );
var picturesClipsHolder:Array = new Array();
var pictureOld:MovieClip;
var pictureNew:MovieClip;
var tweenFadeOut:Tween;
var tweenFadeIn:Tween;
var tweenSpeed:Number = 2;

//-------------------------------------

function init():Void {
    
    var pictureHolder:MovieClip;
    
    for ( var p:Number = 0; p < fileHolder.length; p++ ) {
        
       pictureHolder = galleryHolder.createEmptyMovieClip( "Pic" + p, galleryHolder.getNextHighestDepth() );
       pictureHolder._alpha = 0;
       pictureHolder.loadMovie( filePath + fileHolder[ p ] );
       
       picturesClipsHolder.push( pictureHolder );
       
    }
    
    switching();

    intervalHolder = setInterval( switching, intervalSpeed ); 
    
}

//-------------------------------------

function switching():Void {
    
    tweenFadeOut.stop();
    tweenFadeIn.stop();

    arrayPos++;
    
    if ( arrayPos == fileHolder.length ) arrayPos = 0;

    pictureNew = picturesClipsHolder[ arrayPos ];

    fadePic();
    
}

//-------------------------------------

function fadePic():Void {
    
    tweenFadeOut = new Tween( pictureOld, "_alpha", Regular.easeInOut , 100, 0, tweenSpeed, true );
    tweenFadeIn  = new Tween( pictureNew, "_alpha", Regular.easeInOut , 0, 100, tweenSpeed, true );
    tweenFadeIn.onMotionFinished  = function():Void {

        pictureOld = pictureNew;
        
    }
   
}

//-------------------------------------

function removeAllPics():Void {
    
    clearInterval( intervalHolder );
    
    var tweenAllOut:Tween;
    
    tweenAllOut = new Tween( galleryHolder, "_alpha", Regular.easeInOut , galleryHolder._alpha, 0, tweenSpeed, true );
    tweenAllOut.onMotionFinished  = function():Void {

        for ( var str:String in picturesClipsHolder ) picturesClipsHolder[ str ].removeMovieClip();

        galleryHolder.removeMovieClip();
        
    }

}

//-------------------------------------

init();

//------------------------------------- 


cheers, sal

[ole4]

wow
super vielen dank für die schnelle hilfe und respekt fürs AS2 coden.
wobei ich das nicht ganz verstehe was im as2 jetzt steht...ich werde es mal studieren : )
danke

[tommui]

Hallo salzar,

ich habe dein Skript auch einmal ausprobiert und es ist wirklich klasse.
Kannst du mir zeigen, wie man in ein Zweites Array neben dem fileHolder mit den Bildnamen eines erzeugt, in dem für jedes Bild eine Anzeigedauer festgelegt wird?

Ich habe es noch nicht geschafft die intervalSpeed-Nummer für jedes Bild einzeln anzupassen.

Vielen Dank

[salazar]

ja hi,
salzar kenn ich nicht...
aber hier die antwort auf deine frage:
(thread original files mit neuem AS anbei)

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

import mx.transitions.*;
import mx.transitions.easing.*;

//-------------------------------------

var filePath:String = "test/";
var fileHolder:Array = new Array( { img:"bild0.jpg", time:18000 }, { img:"bild1.jpg", time:6000 }, { img:"bild2.jpg", time:3000 }, { img:"bild3.jpg", time:4000 } );
var arrayPos:Number = -1;
var intervalHolder:Number;
var intervalSpeed:Number;
var galleryHolder:MovieClip = this.createEmptyMovieClip( "galleryHolder", this.getNextHighestDepth() );
var picturesClipsHolder:Array = new Array();
var pictureOld:MovieClip;
var pictureNew:MovieClip;
var tweenFadeOut:Tween;
var tweenFadeIn:Tween;
var tweenSpeed:Number = 2;

//-------------------------------------

function init():Void {
    
    clearInterval( intervalHolder );
    
    var pictureHolder:MovieClip;
    
    for ( var p:Number = 0; p < fileHolder.length; p++ ) {
        
       pictureHolder = galleryHolder.createEmptyMovieClip( "Pic" + p, galleryHolder.getNextHighestDepth() );
       pictureHolder._alpha = 0;
       pictureHolder.loadMovie( filePath + fileHolder[ p ].img );
       
       picturesClipsHolder.push( pictureHolder );
       
    }
    
    arrayPos++;

    pictureNew = picturesClipsHolder[ arrayPos ];
    
    fadePic();

    intervalSpeed = Number( fileHolder[ 0 ].time );
    intervalHolder = setInterval( switching, intervalSpeed ); 
    
}

//-------------------------------------

function switching():Void {
    
    tweenFadeOut.stop();
    tweenFadeIn.stop();

    arrayPos++;
    
    if ( arrayPos == fileHolder.length ) arrayPos = 0;

    pictureNew = picturesClipsHolder[ arrayPos ];

    fadePic();
    
    clearInterval( intervalHolder );
    
    intervalSpeed = Number( fileHolder[ arrayPos ].time );
    intervalHolder = setInterval( switching, intervalSpeed ); 

}

//-------------------------------------

function fadePic():Void {
    
    tweenFadeOut = new Tween( pictureOld, "_alpha", Regular.easeInOut , 100, 0, tweenSpeed, true );
    tweenFadeIn  = new Tween( pictureNew, "_alpha", Regular.easeInOut , 0, 100, tweenSpeed, true );
    tweenFadeIn.onMotionFinished  = function():Void {

        pictureOld = pictureNew;
        
    }
   
}

//-------------------------------------

function removeAllPics():Void {
    
    clearInterval( intervalHolder );
    
    var tweenAllOut:Tween;
    
    tweenAllOut = new Tween( galleryHolder, "_alpha", Regular.easeInOut , galleryHolder._alpha, 0, tweenSpeed, true );
    tweenAllOut.onMotionFinished  = function():Void {

        for ( var str:String in picturesClipsHolder ) picturesClipsHolder[ str ].removeMovieClip();

        galleryHolder.removeMovieClip();

    }

}

//-------------------------------------

init();

//------------------------------------- 


mußte ein bissal was für umschreiben. ich hab allerdings kein zweites array hinzugefügt, sondern einfach objects ins array gepackt mit den entsprechenden infos für file und time.

time:18000 = 18 sekunden
time:6000= 6 sekunden
time:3000= 3 sekunden
time:4000= 4 sekunden


cheers, sal

edit: das ganze ist übrigens actionscript 2 und nicht 1

[tommui]

Hallo Danke für deine Antwort. Leider kann ich deine zip-Datei nicht öffnen.
Da ich hier nicht in einen fremden POst reinschreiben wollte, habe ich ein neues Thema aufgemacht. Beim gesperrten Post geht es um einen völlig anderen Lösungsansatz, dort sind Beschreibung und Zeit in einer Datei.
Ich würde mich freuen, wenn du ihn wieder aufmachst

[salazar]

hi,
wieso kannste die zip nicht öffnen?
und selbst wenn du die nicht öffnen kannst.... den code hat ich ja mit dazu gepostet. dann mußte halt die original zip von ganz oben neben und den dort enthaltenen code mit dem aus diesem thread hier ersetzen. mehr hatte ich auch nicht getan...
probier es also einfach mal aus!
naja... mit dem völlig anderen lösungsansatz ist aber nicht unbedingt ersichtlich.
cheers, sal

[tommui]

Ja, von der Fragestellung her hast du recht, aber das Skript bzw der Aufbau ist anders.
Ich versuche gerade deinen Code zu verstehen und es an das Skript, im gesperrten Thread, anzupassen. Nur mir gelingt es nicht
Wie man da eine Verzögerung einbaut, habe ich noch nicht verstanden. Ganz schön kompliziert

[salazar]

Zitat von tommui

Ich versuche gerade deinen Code zu verstehen und es an das Skript, im gesperrten Thread, anzupassen.

hi,
erstens ist der thread nicht mehr gesperrt und zweitens brauchste nix anzupassen. jedenfalls nicht wenn es um deine frage

Zitat von tommui

Ich habe es noch nicht geschafft die intervalSpeed-Nummer für jedes Bild einzeln anzupassen.

geht. dann kannste nämlich ganz einfach das script nehmen und alles läuft so wie gewünscht

cheers, sal

[tommui]

Nochmals Vielen Dank für deine ganzen Antworten (:
Ich werde jetzt erstmal eine Pause machen, vielleicht klappt's dann einfacher

[Bibbell]

Besten Dank für das tolle Script!!!

Ich würde jetzt gerne einen Rahmen (png) über das ganze legen...
Hab schon alles ausprobiert (wie z.B. das .png in einen mc konvertiert und per "swapDepths(this.getNextHighestDepth() );" auf eine höhere Tiefe zu legen).
Funktioniert aber alles nicht.

Komme nicht mehr weiter.. seit gestern mittag.

Kann mir jemand helfen ?