Bei Klick Text unter Cursor im Textfeld auslesen

[tanja3000]

Hallo!

Gib es eine Möglichkeit durch ein Mausklick auf das Textfeld das Wort oder den Inhalt einer Textzeile, das/die sich gerade unter dem Mauszeiger befindet, auszulesen bzw. in einem anderem Textfeld ausgeben lassen?

Danke!

[andretti]

aloha!

also ich kenn das evt. nur für eingabetextfelder und deren ganzen inhalt;
du müsstest ein eingabetextfeld nehmen und da mal den text reinschreiben;

dann actionscript in die hauptzeitleiste(das eingabetextfeld heißt "input_txt", das andre (dynamische) textfeld heißt "save_txt"):

PHP-Code:

//bei reinklicken:
_root.input_txt.onSetFocus = function(){
_root.save_txt.text= _root.input_txt.text;
} 


mal ausprobieren;
eventuell funktioniert onSetFocus() auch bei dynamischen textfeldern, weiß i jetzt net;

sieh dir auch noch "setSelection()" in der flashhilfe an!

generell:

http://www.flashforum.de/forum/searc...archid=1282125

[sonar]

Hallo!

Gibt es eine Möglichkeit, noch allgemeinere Betreffs für einen Beitrag zu wählen*.. ?

Leg ein dyn. Textfeld an, gib ihm den Instanznamen 'txt' und... hex hex...

PHP-Code:

txt.onMouseUp = function() {
    
    var currWord = "";
    var index = Selection.getBeginIndex()
    
    while (txt.text.charAt(--index) != " ") {}
    
    while (txt.text.charAt(++index) != " ") {
        currWord += txt.text.charAt(index);
    }
    
    trace(currWord);
}

Mouse.addListener(txt); 


* Ich ändere den mal für andere Leute, die auch sowas suchen... beim nächsten Mal an die anderen denken bitte!

[andretti]

soll ich meinen beitrag wieder löschen?

[Der Frager]

@ sonar: Beim ersten oder letzten Wort kackt Flash aber ab .

PHP-Code:

txt.onMouseUp = function() {
    var currWord = "";
    var index = Selection.getBeginIndex();
    while (txt.text.charAt(--index) != " " && index != -1) {
    }
    while (txt.text.charAt(++index) != " " && index != txt.text.length) {
        currWord += txt.text.charAt(index);
    }
    trace(currWord);
};
Mouse.addListener(txt); 


[sonar]

Ouh ouh... stümmt Asche auf mein Haupt...
Danke, Herr Frager!

[sonar]

Oh je... so ganz das Wahre war das immer noch nicht.
Wenn man nun woanders hinklickt, wird die Funktion ja auch aufgerufen, und das ganze geht ins Ungewisse... Soisrichtig:

PHP-Code:

txt.onSetFocus = function():Void {
    
    this.onMouseUp = function():Void {
        
        var currWord:String = "";
        var index:Number = Selection.getBeginIndex()
        
        while (this.text.charAt(--index) != " " && index != -1) {}
        
        while (this.text.charAt(++index) != " " && index != this.text.length) {
            currWord += this.text.charAt(index);
        }
        
        trace(currWord);
    };
    
    Mouse.addListener(this);
};

txt.onKillFocus = function():Void {
    Mouse.removeListener(this);
}; 


[andretti]

juhu, mein onSetFocus war richtig!!!!

[sonar]

Naja - immerhin...

[Der Frager]

@ sonar: Irgendwie nicht wirklich... Also mir stürzt Flash da ab (nicht immer, aber ab und zu). Genaugenommen, wenn man direkt nach dem Start aufs letzte Wort klickt und dann außerhalb des Textfeldes. Liegt aber wohl nur an der Trace-Ausgabe (die klaut ja den Focus, oder?).
So scheint's dann aber zu gehen - und jetzt ist's auch gut mit Schaiß hier

PHP-Code:

txt.onSetFocus = function() {
    this._parent.onEnterFrame = function() {
        delete this.onEnterFrame;
        var currWord:String = "";
        var index:Number = Selection.getCaretIndex();
        while (this.txt.text.charAt(--index) != " " && index != -1) {
        }
        while (this.txt.text.charAt(++index) != " " && index != this.txt.text.length) {
            currWord += this.txt.text.charAt(index);
        }
        trace(currWord);
        Selection.setFocus(null);
    };
}; 


[sonar]

Also das mit dem Abstürzen konnt ich jetzt nicht nachvollziehen (und das am Mac...). Aber gut, noch nen anderen Ansatz am Start zu haben...

Wenn sich die Thread-Starterin dann auch mal bequemt, hier wieder reinzusehen... naja, egal, wir hatten unseren Spaß...