Bilderabstand

[obster]

Hi,

ich versuche eine dynamische Bilderleiste umzusetzen, die eine beliebige Anzahl von Bilder nebeneinander anordnet. Die Bilder sind in ihren Größen variabel. Ich kann die Bilder dynamisch einlesen und sie in leeren MC platzieren. Leider kann ich aber die Größe der Bilder selbst nicht abfragen und auch die with der MC verändert sich nicht.
Kennt jemand eine Möglichkeit um die Bildergröße abzufragen oder aber einen festen Abstand zwischen den Bilder umzusetzen (quasi ähnlich wie margin oder padding im CSS)?

Vielen Dank

P.S.: in actionscript 1 oder 2 am besten

[RustyCake]

Servus und Willkommen im FF
wie hast Du es den probiert?

[muschko]

bildmc._width ?

[RustyCake]

Bisschen mehr infos wären nicht schlecht!
Verwendest Du loadMovie oder attachMovie?

[obster]

for (var i=1;i<_global.numberOfImages+1;i++)
	{
		trace(this.tempI + " tempI1");
		this.createEmptyMovieClip(_global.nameOfTheImages+i,this.tempI);
		this.tempI++; 
		trace(this.tempI + " tempI2");
		this.attachMovie("thumb","press" + _global.nameOfTheImages+i,this.tempI);
	    this["press"+_global.nameOfTheImages + i]._width=_global.thumbHeight*3/4;
		this["press"+_global.nameOfTheImages + i]._height=_global.thumbHeight;
		this["press"+_global.nameOfTheImages + i]._x=(this[_global.nameOfTheImages +(i-1)]._x)+_global.spacer;	
	
		this[_global.nameOfTheImages + i].loadMovie (_global.nameOfTheImages + i +".jpg");

		if(i > 1){
			trace(this[_global.nameOfTheImages + i]._x + " pos_x");
			trace((this[_global.nameOfTheImages +(i-1)]._width));
			this[_global.nameOfTheImages + i]._x=(this[_global.nameOfTheImages +(i-1)]._x)+(this[_global.nameOfTheImages +(i-1)]._width)+_global.spacer;	
			trace(this[_global.nameOfTheImages + i]._x + " pos_x");
			}
		}
	}

So habe ich es versucht, die traces reagieren aber nicht, die Bilder selbst kann ich mit der _x Koordinate ansprechen.
Die ""press Geschichte dient nur zur Bedienung später (bei kllicken vergrößern etc.)

[RustyCake]

Keiner dieser traces gibt was aus??

[obster]

Doch, die Positions Traces funktionieren, doch ist der _width trace mit 0 ausgegeben. Der emptyMC ist natürlich ursprünglich 0px breit, aber müsste ja durch das Bild quasi "aufgebläht" werden.

[RustyCake]

Von dem "this[_global.nameOfTheImages + i]" bekommst nur die breite und höhe wennst einen loader dazwischen legst, der abfrägt ob die Dinger schon komplett geladen sind, vorher kannst diese Infos nicht bekommen, und auch keine werte zuweisen !

[obster]

hm, naja, aber wenn ich eine einfache Abfrage mache

	if(this[_global.nameOfTheImages + i].getBytesTotal()>=this[_global.nameOfTheImages + i].getBytesLoaded())
	{
		trace("width: " + this[_global.nameOfTheImages + i]._width);
	}

dann kommt im trace aber auch nur 0 und keine spezifische width.

[RustyCake]

Da brauchts einen onEnterFrame oder setInterval noch zu, um den Ladestatus eines files zu erkennen!

[obster]

Also das versteh eich nicht so recht, die Funktion wird ja aufgerufen, mindestens einmalig und ich bekomme ein Ergebnis, auch ohne Ereignis Call wie onEnterFrame, wenn ich allerdings onEnterFrame = function(){ ... } um die if Abfrage setze, dann erhalte ich kein Ergebnis für width.

[RustyCake]

Hab Dir mal was gebastelt, ich muß mich sowieso grad mit dem MovieClipLoader auseiandersetzen

PHP-Code:

var movieArray = ["rot.swf", "gruen.swf", "blau.swf", "gelb.swf"];
var posArray = [[0, 0], [50, 50], [100, 100], [150, 150]];
var bild_mc = new MovieClipLoader();
ObjL = new Object();
ObjL.onLoadStart = function(obi)
{
    trace("Start  | "+obi);
};
ObjL.onLoadInit = function(obi)
{
    trace("obi._width = "+obi._width+" | "+"obi._height = "+obi._height);
    obi._width = 200;
    obi._height = 200;
    trace("obi._width = "+obi._width+" | "+"obi._height = "+obi._height);
};
ObjL.onLoadComplete = function(obi)
{
    trace("Ready  | "+obi);
};
_root.bild_mc.addListener(ObjL);
for (var i = 0; i<movieArray.length; i++)
{
    var mc = this.createEmptyMovieClip("container"+i, this.getNextHighestDepth());
    mc._x = posArray[i][0];
    mc._y = posArray[i][1];
    this.bild_mc.loadClip(movieArray[i], mc);
}